m4/efl_binary.m4

   1 dnl Copyright (C) 2010 Vincent Torri <vtorri at univ-evry dot fr>
   2 dnl That code is public domain and can be freely used or copied.
   3
   4 dnl Macro that check if a binary is built or not
   5
   6 dnl Usage: EFL_ENABLE_BIN(binary)
   7 dnl Call AC_SUBST(BINARY_PRG) (BINARY is the uppercase of binary, - being tranformed into _)
   8 dnl Define have_binary (- is tranformed into _)
   9 dnl Define conditional BUILD_BINARY (BINARY is the uppercase of binary, - being tranformed into _)
  10
  11 AC_DEFUN([EFL_ENABLE_BIN],
  12 [
  13
  14 m4_pushdef([UP], m4_translit([[$1]], [-a-z], [_A-Z]))dnl
  15 m4_pushdef([DOWN], m4_translit([[$1]], [-A-Z], [_a-z]))dnl
  16
  17 have_[]m4_defn([DOWN])="yes"
  18
  19 dnl configure option
  20
  21 AC_ARG_ENABLE([$1],
  22    [AC_HELP_STRING([--disable-$1], [disable building of ]DOWN)],
  23    [
  24     if test "x${enableval}" = "xyes" ; then
  25        have_[]m4_defn([DOWN])="yes"
  26     else
  27        have_[]m4_defn([DOWN])="no"
  28     fi
  29    ])
  30
  31 AC_MSG_CHECKING([whether to build ]DOWN[ binary])
  32 AC_MSG_RESULT([$have_[]m4_defn([DOWN])])
  33
  34 if test "x$have_[]m4_defn([DOWN])" = "xyes"; then
  35    UP[]_PRG=DOWN[${EXEEXT}]
  36 fi
  37
  38 AC_SUBST(UP[]_PRG)
  39
  40 AM_CONDITIONAL(BUILD_[]UP, test "x$have_[]m4_defn([DOWN])" = "xyes")
  41
  42 AS_IF([test "x$have_[]m4_defn([DOWN])" = "xyes"], [$2], [$3])
  43
  44 ])
  45
  46
  47 dnl Macro that check if a binary is built or not
  48
  49 dnl Usage: EFL_WITH_BIN(package, binary, default_value)
  50 dnl Call AC_SUBST(_binary) (_binary is the lowercase of binary, - being tranformed into _ by default, or the value set by the user)
  51
  52 AC_DEFUN([EFL_WITH_BIN],
  53 [
  54
  55 m4_pushdef([DOWN], m4_translit([[$2]], [-A-Z], [_a-z]))dnl
  56
  57 dnl configure option
  58
  59 AC_ARG_WITH([$2],
  60    [AC_HELP_STRING([--with-$2=PATH], [specify a specific path to ]DOWN[ @<:@default=$3@:>@])],
  61    [_efl_with_binary=${withval}],
  62    [_efl_with_binary=$(pkg-config --variable=prefix $1)/bin/$3])
  63
  64 DOWN=${_efl_with_binary}
  65 AC_MSG_NOTICE(DOWN[ set to ${_efl_with_binary}])
  66
  67 with_binary_[]m4_defn([DOWN])=${_efl_with_binary}
  68
  69 AC_SUBST(DOWN)
  70
  71 ])