m4/dup.m4

   1 # dup.m4 serial 7
   2 dnl Copyright (C) 2011-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_DUP],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11   m4_ifdef([gl_MSVC_INVAL], [
  12     AC_REQUIRE([gl_MSVC_INVAL])
  13     if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
  14       REPLACE_DUP=1
  15     fi
  16   ])
  17   dnl Replace dup() for supporting the gnulib-defined fchdir() function,
  18   dnl to keep fchdir's bookkeeping up-to-date.
  19   m4_ifdef([gl_FUNC_FCHDIR], [
  20     gl_TEST_FCHDIR
  21     if test $HAVE_FCHDIR = 0; then
  22       REPLACE_DUP=1
  23     fi
  24   ])
  25   AC_CACHE_CHECK([whether dup works], [gl_cv_func_dup_works],
  26     [AC_RUN_IFELSE(
  27       [AC_LANG_PROGRAM([[#include <unistd.h>
  28                          #include <fcntl.h>
  29                          #include <errno.h>
  30                        ]GL_MDA_DEFINES],
  31          [[/* On OS/2 kLIBC, dup does not work on a directory fd.  */
  32            int fd = open (".", O_RDONLY);
  33            return fd < 0 ? 1 : dup (fd) < 0 ? 2 : 0;
  34          ]])
  35       ],
  36       [gl_cv_func_dup_works=yes],
  37       [gl_cv_func_dup_works=no],
  38       [case "$host_os" in
  39                  # Guess no on native Windows.
  40          mingw*) gl_cv_func_dup_works="guessing no" ;;
  41          *)      gl_cv_func_dup_works="guessing yes" ;;
  42        esac
  43       ])
  44     ])
  45   case "$gl_cv_func_dup_works" in
  46     *yes) ;;
  47     *)
  48       REPLACE_DUP=1
  49       ;;
  50   esac
  51 ])
  52
  53 # Prerequisites of lib/dup.c.
  54 AC_DEFUN([gl_PREREQ_DUP], [:])