m4/dpkg-types.m4

   1 # Copyright © 2005 Scott James Remnant <scott@netsplit.com>
   2 # Copyright © 2009-2011 Guillem Jover <guillem@debian.org>
   3
   4 # DPKG_TYPE_PTRDIFF_T
   5 # -------------------
   6 # Check for the ptrdiff_t type, defining to int if not defined
   7 AC_DEFUN([DPKG_TYPE_PTRDIFF_T],
   8 [AC_CHECK_TYPE([ptrdiff_t],,
   9         AC_DEFINE_UNQUOTED([ptrdiff_t], [int],
  10                            [Define to 'int' if <malloc.h> does not define.]))dnl
  11 ])# DPKG_TYPE_PTRDIFF_T
  12
  13 # DPKG_TYPE_U_INT_T(N)
  14 # --------------------
  15 # Check for u_intN_t BSD type, defining to C99 type if not.
  16 AC_DEFUN([DPKG_TYPE_U_INT_T],
  17 [
  18   AC_CHECK_TYPE([u_int$1_t], [],
  19                 AC_DEFINE_UNQUOTED([u_int$1_t], [uint$1_t],
  20                                    [Define to 'uint$1_t' if not defined.]))
  21 ])
  22
  23 # DPKG_TYPES_U_INT_T
  24 # ------------------
  25 # Check for u_int(8|16|32|64)_t BSD types, defining to C99 types if not.
  26 AC_DEFUN([DPKG_TYPES_U_INT_T],
  27 [
  28   DPKG_TYPE_U_INT_T([8])
  29   DPKG_TYPE_U_INT_T([16])
  30   DPKG_TYPE_U_INT_T([32])
  31   DPKG_TYPE_U_INT_T([64])
  32 ])
  33
  34 # DPKG_DECL_SYS_SIGLIST
  35 # ---------------------
  36 # Check for the sys_siglist variable in either signal.h or unistd.h
  37 AC_DEFUN([DPKG_DECL_SYS_SIGLIST],
  38 [AC_CHECK_HEADERS([unistd.h])
  39 AC_CHECK_DECLS([sys_siglist],,,
  40 [#include <signal.h>
  41 /* NetBSD declares sys_siglist in unistd.h.  */
  42 #if HAVE_UNISTD_H
  43 #  include <unistd.h>
  44 #endif
  45 ])dnl
  46 ])# DPKG_DECL_SYS_SIGLIST
  47
  48 # DPKG_CHECK_DECL([DECL], [HEADER])
  49 # -----------------
  50 # Define HAVE_DECL to 1 if declared in HEADER
  51 AC_DEFUN([DPKG_CHECK_DECL],
  52 [
  53   AC_CHECK_DECL($1,
  54                 [AC_DEFINE([HAVE_]AS_TR_CPP($1), 1,
  55                            [Define to 1 if ']$1[' is declared in <$2>])],,
  56                 [[#include <$2>]])
  57 ])# DPKG_CHECK_DECL