m4/ax_python_devel.m4

   1 # ===========================================================================
   2 #      http://www.gnu.org/software/autoconf-archive/ax_python_devel.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PYTHON_DEVEL([version])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Note: Defines as a precious variable "PYTHON_VERSION". Don't override it
  12 #   in your configure.ac.
  13 #
  14 #   This macro checks for Python and tries to get the include path to
  15 #   'Python.h'. It provides the $(PYTHON_CPPFLAGS) and $(PYTHON_LDFLAGS)
  16 #   output variables. It also exports $(PYTHON_EXTRA_LIBS) and
  17 #   $(PYTHON_EXTRA_LDFLAGS) for embedding Python in your code.
  18 #
  19 #   You can search for some particular version of Python by passing a
  20 #   parameter to this macro, for example ">= '2.3.1'", or "== '2.4'". Please
  21 #   note that you *have* to pass also an operator along with the version to
  22 #   match, and pay special attention to the single quotes surrounding the
  23 #   version number. Don't use "PYTHON_VERSION" for this: that environment
  24 #   variable is declared as precious and thus reserved for the end-user.
  25 #
  26 #   This macro should work for all versions of Python >= 2.1.0. As an end
  27 #   user, you can disable the check for the python version by setting the
  28 #   PYTHON_NOVERSIONCHECK environment variable to something else than the
  29 #   empty string.
  30 #
  31 #   If you need to use this macro for an older Python version, please
  32 #   contact the authors. We're always open for feedback.
  33 #
  34 # LICENSE
  35 #
  36 #   Copyright (c) 2009 Sebastian Huber <sebastian-huber@web.de>
  37 #   Copyright (c) 2009 Alan W. Irwin
  38 #   Copyright (c) 2009 Rafael Laboissiere <rafael@laboissiere.net>
  39 #   Copyright (c) 2009 Andrew Collier
  40 #   Copyright (c) 2009 Matteo Settenvini <matteo@member.fsf.org>
  41 #   Copyright (c) 2009 Horst Knorr <hk_classes@knoda.org>
  42 #   Copyright (c) 2013 Daniel Mullner <muellner@math.stanford.edu>
  43 #
  44 #   This program is free software: you can redistribute it and/or modify it
  45 #   under the terms of the GNU General Public License as published by the
  46 #   Free Software Foundation, either version 3 of the License, or (at your
  47 #   option) any later version.
  48 #
  49 #   This program is distributed in the hope that it will be useful, but
  50 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  51 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  52 #   Public License for more details.
  53 #
  54 #   You should have received a copy of the GNU General Public License along
  55 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  56 #
  57 #   As a special exception, the respective Autoconf Macro's copyright owner
  58 #   gives unlimited permission to copy, distribute and modify the configure
  59 #   scripts that are the output of Autoconf when processing the Macro. You
  60 #   need not follow the terms of the GNU General Public License when using
  61 #   or distributing such scripts, even though portions of the text of the
  62 #   Macro appear in them. The GNU General Public License (GPL) does govern
  63 #   all other use of the material that constitutes the Autoconf Macro.
  64 #
  65 #   This special exception to the GPL applies to versions of the Autoconf
  66 #   Macro released by the Autoconf Archive. When you make and distribute a
  67 #   modified version of the Autoconf Macro, you may extend this special
  68 #   exception to the GPL to apply to your modified version as well.
  69
  70 #serial 16
  71
  72 AU_ALIAS([AC_PYTHON_DEVEL], [AX_PYTHON_DEVEL])
  73 AC_DEFUN([AX_PYTHON_DEVEL],[
  74         #
  75         # Allow the use of a (user set) custom python version
  76         #
  77         AC_ARG_VAR([PYTHON_VERSION],[The installed Python
  78                 version to use, for example '2.3'. This string
  79                 will be appended to the Python interpreter
  80                 canonical name.])
  81
  82         AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
  83         if test -z "$PYTHON"; then
  84            AC_MSG_WARN([Cannot find python$PYTHON_VERSION in your system path])
  85            PYTHON_VERSION=""
  86            no_python_devel=yes
  87         fi
  88
  89 AS_IF([test -z "$no_python_devel"], [
  90         #
  91         # Check for a version of Python >= 2.1.0
  92         #
  93         AC_MSG_CHECKING([for a version of Python >= '2.1.0'])
  94         ac_supports_python_ver=`$PYTHON -c "import sys; \
  95                 ver = sys.version.split ()[[0]]; \
  96                 print (ver >= '2.1.0')"`
  97         if test "$ac_supports_python_ver" != "True"; then
  98                 if test -z "$PYTHON_NOVERSIONCHECK"; then
  99                         AC_MSG_RESULT([no])
 100                         AC_MSG_WARN([
 101 This version of the AC@&t@_PYTHON_DEVEL macro
 102 doesn't work properly with versions of Python before
 103 2.1.0. You may need to re-run configure, setting the
 104 variables PYTHON_CPPFLAGS, PYTHON_LDFLAGS, PYTHON_SITE_PKG,
 105 PYTHON_EXTRA_LIBS and PYTHON_EXTRA_LDFLAGS by hand.
 106 Moreover, to disable this check, set PYTHON_NOVERSIONCHECK
 107 to something else than an empty string.
 108 ])
 109                         no_python_devel=yes
 110                 else
 111                         AC_MSG_RESULT([skip at user request])
 112                 fi
 113         else
 114                 AC_MSG_RESULT([yes])
 115         fi
 116 ]) # AS_IF
 117
 118 AS_IF([test -z "$no_python_devel"], [
 119         #
 120         # if the macro parameter ``version'' is set, honour it
 121         #
 122         if test -n "$1"; then
 123                 AC_MSG_CHECKING([for a version of Python $1])
 124                 ac_supports_python_ver=`$PYTHON -c "import sys; \
 125                         ver = sys.version.split ()[[0]]; \
 126                         print (ver $1)"`
 127                 if test "$ac_supports_python_ver" = "True"; then
 128                    AC_MSG_RESULT([yes])
 129                 else
 130                         AC_MSG_RESULT([no])
 131                         AC_MSG_WARN([this package requires Python $1.
 132 If you have it installed, but it isn't the default Python
 133 interpreter in your system path, please pass the PYTHON_VERSION
 134 variable to configure. See ``configure --help'' for reference.
 135 ])
 136                         PYTHON_VERSION=""
 137                         no_python_devel=yes
 138                 fi
 139         fi
 140 ]) # AS_IF
 141
 142 AS_IF([test -z "$no_python_devel"], [
 143         #
 144         # Check if you have distutils, else fail
 145         #
 146         AC_MSG_CHECKING([for the distutils Python package])
 147         ac_distutils_result=`$PYTHON -c "import distutils" 2>&1`
 148         if test -z "$ac_distutils_result"; then
 149                 AC_MSG_RESULT([yes])
 150         else
 151                 AC_MSG_RESULT([no])
 152                 AC_MSG_WARN([cannot import Python module "distutils".
 153 Please check your Python installation. The error was:
 154 $ac_distutils_result])
 155                 PYTHON_VERSION=""
 156                 no_python_devel=yes
 157         fi
 158 ]) # AS_IF
 159
 160 AS_IF([test -z "$no_python_devel"], [
 161         #
 162         # Check for Python include path
 163         #
 164         AC_MSG_CHECKING([for Python include path])
 165         if test -z "$PYTHON_CPPFLAGS"; then
 166                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 167                         print (distutils.sysconfig.get_python_inc ());"`
 168                 plat_python_path=`$PYTHON -c "import distutils.sysconfig; \
 169                         print (distutils.sysconfig.get_python_inc (plat_specific=1));"`
 170                 if test -n "${python_path}"; then
 171                         if test "${plat_python_path}" != "${python_path}"; then
 172                                 python_path="-I$python_path -I$plat_python_path"
 173                         else
 174                                 python_path="-I$python_path"
 175                         fi
 176                 fi
 177                 PYTHON_CPPFLAGS=$python_path
 178         fi
 179         AC_MSG_RESULT([$PYTHON_CPPFLAGS])
 180         AC_SUBST([PYTHON_CPPFLAGS])
 181
 182         #
 183         # Check for Python library path
 184         #
 185         AC_MSG_CHECKING([for Python library path])
 186         if test -z "$PYTHON_LDFLAGS"; then
 187                 # (makes two attempts to ensure we've got a version number
 188                 # from the interpreter)
 189                 ac_python_version=`cat<<EOD | $PYTHON -
 190
 191 # join all versioning strings, on some systems
 192 # major/minor numbers could be in different list elements
 193 from distutils.sysconfig import *
 194 e = get_config_var('VERSION')
 195 if e is not None:
 196         print(e)
 197 EOD`
 198
 199                 if test -z "$ac_python_version"; then
 200                         if test -n "$PYTHON_VERSION"; then
 201                                 ac_python_version=$PYTHON_VERSION
 202                         else
 203                                 ac_python_version=`$PYTHON -c "import sys; \
 204                                         print (sys.version[[:3]])"`
 205                         fi
 206                 fi
 207
 208                 # Make the versioning information available to the compiler
 209                 AC_DEFINE_UNQUOTED([HAVE_PYTHON], ["$ac_python_version"],
 210                                    [If available, contains the Python version number currently in use.])
 211
 212                 # First, the library directory:
 213                 ac_python_libdir=`cat<<EOD | $PYTHON -
 214
 215 # There should be only one
 216 import distutils.sysconfig
 217 e = distutils.sysconfig.get_config_var('LIBDIR')
 218 if e is not None:
 219         print (e)
 220 EOD`
 221
 222                 # Now, for the library:
 223                 ac_python_library=`cat<<EOD | $PYTHON -
 224
 225 import distutils.sysconfig
 226 c = distutils.sysconfig.get_config_vars()
 227 if 'LDVERSION' in c:
 228         print ('python'+c[['LDVERSION']])
 229 else:
 230         print ('python'+c[['VERSION']])
 231 EOD`
 232
 233                 # This small piece shamelessly adapted from PostgreSQL python macro;
 234                 # credits goes to momjian, I think. I'd like to put the right name
 235                 # in the credits, if someone can point me in the right direction... ?
 236                 #
 237                 if test -n "$ac_python_libdir" -a -n "$ac_python_library"
 238                 then
 239                         # use the official shared library
 240                         ac_python_library=`echo "$ac_python_library" | sed "s/^lib//"`
 241                         PYTHON_LDFLAGS="-L$ac_python_libdir -l$ac_python_library"
 242                 else
 243                         # old way: use libpython from python_configdir
 244                         ac_python_libdir=`$PYTHON -c \
 245                           "from distutils.sysconfig import get_python_lib as f; \
 246                           import os; \
 247                           print (os.path.join(f(plat_specific=1, standard_lib=1), 'config'));"`
 248                         PYTHON_LDFLAGS="-L$ac_python_libdir -lpython$ac_python_version"
 249                 fi
 250
 251                 if test -z "PYTHON_LDFLAGS"; then
 252                         AC_MSG_WARN([
 253   Cannot determine location of your Python DSO. Please check it was installed with
 254   dynamic libraries enabled, or try setting PYTHON_LDFLAGS by hand.
 255                         ])
 256                         no_python_devel=yes
 257                 fi
 258         fi
 259         AC_MSG_RESULT([$PYTHON_LDFLAGS])
 260         AC_SUBST([PYTHON_LDFLAGS])
 261 ]) # AS_IF
 262
 263 AS_IF([test -z "$no_python_devel"], [
 264         #
 265         # Check for site packages
 266         #
 267         AC_MSG_CHECKING([for Python site-packages path])
 268         if test -z "$PYTHON_SITE_PKG"; then
 269                 PYTHON_SITE_PKG=`$PYTHON -c "import distutils.sysconfig; \
 270                         print (distutils.sysconfig.get_python_lib(0,0));"`
 271         fi
 272         AC_MSG_RESULT([$PYTHON_SITE_PKG])
 273         AC_SUBST([PYTHON_SITE_PKG])
 274
 275         #
 276         # libraries which must be linked in when embedding
 277         #
 278         AC_MSG_CHECKING(python extra libraries)
 279         if test -z "$PYTHON_EXTRA_LIBS"; then
 280            PYTHON_EXTRA_LIBS=`$PYTHON -c "import distutils.sysconfig; \
 281                 conf = distutils.sysconfig.get_config_var; \
 282                 print (conf('LIBS'))"`
 283         fi
 284         AC_MSG_RESULT([$PYTHON_EXTRA_LIBS])
 285         AC_SUBST(PYTHON_EXTRA_LIBS)
 286
 287         #
 288         # linking flags needed when embedding
 289         #
 290         AC_MSG_CHECKING(python extra linking flags)
 291         if test -z "$PYTHON_EXTRA_LDFLAGS"; then
 292                 PYTHON_EXTRA_LDFLAGS=`$PYTHON -c "import distutils.sysconfig; \
 293                         conf = distutils.sysconfig.get_config_var; \
 294                         print (conf('LINKFORSHARED'))"`
 295         fi
 296         AC_MSG_RESULT([$PYTHON_EXTRA_LDFLAGS])
 297         AC_SUBST(PYTHON_EXTRA_LDFLAGS)
 298
 299         #
 300         # final check to see if everything compiles alright
 301         #
 302         AC_MSG_CHECKING([consistency of all components of python development environment])
 303         # save current global flags
 304         ac_save_LIBS="$LIBS"
 305         ac_save_CPPFLAGS="$CPPFLAGS"
 306         LIBS="$ac_save_LIBS $PYTHON_LDFLAGS $PYTHON_EXTRA_LDFLAGS $PYTHON_EXTRA_LIBS"
 307         CPPFLAGS="$ac_save_CPPFLAGS $PYTHON_CPPFLAGS"
 308         AC_LANG_PUSH([C])
 309         AC_LINK_IFELSE([
 310                 AC_LANG_PROGRAM([[#include <Python.h>]],
 311                                 [[Py_Initialize();]])
 312                 ],[pythonexists=yes],[pythonexists=no])
 313         AC_LANG_POP([C])
 314         # turn back to default flags
 315         CPPFLAGS="$ac_save_CPPFLAGS"
 316         LIBS="$ac_save_LIBS"
 317
 318         AC_MSG_RESULT([$pythonexists])
 319
 320         if test ! "x$pythonexists" = "xyes"; then
 321            AC_MSG_WARN([
 322   Could not link test program to Python. Maybe the main Python library has been
 323   installed in some non-standard library path. If so, pass it to configure,
 324   via the LDFLAGS environment variable.
 325   Example: ./configure LDFLAGS="-L/usr/non-standard-path/python/lib"
 326   ============================================================================
 327    ERROR!
 328    You probably have to install the development version of the Python package
 329    for your distribution.  The exact name of this package varies among them.
 330   ============================================================================
 331            ])
 332           PYTHON_VERSION=""
 333           no_python_devel=yes
 334         fi
 335
 336         #
 337         # all done!
 338         #
 339 ]) # AS_IF
 340
 341 AS_IF([test -z "$no_python_devel"],
 342       [have_python_dev=yes], [have_python_dev=no])
 343
 344 ]) # AS_IF