m4/amversion.in

   1 ##                                                          -*- Autoconf -*-
   2 ## @configure_input@
   3 # Copyright (C) 2002, 2003, 2005, 2006, 2007, 2008, 2011 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 # serial 8
  11
  12 # AM_AUTOMAKE_VERSION(VERSION)
  13 # ----------------------------
  14 # Automake X.Y traces this macro to ensure aclocal.m4 has been
  15 # generated from the m4 files accompanying Automake X.Y.
  16 # (This private macro should not be called outside this file.)
  17 AC_DEFUN([AM_AUTOMAKE_VERSION],
  18 [am__api_version='@APIVERSION@'
  19 dnl Some users find AM_AUTOMAKE_VERSION and mistake it for a way to
  20 dnl require some minimum version.  Point them to the right macro.
  21 m4_if([$1], [@VERSION@], [],
  22       [AC_FATAL([Do not call $0, use AM_INIT_AUTOMAKE([$1]).])])dnl
  23 ])
  24
  25 # _AM_AUTOCONF_VERSION(VERSION)
  26 # -----------------------------
  27 # aclocal traces this macro to find the Autoconf version.
  28 # This is a private macro too.  Using m4_define simplifies
  29 # the logic in aclocal, which can simply ignore this definition.
  30 m4_define([_AM_AUTOCONF_VERSION], [])
  31
  32 # AM_SET_CURRENT_AUTOMAKE_VERSION
  33 # -------------------------------
  34 # Call AM_AUTOMAKE_VERSION and AM_AUTOMAKE_VERSION so they can be traced.
  35 # This function is AC_REQUIREd by AM_INIT_AUTOMAKE.
  36 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
  37 [AM_AUTOMAKE_VERSION([@VERSION@])dnl
  38 m4_ifndef([AC_AUTOCONF_VERSION],
  39   [m4_copy([m4_PACKAGE_VERSION], [AC_AUTOCONF_VERSION])])dnl
  40 _AM_AUTOCONF_VERSION(m4_defn([AC_AUTOCONF_VERSION]))])