libs/gst/net/meson.build

   1 gst_net_sources = [
   2   'gstnetaddressmeta.c',
   3   'gstnetclientclock.c',
   4   'gstnetcontrolmessagemeta.c',
   5   'gstnettimepacket.c',
   6   'gstnettimeprovider.c',
   7   'gstptpclock.c',
   8   'gstntppacket.c',
   9   'gstnetutils.c',
  10 ]
  11
  12 gst_net_headers = [
  13  'gstnet.h',
  14  'gstnetaddressmeta.h',
  15  'gstnetclientclock.h',
  16  'gstnetcontrolmessagemeta.h',
  17  'gstnettimepacket.h',
  18  'gstnettimeprovider.h',
  19  'gstptpclock.h',
  20  'net.h',
  21 ]
  22 install_headers(gst_net_headers, subdir : 'gstreamer-1.0/gst/net/')
  23
  24 if libtype != 'shared'
  25   gst_net_static = static_library('gstnet-@0@'.format(apiversion),
  26     gst_net_sources,
  27     c_args : gst_c_args,
  28     include_directories : [configinc, libsinc],
  29     install : true,
  30     dependencies : [gio_dep, gst_base_dep],
  31   )
  32   gst_net = gst_net_static
  33 endif
  34
  35 gst_net_gen_sources = []
  36 if libtype != 'static'
  37   gst_net_shared = shared_library('gstnet-@0@'.format(apiversion),
  38     gst_net_sources,
  39     c_args : gst_c_args,
  40     include_directories : [configinc, libsinc],
  41     version : libversion,
  42     soversion : soversion,
  43     install : true,
  44     dependencies : [gio_dep, gst_base_dep],
  45   )
  46   gst_net = gst_net_shared
  47   if build_gir
  48     gst_gir_extra_args = gir_init_section + [ '--c-include=gst/net/net.h' ]
  49     gst_net_gir = gnome.generate_gir(gst_net_shared,
  50       sources : gst_net_sources + gst_net_headers,
  51       namespace : 'GstNet',
  52       nsversion : apiversion,
  53       identifier_prefix : 'Gst',
  54       symbol_prefix : 'gst',
  55       export_packages : 'gstreamer-net-1.0',
  56       dependencies : [gst_base_dep],
  57       include_directories : [configinc, libsinc],
  58       includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gio-2.0', 'Gst-1.0'],
  59       install : true,
  60       extra_args : gst_gir_extra_args,
  61     )
  62     gst_net_gen_sources += [gst_net_gir]
  63   endif
  64 endif
  65
  66 gst_net_dep = declare_dependency(link_with : gst_net,
  67   include_directories : [libsinc],
  68   sources: gst_net_gen_sources,
  69   dependencies : [gst_base_dep])