libs/beast/CMakeLists.txt

   1 #
   2 # Copyright (c) 2016-2017 Vinnie Falco (vinnie dot falco at gmail dot com)
   3 #
   4 # Distributed under the Boost Software License, Version 1.0. (See accompanying
   5 # file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
   6 #
   7 # Official repository: https://github.com/boostorg/beast
   8 #
   9
  10 cmake_minimum_required (VERSION 3.5.1)
  11
  12 if (POLICY CMP0074)
  13     cmake_policy (SET CMP0074 NEW)
  14 endif()
  15
  16 #-------------------------------------------------------------------------------
  17
  18 function (DoGroupSources curdir rootdir folder)
  19     file (GLOB children RELATIVE ${PROJECT_SOURCE_DIR}/${curdir} ${PROJECT_SOURCE_DIR}/${curdir}/*)
  20     foreach (child ${children})
  21         if (IS_DIRECTORY ${PROJECT_SOURCE_DIR}/${curdir}/${child})
  22             DoGroupSources (${curdir}/${child} ${rootdir} ${folder})
  23         elseif (${child} STREQUAL "CMakeLists.txt")
  24             source_group("" FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
  25         else()
  26             string (REGEX REPLACE ^${rootdir} ${folder} groupname ${curdir})
  27             string (REPLACE "/" "\\" groupname ${groupname})
  28             source_group (${groupname} FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
  29         endif()
  30     endforeach()
  31 endfunction()
  32
  33 function (GroupSources curdir folder)
  34     DoGroupSources (${curdir} ${curdir} ${folder})
  35 endfunction()
  36
  37 #-------------------------------------------------------------------------------
  38 #
  39 # Beast
  40 #
  41 #-------------------------------------------------------------------------------
  42
  43 project (Beast VERSION 277)
  44
  45 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  46 option (Beast_BUILD_EXAMPLES "Build examples" ON)
  47 option (Beast_BUILD_TESTS "Build tests" ON)
  48
  49 if (MSVC)
  50     set (CMAKE_VERBOSE_MAKEFILE FALSE)
  51
  52     add_definitions (
  53         -D_WIN32_WINNT=0x0601
  54         -D_SCL_SECURE_NO_WARNINGS=1
  55         -D_CRT_SECURE_NO_WARNINGS=1
  56         -D_SILENCE_CXX17_ALLOCATOR_VOID_DEPRECATION_WARNING
  57         -D_SILENCE_CXX17_ADAPTOR_TYPEDEFS_DEPRECATION_WARNING
  58     )
  59
  60     add_compile_options(
  61         /bigobj       # large object file format
  62         /permissive-  # strict C++
  63         #/wd4503      # decorated name length exceeded, name was truncated
  64         /W4           # enable all warnings
  65         /MP           # Multi-processor compilation
  66         )
  67
  68     set (Boost_USE_STATIC_LIBS ON)
  69     set (Boost_USE_STATIC_RUNTIME ON)
  70
  71     set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
  72     set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /Ob2 /Oi /Ot /GL /MT")
  73     set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /Oi /Ot /MT")
  74
  75     set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
  76     set (CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG")
  77
  78     # for RelWithDebInfo builds, disable incremental linking
  79     # since CMake sets it ON by default for that build type and it
  80     # causes warnings
  81     #
  82     string (REPLACE "/INCREMENTAL" "/INCREMENTAL:NO" replacement_flags
  83         ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO})
  84     set (CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO ${replacement_flags})
  85
  86 else()
  87     set (THREADS_PREFER_PTHREAD_FLAG ON)
  88     find_package (Threads)
  89
  90     set( CMAKE_CXX_FLAGS
  91       "${CMAKE_CXX_FLAGS} -std=c++11 -Wall -Wextra -Wpedantic -Wno-unused-parameter")
  92
  93     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  94         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wrange-loop-analysis")
  95     endif ()
  96 endif()
  97
  98 # Must come before Boost includes, otherwise the
  99 # IDE sees the wrong file due to boost/ symlinks.
 100 include_directories (include)
 101
 102 #-------------------------------------------------------------------------------
 103 #
 104 # OpenSSL
 105 #
 106 #-------------------------------------------------------------------------------
 107
 108 if (APPLE AND NOT DEFINED ENV{OPENSSL_ROOT_DIR})
 109   find_program(HOMEBREW brew)
 110   if (NOT HOMEBREW STREQUAL "HOMEBREW-NOTFOUND")
 111     execute_process(COMMAND brew --prefix openssl
 112       OUTPUT_VARIABLE OPENSSL_ROOT_DIR
 113       OUTPUT_STRIP_TRAILING_WHITESPACE)
 114   endif()
 115 endif()
 116
 117 find_package(OpenSSL)
 118
 119 #-------------------------------------------------------------------------------
 120 #
 121 # Boost
 122 #
 123 #-------------------------------------------------------------------------------
 124
 125 get_filename_component (BOOST_ROOT ../../ ABSOLUTE)
 126
 127 # VFALCO I want static but "b2 stage" builds a minimal set which excludes static
 128 add_definitions (-DBOOST_ALL_STATIC_LINK=1)
 129
 130 add_definitions (-DBOOST_ASIO_NO_DEPRECATED=1)
 131 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_ARRAY=1)
 132 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_BIND=1)
 133 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_DATE_TIME=1)
 134 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_REGEX=1)
 135 add_definitions (-DBOOST_COROUTINES_NO_DEPRECATION_WARNING=1)
 136
 137 include_directories (${BOOST_ROOT})
 138
 139 link_directories(${BOOST_ROOT}/stage/lib)
 140
 141 if (MINGW)
 142     link_libraries(ws2_32 mswsock)
 143 endif()
 144
 145 #-------------------------------------------------------------------------------
 146
 147 if ("${VARIANT}" STREQUAL "coverage")
 148     if (MSVC)
 149     else()
 150         set (CMAKE_BUILD_TYPE DEBUG)
 151         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -msse4.2 --coverage")
 152         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 153     endif()
 154
 155 elseif ("${VARIANT}" STREQUAL "ubasan")
 156     if (MSVC)
 157     else()
 158         set (CMAKE_BUILD_TYPE RELWITHDEBINFO)
 159         set (CMAKE_CXX_FLAGS
 160           "${CMAKE_CXX_FLAGS} -DBOOST_BEAST_NO_SLOW_TESTS=1 -msse4.2 -funsigned-char -fno-omit-frame-pointer -fsanitize=address,undefined -fno-sanitize-recover=address,undefined -fsanitize-blacklist=${PROJECT_SOURCE_DIR}/tools/blacklist.supp")
 161         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,undefined -fno-sanitize-recover=address,undefined")
 162     endif()
 163
 164 elseif ("${VARIANT}" STREQUAL "debug")
 165     set (CMAKE_BUILD_TYPE DEBUG)
 166
 167 elseif ("${VARIANT}" STREQUAL "release")
 168     set (CMAKE_BUILD_TYPE RELEASE)
 169
 170 endif()
 171
 172 #-------------------------------------------------------------------------------
 173 #
 174 # Static Libraries
 175 #
 176 #-------------------------------------------------------------------------------
 177
 178 add_definitions (-DBOOST_ASIO_SEPARATE_COMPILATION=1)
 179 add_definitions (-DBOOST_BEAST_SEPARATE_COMPILATION=1)
 180
 181 GroupSources (test "/")
 182
 183 add_library (
 184     lib-asio STATIC
 185     test/lib_asio.cpp
 186 )
 187
 188 set_property(TARGET lib-asio PROPERTY FOLDER "static-libs")
 189
 190 add_library (
 191     lib-asio-ssl STATIC
 192     test/lib_asio_ssl.cpp
 193 )
 194
 195 set_property(TARGET lib-asio-ssl PROPERTY FOLDER "static-libs")
 196
 197 add_library (
 198     lib-beast STATIC
 199     test/lib_beast.cpp
 200 )
 201
 202 set_property(TARGET lib-beast PROPERTY FOLDER "static-libs")
 203
 204 target_link_libraries(lib-asio lib-beast)
 205
 206 #-------------------------------------------------------------------------------
 207 #
 208 # Tests and examples
 209 #
 210
 211 include_directories (.)
 212
 213 if (OPENSSL_FOUND)
 214     include_directories (${OPENSSL_INCLUDE_DIR})
 215 endif()
 216
 217 file (GLOB_RECURSE BOOST_BEAST_FILES
 218     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.hpp
 219     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.ipp
 220 )
 221
 222 file (GLOB_RECURSE BOOST_BEAST_EXPERIMENTAL_FILES
 223     ${PROJECT_SOURCE_DIR}/include/boost/beast/_experimental/*.hpp
 224     ${PROJECT_SOURCE_DIR}/include/boost/beast/_experimental/*.ipp
 225 )
 226
 227 file (GLOB_RECURSE COMMON_FILES
 228     ${PROJECT_SOURCE_DIR}/example/common/*.hpp
 229   )
 230
 231 if (Beast_BUILD_EXAMPLES AND
 232     (NOT "${VARIANT}" STREQUAL "coverage") AND
 233     (NOT "${VARIANT}" STREQUAL "ubasan"))
 234     add_subdirectory (example)
 235 endif()
 236
 237 if (Beast_BUILD_TESTS)
 238     add_subdirectory (test)
 239 endif()