libitm/acinclude.m4

   1 dnl ----------------------------------------------------------------------
   2 dnl This whole bit snagged from libgfortran.
   3
   4 dnl Check whether the target supports __sync_*_compare_and_swap.
   5 AC_DEFUN([LIBITM_CHECK_SYNC_BUILTINS], [
   6   AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
   7                  libitm_cv_have_sync_builtins, [
   8   AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
   9               libitm_cv_have_sync_builtins=yes, libitm_cv_have_sync_builtins=no)])
  10   if test $libitm_cv_have_sync_builtins = yes; then
  11     AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
  12               [Define to 1 if the target supports __sync_*_compare_and_swap])
  13   fi])
  14
  15 dnl Check whether the target supports 64-bit __sync_*_compare_and_swap.
  16 AC_DEFUN([LIBITM_CHECK_64BIT_SYNC_BUILTINS], [
  17   AC_CACHE_CHECK([whether the target supports 64-bit __sync_*_compare_and_swap],
  18                  libitm_cv_have_64bit_sync_builtins, [
  19   AC_TRY_LINK([#include <stdint.h>],
  20     [uint64_t foo, bar;
  21      bar = __sync_val_compare_and_swap(&foo, 0, 1);],
  22     libitm_cv_have_64bit_sync_builtins=yes,
  23     libitm_cv_have_64bit_sync_builtins=no)])
  24     if test $libitm_cv_have_64bit_sync_builtins = yes; then
  25       AC_DEFINE(HAVE_64BIT_SYNC_BUILTINS, 1,
  26                 [Define to 1 if the target supports 64-bit __sync_*_compare_and_swap])
  27   fi])
  28
  29 dnl Check whether the target supports hidden visibility.
  30 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_VISIBILITY], [
  31   AC_CACHE_CHECK([whether the target supports hidden visibility],
  32                  libitm_cv_have_attribute_visibility, [
  33   save_CFLAGS="$CFLAGS"
  34   CFLAGS="$CFLAGS -Werror"
  35   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
  36                  [], libitm_cv_have_attribute_visibility=yes,
  37                  libitm_cv_have_attribute_visibility=no)
  38   CFLAGS="$save_CFLAGS"])
  39   if test $libitm_cv_have_attribute_visibility = yes; then
  40     AC_DEFINE(HAVE_ATTRIBUTE_VISIBILITY, 1,
  41       [Define to 1 if the target supports __attribute__((visibility(...))).])
  42   fi])
  43
  44 dnl Check whether the target supports dllexport
  45 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_DLLEXPORT], [
  46   AC_CACHE_CHECK([whether the target supports dllexport],
  47                  libitm_cv_have_attribute_dllexport, [
  48   save_CFLAGS="$CFLAGS"
  49   CFLAGS="$CFLAGS -Werror"
  50   AC_TRY_COMPILE([void __attribute__((dllexport)) foo(void) { }],
  51                  [], libitm_cv_have_attribute_dllexport=yes,
  52                  libitm_cv_have_attribute_dllexport=no)
  53   CFLAGS="$save_CFLAGS"])
  54   if test $libitm_cv_have_attribute_dllexport = yes; then
  55     AC_DEFINE(HAVE_ATTRIBUTE_DLLEXPORT, 1,
  56       [Define to 1 if the target supports __attribute__((dllexport)).])
  57   fi])
  58
  59 dnl Check whether the target supports symbol aliases.
  60 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_ALIAS], [
  61   AC_CACHE_CHECK([whether the target supports symbol aliases],
  62                  libitm_cv_have_attribute_alias, [
  63   AC_TRY_LINK([
  64 void foo(void) { }
  65 extern void bar(void) __attribute__((alias("foo")));],
  66     [bar();], libitm_cv_have_attribute_alias=yes, libitm_cv_have_attribute_alias=no)])
  67   if test $libitm_cv_have_attribute_alias = yes; then
  68     AC_DEFINE(HAVE_ATTRIBUTE_ALIAS, 1,
  69       [Define to 1 if the target supports __attribute__((alias(...))).])
  70   fi])
  71
  72 dnl Check how size_t is mangled.
  73 AC_DEFUN([LIBITM_CHECK_SIZE_T_MANGLING], [
  74   AC_CACHE_CHECK([how size_t is mangled],
  75                  libitm_cv_size_t_mangling, [
  76     AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned long x;],
  77                    [libitm_cv_size_t_mangling=m], [
  78       AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned int x;],
  79                      [libitm_cv_size_t_mangling=j], [
  80         AC_TRY_COMPILE([],
  81                        [extern __SIZE_TYPE__ x; extern unsigned long long x;],
  82                        [libitm_cv_size_t_mangling=y], [
  83           AC_TRY_COMPILE([],
  84                          [extern __SIZE_TYPE__ x; extern unsigned short x;],
  85                          [libitm_cv_size_t_mangling=t],
  86                          [libitm_cv_size_t_mangling=x])
  87         ])
  88       ])
  89     ])
  90   ])
  91   if test $libitm_cv_size_t_mangling = x; then
  92     AC_MSG_ERROR([Unknown underlying type for size_t])
  93   fi
  94   AC_DEFINE_UNQUOTED(MANGLE_SIZE_T, [$libitm_cv_size_t_mangling],
  95     [Define to the letter to which size_t is mangled.])
  96 ])
  97
  98 dnl Check if as supports AVX instructions.
  99 AC_DEFUN([LIBITM_CHECK_AS_AVX], [
 100 case "${target_cpu}" in
 101 i[[34567]]86 | x86_64)
 102   AC_CACHE_CHECK([if the assembler supports AVX], libitm_cv_as_avx, [
 103     AC_TRY_COMPILE([], [asm("vzeroupper");],
 104                    [libitm_cv_as_avx=yes], [libitm_cv_as_avx=no])
 105   ])
 106   if test x$libitm_cv_as_avx = xyes; then
 107     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 108   fi
 109   ;;
 110 esac])
 111
 112 dnl Check if as supports RTM instructions.
 113 AC_DEFUN([LIBITM_CHECK_AS_RTM], [
 114 case "${target_cpu}" in
 115 i[[34567]]86 | x86_64)
 116   AC_CACHE_CHECK([if the assembler supports RTM], libitm_cv_as_rtm, [
 117     AC_TRY_COMPILE([], [asm("1: xbegin 1b; xend");],
 118                    [libitm_cv_as_rtm=yes], [libitm_cv_as_rtm=no])
 119   ])
 120   if test x$libitm_cv_as_rtm = xyes; then
 121     AC_DEFINE(HAVE_AS_RTM, 1, [Define to 1 if the assembler supports RTM.])
 122   fi
 123   ;;
 124 s390*)
 125   AC_CACHE_CHECK([if the assembler supports HTM], libitm_cv_as_htm, [
 126     save_CFLAGS="$CFLAGS"
 127     CFLAGS="$CFLAGS -march=zEC12"
 128     AC_TRY_COMPILE([], [asm("tbegin 0,0; tend");],
 129                    [libitm_cv_as_htm=yes], [libitm_cv_as_htm=no])
 130     CFLAGS="$save_CFLAGS"])
 131   if test x$libitm_cv_as_htm = xyes; then
 132     AC_DEFINE(HAVE_AS_HTM, 1, [Define to 1 if the assembler supports HTM.])
 133   fi
 134   ;;
 135 esac])
 136
 137 sinclude(../libtool.m4)
 138 dnl The lines below arrange for aclocal not to bring an installed
 139 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
 140 dnl add a definition of LIBTOOL to Makefile.in.
 141 ifelse(,,,[AC_SUBST(LIBTOOL)
 142 AC_DEFUN([AM_PROG_LIBTOOL])
 143 AC_DEFUN([AC_LIBTOOL_DLOPEN])
 144 AC_DEFUN([AC_PROG_LD])
 145 ])
 146
 147 dnl ----------------------------------------------------------------------
 148 dnl This whole bit snagged from libstdc++-v3.
 149
 150 dnl
 151 dnl LIBITM_ENABLE
 152 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 153 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 154 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 155 dnl
 156 dnl See docs/html/17_intro/configury.html#enable for documentation.
 157 dnl
 158 m4_define([LIBITM_ENABLE],[dnl
 159 m4_define([_g_switch],[--enable-$1])dnl
 160 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 161  AC_ARG_ENABLE($1,_g_help,
 162   m4_bmatch([$5],
 163    [^permit ],
 164      [[
 165       case "$enableval" in
 166        m4_bpatsubst([$5],[permit ])) ;;
 167        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 168           dnl Idea for future:  generate a URL pointing to
 169           dnl "onlinedocs/configopts.html#whatever"
 170       esac
 171      ]],
 172    [^$],
 173      [[
 174       case "$enableval" in
 175        yes|no) ;;
 176        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 177       esac
 178      ]],
 179    [[$5]]),
 180   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 181 m4_undefine([_g_switch])dnl
 182 m4_undefine([_g_help])dnl
 183 ])
 184
 185
 186 dnl
 187 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 188 dnl the native linker is in use, all variables will be defined to something
 189 dnl safe (like an empty string).
 190 dnl
 191 dnl Defines:
 192 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 193 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 194 dnl  LD (as a side effect of testing)
 195 dnl Sets:
 196 dnl  with_gnu_ld
 197 dnl  libitm_ld_is_gold (possibly)
 198 dnl  libitm_gnu_ld_version (possibly)
 199 dnl
 200 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 201 dnl set libitm_gnu_ld_version to 12345.  Zeros cause problems.
 202 dnl
 203 AC_DEFUN([LIBITM_CHECK_LINKER_FEATURES], [
 204   # If we're not using GNU ld, then there's no point in even trying these
 205   # tests.  Check for that first.  We should have already tested for gld
 206   # by now (in libtool), but require it now just to be safe...
 207   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 208   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 209   AC_REQUIRE([AC_PROG_LD])
 210   AC_REQUIRE([AC_PROG_AWK])
 211
 212   # The name set by libtool depends on the version of libtool.  Shame on us
 213   # for depending on an impl detail, but c'est la vie.  Older versions used
 214   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 215   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 216   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 217   # set (hence we're using an older libtool), then set it.
 218   if test x${with_gnu_ld+set} != xset; then
 219     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 220       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 221       with_gnu_ld=no
 222     else
 223       with_gnu_ld=$ac_cv_prog_gnu_ld
 224     fi
 225   fi
 226
 227   # Start by getting the version number.  I think the libtool test already
 228   # does some of this, but throws away the result.
 229   libitm_ld_is_gold=no
 230   if $LD --version 2>/dev/null | grep 'GNU gold'> /dev/null 2>&1; then
 231     libitm_ld_is_gold=yes
 232   fi
 233   changequote(,)
 234   ldver=`$LD --version 2>/dev/null |
 235          sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 236   changequote([,])
 237   libitm_gnu_ld_version=`echo $ldver | \
 238          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 239
 240   # Set --gc-sections.
 241   if test "$with_gnu_ld" = "notbroken"; then
 242     # GNU ld it is!  Joy and bunny rabbits!
 243
 244     # All these tests are for C++; save the language and the compiler flags.
 245     # Need to do this so that g++ won't try to link in libstdc++
 246     ac_test_CFLAGS="${CFLAGS+set}"
 247     ac_save_CFLAGS="$CFLAGS"
 248     CFLAGS='-x c++  -Wl,--gc-sections'
 249
 250     # Check for -Wl,--gc-sections
 251     # XXX This test is broken at the moment, as symbols required for linking
 252     # are now in libsupc++ (not built yet).  In addition, this test has
 253     # cored on solaris in the past.  In addition, --gc-sections doesn't
 254     # really work at the moment (keeps on discarding used sections, first
 255     # .eh_frame and now some of the glibc sections for iconv).
 256     # Bzzzzt.  Thanks for playing, maybe next time.
 257     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 258     AC_TRY_RUN([
 259      int main(void)
 260      {
 261        try { throw 1; }
 262        catch (...) { };
 263        return 0;
 264      }
 265     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 266     if test "$ac_test_CFLAGS" = set; then
 267       CFLAGS="$ac_save_CFLAGS"
 268     else
 269       # this is the suspicious part
 270       CFLAGS=''
 271     fi
 272     if test "$ac_sectionLDflags" = "yes"; then
 273       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 274     fi
 275     AC_MSG_RESULT($ac_sectionLDflags)
 276   fi
 277
 278   # Set linker optimization flags.
 279   if test x"$with_gnu_ld" = x"yes"; then
 280     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 281   fi
 282
 283   AC_SUBST(SECTION_LDFLAGS)
 284   AC_SUBST(OPT_LDFLAGS)
 285 ])
 286
 287
 288 dnl
 289 dnl Check if the linker used supports linker maps to clear hardware
 290 dnl capabilities.  This is only supported by Sun ld at the moment.
 291 dnl
 292 dnl Defines:
 293 dnl  HWCAP_LDFLAGS='-Wl,-M,clearcap.map' if possible
 294 dnl  LD (as a side effect of testing)
 295 dnl
 296 AC_DEFUN([LIBITM_CHECK_LINKER_HWCAP], [
 297   test -z "$HWCAP_LDFLAGS" && HWCAP_LDFLAGS=''
 298   AC_REQUIRE([AC_PROG_LD])
 299
 300   ac_save_LDFLAGS="$LDFLAGS"
 301   LDFLAGS="$LFLAGS -Wl,-M,$srcdir/clearcap.map"
 302
 303   AC_MSG_CHECKING([for ld that supports -Wl,-M,mapfile])
 304   AC_TRY_LINK([], [return 0;], [ac_hwcap_ldflags=yes],[ac_hwcap_ldflags=no])
 305   if test "$ac_hwcap_ldflags" = "yes"; then
 306     HWCAP_LDFLAGS="-Wl,-M,$srcdir/clearcap.map $HWCAP_LDFLAGS"
 307   fi
 308   AC_MSG_RESULT($ac_hwcap_ldflags)
 309
 310   LDFLAGS="$ac_save_LDFLAGS"
 311
 312   AC_SUBST(HWCAP_LDFLAGS)
 313
 314   AM_CONDITIONAL(HAVE_HWCAP, test $ac_hwcap_ldflags != no)
 315 ])
 316
 317
 318 dnl
 319 dnl Add version tags to symbols in shared library (or not), additionally
 320 dnl marking other symbols as private/local (or not).
 321 dnl
 322 dnl --enable-symvers=style adds a version script to the linker call when
 323 dnl       creating the shared library.  The choice of version script is
 324 dnl       controlled by 'style'.
 325 dnl --disable-symvers does not.
 326 dnl  +  Usage:  LIBITM_ENABLE_SYMVERS[(DEFAULT)]
 327 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
 328 dnl       choose a default style based on linker characteristics.  Passing
 329 dnl       'no' disables versioning.
 330 dnl
 331 AC_DEFUN([LIBITM_ENABLE_SYMVERS], [
 332
 333 LIBITM_ENABLE(symvers,yes,[=STYLE],
 334   [enables symbol versioning of the shared library],
 335   [permit yes|no|gnu*|sun])
 336
 337 # If we never went through the LIBITM_CHECK_LINKER_FEATURES macro, then we
 338 # don't know enough about $LD to do tricks...
 339 AC_REQUIRE([LIBITM_CHECK_LINKER_FEATURES])
 340
 341 # Turn a 'yes' into a suitable default.
 342 if test x$enable_symvers = xyes ; then
 343   # FIXME  The following test is too strict, in theory.
 344   if test $enable_shared = no || test "x$LD" = x; then
 345     enable_symvers=no
 346   else
 347     if test $with_gnu_ld = yes ; then
 348       enable_symvers=gnu
 349     else
 350       case ${target_os} in
 351         # Sun symbol versioning exists since Solaris 2.5.
 352         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
 353           enable_symvers=sun ;;
 354         *)
 355           enable_symvers=no ;;
 356       esac
 357     fi
 358   fi
 359 fi
 360
 361 # Check if 'sun' was requested on non-Solaris 2 platforms.
 362 if test x$enable_symvers = xsun ; then
 363   case ${target_os} in
 364     solaris2*)
 365       # All fine.
 366       ;;
 367     *)
 368       # Unlikely to work.
 369       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
 370       AC_MSG_WARN([=== you are not targetting Solaris 2.])
 371       AC_MSG_WARN([=== Symbol versioning will be disabled.])
 372       enable_symvers=no
 373       ;;
 374   esac
 375 fi
 376
 377 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
 378 if test $enable_symvers != no; then
 379   AC_MSG_CHECKING([for shared libgcc])
 380   ac_save_CFLAGS="$CFLAGS"
 381   CFLAGS=' -lgcc_s'
 382   AC_TRY_LINK(, [return 0;], libitm_shared_libgcc=yes, libitm_shared_libgcc=no)
 383   CFLAGS="$ac_save_CFLAGS"
 384   if test $libitm_shared_libgcc = no; then
 385     cat > conftest.c <<EOF
 386 int main (void) { return 0; }
 387 EOF
 388 changequote(,)dnl
 389     libitm_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 390                              -shared -shared-libgcc -o conftest.so \
 391                              conftest.c -v 2>&1 >/dev/null \
 392                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
 393 changequote([,])dnl
 394     rm -f conftest.c conftest.so
 395     if test x${libitm_libgcc_s_suffix+set} = xset; then
 396       CFLAGS=" -lgcc_s$libitm_libgcc_s_suffix"
 397       AC_TRY_LINK(, [return 0;], libitm_shared_libgcc=yes)
 398       CFLAGS="$ac_save_CFLAGS"
 399     fi
 400   fi
 401   AC_MSG_RESULT($libitm_shared_libgcc)
 402 fi
 403
 404 # For GNU ld, we need at least this version.  The format is described in
 405 # LIBITM_CHECK_LINKER_FEATURES above.
 406 libitm_min_gnu_ld_version=21400
 407 # XXXXXXXXXXX libitm_gnu_ld_version=21390
 408
 409 # Check to see if unspecified "yes" value can win, given results above.
 410 # Change "yes" into either "no" or a style name.
 411 if test $enable_symvers != no && test $libitm_shared_libgcc = yes; then
 412   if test $with_gnu_ld = yes; then
 413     if test $libitm_gnu_ld_version -ge $libitm_min_gnu_ld_version ; then
 414       enable_symvers=gnu
 415     elif test $libitm_ld_is_gold = yes ; then
 416       enable_symvers=gnu
 417     else
 418       # The right tools, the right setup, but too old.  Fallbacks?
 419       AC_MSG_WARN(=== Linker version $libitm_gnu_ld_version is too old for)
 420       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
 421       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
 422       AC_MSG_WARN(=== $libitm_min_gnu_ld_version or later and rebuild GCC.)
 423       if test $libitm_gnu_ld_version -ge 21200 ; then
 424         # Globbing fix is present, proper block support is not.
 425         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
 426         dnl enable_symvers=???
 427         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 428         enable_symvers=no
 429       else
 430         # 2.11 or older.
 431         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 432         enable_symvers=no
 433       fi
 434     fi
 435   elif test $enable_symvers = sun; then
 436     : All interesting versions of Sun ld support sun style symbol versioning.
 437   else
 438     # just fail for now
 439     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
 440     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
 441     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
 442     AC_MSG_WARN([=== Symbol versioning will be disabled.])
 443     enable_symvers=no
 444   fi
 445 fi
 446
 447 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
 448 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB_GNU, test $enable_symvers = gnu)
 449 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB_SUN, test $enable_symvers = sun)
 450 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
 451 ])