libdecnumber/configure.ac

   1 # configure.ac for libdecnumber                 -*- Autoconf -*-
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 2005-2013 Free Software Foundation, Inc.
   5
   6 # This file is part of GCC.
   7
   8 # GCC is free software; you can redistribute it and/or modify it under
   9 # the terms of the GNU General Public License as published by the Free
  10 # Software Foundation; either version 3, or (at your option) any
  11 # later #version.
  12
  13 # GCC is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  16 # License #for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with GCC; see the file COPYING3.  If not see
  20 # <http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.64)
  23 AC_INIT(libdecnumber, [ ], gcc-bugs@gcc.gnu.org, libdecnumber)
  24 AC_CONFIG_SRCDIR(decNumber.h)
  25 AC_CONFIG_MACRO_DIR(../config)
  26 AC_CONFIG_AUX_DIR(..)
  27
  28 # Checks for programs.
  29 AC_PROG_MAKE_SET
  30 AC_PROG_CC
  31 AC_PROG_RANLIB
  32
  33 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  34 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  35 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  36 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  37
  38 # Figure out what compiler warnings we can enable.
  39 # See config/warnings.m4 for details.
  40
  41 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  42                           -Wmissing-prototypes -Wold-style-definition \
  43                           -Wmissing-format-attribute -Wcast-qual])
  44 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  45
  46 # Only enable with --enable-werror-always until existing warnings are
  47 # corrected.
  48 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  49
  50 # Checks for header files.
  51 AC_CHECK_HEADERS(ctype.h stddef.h string.h stdio.h)
  52 GCC_HEADER_STDINT(gstdint.h)
  53
  54 # Checks for typedefs, structures, and compiler characteristics.
  55 AC_C_CONST
  56 AC_TYPE_OFF_T
  57 AC_CHECK_SIZEOF(int)
  58 AC_CHECK_SIZEOF(long)
  59
  60 # Checks for library functions.
  61 AC_HEADER_STDC
  62
  63 AC_ARG_ENABLE(maintainer-mode,
  64 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  65 enable_maintainer_mode=no)
  66
  67 if test "x$enable_maintainer_mode" = xno; then
  68   MAINT='#'
  69 else
  70   MAINT=
  71 fi
  72 AC_SUBST(MAINT)
  73
  74 AC_CANONICAL_TARGET
  75
  76 # Default decimal format
  77 # If you change the defaults here, be sure to change them in the GCC directory also
  78 AC_MSG_CHECKING([for decimal floating point])
  79
  80 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
  81
  82 # Use default_decimal_float for dependency.
  83 enable_decimal_float=$default_decimal_float
  84
  85 # If BID is being used, additional objects should be linked in.
  86 if test x$enable_decimal_float = xbid; then
  87   ADDITIONAL_OBJS="$ADDITIONAL_OBJS \$(bid_OBJS)"
  88 else
  89   ADDITIONAL_OBJS=
  90 fi
  91
  92 AC_MSG_RESULT($enable_decimal_float)
  93 AC_SUBST(enable_decimal_float)
  94 AC_SUBST(ADDITIONAL_OBJS)
  95
  96 AC_C_BIGENDIAN
  97
  98 # Enable --enable-host-shared.
  99 AC_ARG_ENABLE(host-shared,
 100 [AS_HELP_STRING([--enable-host-shared],
 101                 [build host code as shared libraries])],
 102 [PICFLAG=-fPIC], [PICFLAG=])
 103 AC_SUBST(PICFLAG)
 104
 105 # Output.
 106
 107 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 108 AC_CONFIG_FILES(Makefile)
 109 AC_OUTPUT