libatomic/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2 #  Copyright (C) 2012 Free Software Foundation, Inc.
   3 #
   4 #  This file is part of the GNU Atomic Library (libatomic).
   5 #
   6 #  Libatomic is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU General Public License as published by
   8 #  the Free Software Foundation; either version 3 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  Libatomic is distributed in the hope that it will be useful, but WITHOUT ANY
  12 #  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 #  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  14 #  more details.
  15 #
  16 #  Under Section 7 of GPL version 3, you are granted additional
  17 #  permissions described in the GCC Runtime Library Exception, version
  18 #  3.1, as published by the Free Software Foundation.
  19 #
  20 #  You should have received a copy of the GNU General Public License and
  21 #  a copy of the GCC Runtime Library Exception along with this program;
  22 #  see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  23 #  <http://www.gnu.org/licenses/>.
  24
  25 AC_PREREQ(2.59)
  26 AC_INIT([GNU Atomic Library], 1.0,,[libatomic])
  27 AC_CONFIG_HEADER(auto-config.h)
  28
  29 # -------
  30 # Options
  31 # -------
  32
  33 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  34 LIBAT_ENABLE(version-specific-runtime-libs, no, ,
  35    [Specify that runtime libraries should be installed in a compiler-specific directory],
  36    permit yes|no)
  37 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  38
  39 # We would like our source tree to be readonly. However when releases or
  40 # pre-releases are generated, the flex/bison generated files as well as the
  41 # various formats of manuals need to be included along with the rest of the
  42 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  43 # just that.
  44 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  45 LIBAT_ENABLE(generated-files-in-srcdir, no, ,
  46    [put copies of generated files in source dir intended for creating source
  47     tarballs for users without texinfo bison or flex.],
  48    permit yes|no)
  49 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  50 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  51
  52
  53 # -------
  54
  55 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  56 #
  57 # You will slowly go insane if you do not grok the following fact:  when
  58 # building this library, the top-level /target/ becomes the library's /host/.
  59 #
  60 # configure then causes --target to default to --host, exactly like any
  61 # other package using autoconf.  Therefore, 'target' and 'host' will
  62 # always be the same.  This makes sense both for native and cross compilers
  63 # just think about it for a little while.  :-)
  64 #
  65 # Also, if this library is being configured as part of a cross compiler, the
  66 # top-level configure script will pass the "real" host as $with_cross_host.
  67 #
  68 # Do not delete or change the following two lines.  For why, see
  69 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  70 AC_CANONICAL_SYSTEM
  71 target_alias=${target_alias-$host_alias}
  72
  73 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  74 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  75 #  1.9.0:  minimum required version
  76 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  77 #              of other PACKAGE_* variables will, however, and there's nothing
  78 #              we can do about that; they come from AC_INIT).
  79 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  80 #            file in the top srcdir, etc, etc), so stop complaining.
  81 #  -Wall:  turns on all automake warnings...
  82 #  -Wno-portability:  ...except this one, since GNU make is required.
  83 #  -Wno-override: ... and this one, since we do want this in testsuite.
  84 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  85 AM_ENABLE_MULTILIB(, ..)
  86
  87 # Calculate toolexeclibdir
  88 # Also toolexecdir, though it's only used in toolexeclibdir
  89 case ${enable_version_specific_runtime_libs} in
  90   yes)
  91     # Need the gcc compiler version to know where to install libraries
  92     # and header files if --enable-version-specific-runtime-libs option
  93     # is selected.
  94     toolexecdir='$(libdir)/gcc/$(target_alias)'
  95     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  96     ;;
  97   no)
  98     if test -n "$with_cross_host" &&
  99        test x"$with_cross_host" != x"no"; then
 100       # Install a library built with a cross compiler in tooldir, not libdir.
 101       toolexecdir='$(exec_prefix)/$(target_alias)'
 102       toolexeclibdir='$(toolexecdir)/lib'
 103     else
 104       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 105       toolexeclibdir='$(libdir)'
 106     fi
 107     multi_os_directory=`$CC -print-multi-os-directory`
 108     case $multi_os_directory in
 109       .) ;; # Avoid trailing /.
 110       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 111     esac
 112     ;;
 113 esac
 114 AC_SUBST(toolexecdir)
 115 AC_SUBST(toolexeclibdir)
 116
 117 # Check the compiler.
 118 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 119 # We must force CC to /not/ be precious variables; otherwise
 120 # the wrong, non-multilib-adjusted value will be used in multilibs.
 121 # As a side effect, we have to subst CFLAGS ourselves.
 122
 123 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 124 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 125 AC_PROG_CC
 126 AM_PROG_AS
 127 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 128
 129 AC_SUBST(CFLAGS)
 130
 131 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 132 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 133 # in both places for now and restore CFLAGS at the end of config.
 134 save_CFLAGS="$CFLAGS"
 135
 136 # Find other programs we need.
 137 AC_CHECK_TOOL(AR, ar)
 138 AC_CHECK_TOOL(NM, nm)
 139 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 140 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 141 AC_PROG_INSTALL
 142
 143 # Configure libtool
 144 AM_PROG_LIBTOOL
 145 AC_SUBST(enable_shared)
 146 AC_SUBST(enable_static)
 147
 148 # For libtool versioning info, format is CURRENT:REVISION:AGE
 149 libtool_VERSION=1:0:0
 150 AC_SUBST(libtool_VERSION)
 151
 152 # Get target configury.
 153 . ${srcdir}/configure.tgt
 154 if test -n "$UNSUPPORTED"; then
 155   AC_MSG_ERROR([Configuration ${target} is unsupported.])
 156 fi
 157
 158 # Disable fallbacks to __sync routines from libgcc.  Otherwise we'll
 159 # make silly decisions about what the cpu can do.
 160 CFLAGS="$save_CFLAGS -fno-sync-libcalls $XCFLAGS"
 161
 162 # Check header files.
 163 AC_STDC_HEADERS
 164 ACX_HEADER_STRING
 165 GCC_HEADER_STDINT(gstdint.h)
 166
 167 # Check for common type sizes
 168 LIBAT_FORALL_MODES([LIBAT_HAVE_INT_MODE])
 169
 170 # Check for compiler builtins of atomic operations.
 171 LIBAT_TEST_ATOMIC_INIT
 172 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_LOADSTORE])
 173 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_TAS])
 174 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_EXCHANGE])
 175 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_CAS])
 176 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_ADD])
 177 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_OP])
 178
 179 AC_C_BIGENDIAN
 180 # I don't like the default behaviour of WORDS_BIGENDIAN undefined for LE.
 181 AH_BOTTOM(
 182 [#ifndef WORDS_BIGENDIAN
 183 #define WORDS_BIGENDIAN 0
 184 #endif])
 185
 186 LIBAT_WORDSIZE
 187
 188 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 189 # In case the pthread.h system header is not found, this test will fail.
 190 case " $config_path " in
 191  *" posix "*)
 192   XPCFLAGS=""
 193   CFLAGS="$CFLAGS -pthread"
 194   AC_LINK_IFELSE(
 195     [AC_LANG_PROGRAM(
 196      [#include <pthread.h>
 197       void *g(void *d) { return NULL; }],
 198      [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 199     [XPCFLAGS=" -pthread"],
 200     [CFLAGS="$save_CFLAGS $XCFLAGS" LIBS="-lpthread $LIBS"
 201      AC_LINK_IFELSE(
 202       [AC_LANG_PROGRAM(
 203        [#include <pthread.h>
 204         void *g(void *d) { return NULL; }],
 205        [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 206       [],
 207       [AC_MSG_ERROR([Pthreads are required to build libatomic])])])
 208   CFLAGS="$save_CFLAGS $XCFLAGS"
 209   ;;
 210 esac
 211
 212 # See what sort of export controls are available.
 213 LIBAT_CHECK_ATTRIBUTE_VISIBILITY
 214 LIBAT_CHECK_ATTRIBUTE_DLLEXPORT
 215 LIBAT_CHECK_ATTRIBUTE_ALIAS
 216 if test x$try_ifunc = xyes; then
 217   LIBAT_CHECK_IFUNC
 218 fi
 219
 220 # Check linker support.
 221 LIBAT_ENABLE_SYMVERS
 222
 223 # Cleanup and exit.
 224 CFLAGS="$save_CFLAGS"
 225 AC_CACHE_SAVE
 226
 227 # Add -Wall -Werror if we are using GCC.
 228 if test "x$GCC" = "xyes"; then
 229   XCFLAGS="$XCFLAGS -Wall -Werror"
 230 fi
 231
 232 XCFLAGS="$XCFLAGS $XPCFLAGS"
 233
 234 AC_SUBST(config_path)
 235 AC_SUBST(XCFLAGS)
 236 AC_SUBST(XLDFLAGS)
 237 AC_SUBST(LIBS)
 238 AC_SUBST(SIZES)
 239
 240 AM_CONDITIONAL(HAVE_IFUNC, test x$libat_cv_have_ifunc = xyes)
 241 AM_CONDITIONAL(ARCH_ARM_LINUX,
 242                [expr "$config_path" : ".* linux/arm .*" > /dev/null])
 243 AM_CONDITIONAL(ARCH_I386,
 244                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x4])
 245 AM_CONDITIONAL(ARCH_X86_64,
 246                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x8])
 247
 248 if test ${multilib} = yes; then
 249   multilib_arg="--enable-multilib"
 250 else
 251   multilib_arg=
 252 fi
 253
 254 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 255 AC_OUTPUT