lib_blackfin/memcpy.S

   1 /*
   2  * File:         arch/blackfin/lib/memcpy.S
   3  * Based on:
   4  * Author:
   5  *
   6  * Created:
   7  * Description:  internal version of memcpy(), issued by the compiler
   8  *               to copy blocks of data around.
   9  *               This is really memmove() - it has to be able to deal with
  10  *               possible overlaps, because that ambiguity is when the compiler
  11  *               gives up and calls a function. We have our own, internal version
  12  *               so that we get something we trust, even if the user has redefined
  13  *               the normal symbol.
  14  * Rev:          $Id: memcpy.S 2775 2007-02-21 13:58:44Z hennerich $
  15  *
  16  * Modified:
  17  *               Copyright 2004-2006 Analog Devices Inc.
  18  *
  19  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  20  *
  21  * This program is free software; you can redistribute it and/or modify
  22  * it under the terms of the GNU General Public License as published by
  23  * the Free Software Foundation; either version 2 of the License, or
  24  * (at your option) any later version.
  25  *
  26  * This program is distributed in the hope that it will be useful,
  27  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  28  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  29  * GNU General Public License for more details.
  30  *
  31  * You should have received a copy of the GNU General Public License
  32  * along with this program; if not, see the file COPYING, or write
  33  * to the Free Software Foundation, Inc.,
  34  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  35  */
  36
  37
  38
  39 .align 2
  40
  41 .globl _memcpy_ASM;
  42 _memcpy_ASM:
  43         CC = R2 <=  0;  /* length not positive?*/
  44         IF CC JUMP  .L_P1L2147483647;   /* Nothing to do */
  45
  46         P0 = R0 ;       /* dst*/
  47         P1 = R1 ;       /* src*/
  48         P2 = R2 ;       /* length */
  49
  50         /* check for overlapping data */
  51         CC = R1 < R0;   /* src < dst */
  52         IF !CC JUMP .Lno_overlap;
  53         R3 = R1 + R2;
  54         CC = R0 < R3;   /* and dst < src+len */
  55         IF CC JUMP .Lhas_overlap;
  56
  57 .Lno_overlap:
  58         /* Check for aligned data.*/
  59
  60         R3 = R1 | R0;
  61         R0 = 0x3;
  62         R3 = R3 & R0;
  63         CC = R3;        /* low bits set on either address? */
  64         IF CC JUMP .Lnot_aligned;
  65
  66         /* Both addresses are word-aligned, so we can copy
  67         at least part of the data using word copies.*/
  68         P2 = P2 >> 2;
  69         CC = P2 <= 2;
  70         IF !CC JUMP .Lmore_than_seven;
  71         /* less than eight bytes... */
  72         P2 = R2;
  73         LSETUP(.Lthree_start, .Lthree_end) LC0=P2;
  74         R0 = R1;        /* setup src address for return */
  75 .Lthree_start:
  76         R3 = B[P1++] (X);
  77 .Lthree_end:
  78         B[P0++] = R3;
  79
  80         RTS;
  81
  82 .Lmore_than_seven:
  83         /* There's at least eight bytes to copy. */
  84         P2 += -1;       /* because we unroll one iteration */
  85         LSETUP(.Lword_loop, .Lword_loop) LC0=P2;
  86         R0 = R1;
  87         I1 = P1;
  88         R3 = [I1++];
  89 .Lword_loop:
  90         MNOP || [P0++] = R3 || R3 = [I1++];
  91
  92         [P0++] = R3;
  93         /* Any remaining bytes to copy? */
  94         R3 = 0x3;
  95         R3 = R2 & R3;
  96         CC = R3 == 0;
  97         P1 = I1;        /* in case there's something left, */
  98         IF !CC JUMP .Lbytes_left;
  99         RTS;
 100 .Lbytes_left:   P2 = R3;
 101 .Lnot_aligned:
 102         /* From here, we're copying byte-by-byte. */
 103         LSETUP (.Lbyte_start , .Lbyte_end) LC0=P2;
 104         R0 = R1;        /* Save src address for return */
 105 .Lbyte_start:
 106         R1 = B[P1++] (X);
 107 .Lbyte_end:
 108         B[P0++] = R1;
 109
 110 .L_P1L2147483647:
 111         RTS;
 112
 113 .Lhas_overlap:
 114 /* Need to reverse the copying, because the
 115  * dst would clobber the src.
 116  * Don't bother to work out alignment for
 117  * the reverse case.
 118  */
 119         R0 = R1;        /* save src for later. */
 120         P0 = P0 + P2;
 121         P0 += -1;
 122         P1 = P1 + P2;
 123         P1 += -1;
 124         LSETUP(.Lover_start, .Lover_end) LC0=P2;
 125 .Lover_start:
 126         R1 = B[P1--] (X);
 127 .Lover_end:
 128         B[P0--] = R1;
 129
 130         RTS;