lib/Automake/Condition.pm

   1 # Copyright (C) 1997-2013 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2, or (at your option)
   6 # any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 package Automake::Condition;
  17
  18 use 5.006;
  19 use strict;
  20 use Carp;
  21
  22 require Exporter;
  23 use vars '@ISA', '@EXPORT_OK';
  24 @ISA = qw/Exporter/;
  25 @EXPORT_OK = qw/TRUE FALSE reduce_and reduce_or/;
  26
  27 =head1 NAME
  28
  29 Automake::Condition - record a conjunction of conditionals
  30
  31 =head1 SYNOPSIS
  32
  33   use Automake::Condition;
  34
  35   # Create a condition to represent "COND1 and not COND2".
  36   my $cond = new Automake::Condition "COND1_TRUE", "COND2_FALSE";
  37   # Create a condition to represent "not COND3".
  38   my $other = new Automake::Condition "COND3_FALSE";
  39
  40   # Create a condition to represent
  41   #   "COND1 and not COND2 and not COND3".
  42   my $both = $cond->merge ($other);
  43
  44   # Likewise, but using a list of conditional strings
  45   my $both2 = $cond->merge_conds ("COND3_FALSE");
  46
  47   # Strip from $both any subconditions which are in $other.
  48   # This is the opposite of merge.
  49   $cond = $both->strip ($other);
  50
  51   # Return the list of conditions ("COND1_TRUE", "COND2_FALSE"):
  52   my @conds = $cond->conds;
  53
  54   # Is $cond always true?  (Not in this example)
  55   if ($cond->true) { ... }
  56
  57   # Is $cond always false? (Not in this example)
  58   if ($cond->false) { ... }
  59
  60   # Return the list of conditionals as a string:
  61   #  "COND1_TRUE COND2_FALSE"
  62   my $str = $cond->string;
  63
  64   # Return the list of conditionals as a human readable string:
  65   #  "COND1 and !COND2"
  66   my $str = $cond->human;
  67
  68   # Return the list of conditionals as a AC_SUBST-style string:
  69   #  "@COND1_TRUE@@COND2_FALSE@"
  70   my $subst = $cond->subst_string;
  71
  72   # Is $cond true when $both is true?  (Yes in this example)
  73   if ($cond->true_when ($both)) { ... }
  74
  75   # Is $cond redundant w.r.t. {$other, $both}?
  76   # (Yes in this example)
  77   if ($cond->redundant_wrt ($other, $both)) { ... }
  78
  79   # Does $cond imply any of {$other, $both}?
  80   # (Not in this example)
  81   if ($cond->implies_any ($other, $both)) { ... }
  82
  83   # Remove superfluous conditionals assuming they will eventually
  84   # be multiplied together.
  85   # (Returns @conds = ($both) in this example, because
  86   # $other and $cond are implied by $both.)
  87   @conds = Automake::Condition::reduce_and ($other, $both, $cond);
  88
  89   # Remove superfluous conditionals assuming they will eventually
  90   # be summed together.
  91   # (Returns @conds = ($cond, $other) in this example, because
  92   # $both is a subset condition of $cond: $cond is true whenever $both
  93   # is true.)
  94   @conds = Automake::Condition::reduce_or ($other, $both, $cond);
  95
  96   # Invert a Condition.  This returns a list of Conditions.
  97   @conds = $both->not;
  98
  99 =head1 DESCRIPTION
 100
 101 A C<Condition> is a conjunction of conditionals (i.e., atomic conditions
 102 defined in F<configure.ac> by C<AM_CONDITIONAL>.  In Automake they
 103 are used to represent the conditions into which F<Makefile> variables and
 104 F<Makefile> rules are defined.
 105
 106 If the variable C<VAR> is defined as
 107
 108   if COND1
 109     if COND2
 110       VAR = value
 111     endif
 112   endif
 113
 114 then it will be associated a C<Condition> created with
 115 the following statement.
 116
 117   new Automake::Condition "COND1_TRUE", "COND2_TRUE";
 118
 119 Remember that a C<Condition> is a I<conjunction> of conditionals, so
 120 the above C<Condition> means C<VAR> is defined when C<COND1>
 121 B<and> C<COND2> are true. There is no way to express disjunctions
 122 (i.e., I<or>s) with this class (but see L<DisjConditions>).
 123
 124 Another point worth to mention is that each C<Condition> object is
 125 unique with respect to its conditionals.  Two C<Condition> objects
 126 created for the same set of conditionals will have the same address.
 127 This makes it easy to compare C<Condition>s: just compare the
 128 references.
 129
 130   my $c1 = new Automake::Condition "COND1_TRUE", "COND2_TRUE";
 131   my $c2 = new Automake::Condition "COND1_TRUE", "COND2_TRUE";
 132   $c1 == $c2;  # True!
 133
 134 =head2 Methods
 135
 136 =over 4
 137
 138 =item C<$cond = new Automake::Condition [@conds]>
 139
 140 Return a C<Condition> objects for the conjunctions of conditionals
 141 listed in C<@conds> as strings.
 142
 143 An item in C<@conds> should be either C<"FALSE">, C<"TRUE">, or have
 144 the form C<"NAME_FALSE"> or C<"NAME_TRUE"> where C<NAME> can be
 145 anything (in practice C<NAME> should be the name of a conditional
 146 declared in F<configure.ac> with C<AM_CONDITIONAL>, but it's not
 147 C<Automake::Condition>'s responsibility to ensure this).
 148
 149 An empty C<@conds> means C<"TRUE">.
 150
 151 As explained previously, the reference (object) returned is unique
 152 with respect to C<@conds>.  For this purpose, duplicate elements are
 153 ignored, and C<@conds> is rewritten as C<("FALSE")> if it contains
 154 C<"FALSE"> or two contradictory conditionals (such as C<"NAME_FALSE">
 155 and C<"NAME_TRUE">.)
 156
 157 Therefore the following two statements create the same object (they
 158 both create the C<"FALSE"> condition).
 159
 160   my $c3 = new Automake::Condition "COND1_TRUE", "COND1_FALSE";
 161   my $c4 = new Automake::Condition "COND2_TRUE", "FALSE";
 162   $c3 == $c4;   # True!
 163   $c3 == FALSE; # True!
 164
 165 =cut
 166
 167 # Keys in this hash are conditional strings. Values are the
 168 # associated object conditions.  This is used by 'new' to reuse
 169 # Condition objects with identical conditionals.
 170 use vars '%_condition_singletons';
 171 # Do NOT reset this hash here.  It's already empty by default,
 172 # and any setting would otherwise occur AFTER the 'TRUE' and 'FALSE'
 173 # constants definitions.
 174 #   %_condition_singletons = ();
 175
 176 sub new ($;@)
 177 {
 178   my ($class, @conds) = @_;
 179   my $self = {
 180     hash => {},
 181   };
 182   bless $self, $class;
 183
 184   for my $cond (@conds)
 185     {
 186       # Catch some common programming errors:
 187       # - A Condition passed to new
 188       confess "'$cond' is a reference, expected a string" if ref $cond;
 189       # - A Condition passed as a string to new
 190       confess "'$cond' does not look like a condition" if $cond =~ /::/;
 191     }
 192
 193   # Accept strings like "FOO BAR" as shorthand for ("FOO", "BAR").
 194   @conds = map { split (' ', $_) } @conds;
 195
 196   for my $cond (@conds)
 197     {
 198       next if $cond eq 'TRUE';
 199
 200       # Detect cases when @conds can be simplified to FALSE.
 201       if (($cond eq 'FALSE' && $#conds > 0)
 202           || ($cond =~ /^(.*)_TRUE$/ && exists $self->{'hash'}{"${1}_FALSE"})
 203           || ($cond =~ /^(.*)_FALSE$/ && exists $self->{'hash'}{"${1}_TRUE"}))
 204         {
 205           return &FALSE;
 206         }
 207
 208       $self->{'hash'}{$cond} = 1;
 209     }
 210
 211   my $key = $self->string;
 212   if (exists $_condition_singletons{$key})
 213     {
 214       return $_condition_singletons{$key};
 215     }
 216   $_condition_singletons{$key} = $self;
 217   return $self;
 218 }
 219
 220 =item C<$newcond = $cond-E<gt>merge (@otherconds)>
 221
 222 Return a new condition which is the conjunction of
 223 C<$cond> and C<@otherconds>.
 224
 225 =cut
 226
 227 sub merge ($@)
 228 {
 229   my ($self, @otherconds) = @_;
 230   new Automake::Condition (map { $_->conds } ($self, @otherconds));
 231 }
 232
 233 =item C<$newcond = $cond-E<gt>merge_conds (@conds)>
 234
 235 Return a new condition which is the conjunction of C<$cond> and
 236 C<@conds>, where C<@conds> is a list of conditional strings, as
 237 passed to C<new>.
 238
 239 =cut
 240
 241 sub merge_conds ($@)
 242 {
 243   my ($self, @conds) = @_;
 244   new Automake::Condition $self->conds, @conds;
 245 }
 246
 247 =item C<$newcond = $cond-E<gt>strip ($minuscond)>
 248
 249 Return a new condition which has all the conditionals of C<$cond>
 250 except those of C<$minuscond>.  This is the opposite of C<merge>.
 251
 252 =cut
 253
 254 sub strip ($$)
 255 {
 256   my ($self, $minus) = @_;
 257   my @res = grep { not $minus->_has ($_) } $self->conds;
 258   return new Automake::Condition @res;
 259 }
 260
 261 =item C<@list = $cond-E<gt>conds>
 262
 263 Return the set of conditionals defining C<$cond>, as strings.  Note that
 264 this might not be exactly the list passed to C<new> (or a
 265 concatenation of such lists if C<merge> was used), because of the
 266 cleanup mentioned in C<new>'s description.
 267
 268 For instance C<$c3-E<gt>conds> will simply return C<("FALSE")>.
 269
 270 =cut
 271
 272 sub conds ($ )
 273 {
 274   my ($self) = @_;
 275   my @conds = keys %{$self->{'hash'}};
 276   return ("TRUE") unless @conds;
 277   return sort @conds;
 278 }
 279
 280 # Undocumented, shouldn't be needed outside of this class.
 281 sub _has ($$)
 282 {
 283   my ($self, $cond) = @_;
 284   return exists $self->{'hash'}{$cond};
 285 }
 286
 287 =item C<$cond-E<gt>false>
 288
 289 Return 1 iff this condition is always false.
 290
 291 =cut
 292
 293 sub false ($ )
 294 {
 295   my ($self) = @_;
 296   return $self->_has ('FALSE');
 297 }
 298
 299 =item C<$cond-E<gt>true>
 300
 301 Return 1 iff this condition is always true.
 302
 303 =cut
 304
 305 sub true ($ )
 306 {
 307   my ($self) = @_;
 308   return 0 == keys %{$self->{'hash'}};
 309 }
 310
 311 =item C<$cond-E<gt>string>
 312
 313 Build a string which denotes the condition.
 314
 315 For instance using the C<$cond> definition from L<SYNOPSYS>,
 316 C<$cond-E<gt>string> will return C<"COND1_TRUE COND2_FALSE">.
 317
 318 =cut
 319
 320 sub string ($ )
 321 {
 322   my ($self) = @_;
 323
 324   return $self->{'string'} if defined $self->{'string'};
 325
 326   my $res = '';
 327   if ($self->false)
 328     {
 329       $res = 'FALSE';
 330     }
 331   else
 332     {
 333       $res = join (' ', $self->conds);
 334     }
 335   $self->{'string'} = $res;
 336   return $res;
 337 }
 338
 339 =item C<$cond-E<gt>human>
 340
 341 Build a human readable string which denotes the condition.
 342
 343 For instance using the C<$cond> definition from L<SYNOPSYS>,
 344 C<$cond-E<gt>string> will return C<"COND1 and !COND2">.
 345
 346 =cut
 347
 348 sub _to_human ($ )
 349 {
 350   my ($s) = @_;
 351   if ($s =~ /^(.*)_(TRUE|FALSE)$/)
 352     {
 353       return (($2 eq 'FALSE') ? '!' : '') . $1;
 354     }
 355   else
 356     {
 357       return $s;
 358     }
 359 }
 360
 361 sub human ($ )
 362 {
 363   my ($self) = @_;
 364
 365   return $self->{'human'} if defined $self->{'human'};
 366
 367   my $res = '';
 368   if ($self->false)
 369     {
 370       $res = 'FALSE';
 371     }
 372   else
 373     {
 374       $res = join (' and ', map { _to_human $_ } $self->conds);
 375     }
 376   $self->{'human'} = $res;
 377   return $res;
 378 }
 379
 380 =item C<$cond-E<gt>subst_string>
 381
 382 Build a C<AC_SUBST>-style string for output in F<Makefile.in>.
 383
 384 For instance using the C<$cond> definition from L<SYNOPSYS>,
 385 C<$cond-E<gt>subst_string> will return C<"@COND1_TRUE@@COND2_FALSE@">.
 386
 387 =cut
 388
 389 sub subst_string ($ )
 390 {
 391   my ($self) = @_;
 392
 393   return $self->{'subst_string'} if defined $self->{'subst_string'};
 394
 395   my $res = '';
 396   if ($self->false)
 397     {
 398       $res = '#';
 399     }
 400   elsif (! $self->true)
 401     {
 402       $res = '@' . join ('@@', sort $self->conds) . '@';
 403     }
 404   $self->{'subst_string'} = $res;
 405   return $res;
 406 }
 407
 408 =item C<$cond-E<gt>true_when ($when)>
 409
 410 Return 1 iff C<$cond> is true when C<$when> is true.
 411 Return 0 otherwise.
 412
 413 Using the definitions from L<SYNOPSYS>, C<$cond> is true
 414 when C<$both> is true, but the converse is wrong.
 415
 416 =cut
 417
 418 sub true_when ($$)
 419 {
 420   my ($self, $when) = @_;
 421
 422   # Nothing is true when FALSE (not even FALSE itself, but it
 423   # shouldn't hurt if you decide to change that).
 424   return 0 if $self->false || $when->false;
 425
 426   # If we are true, we stay true when $when is true :)
 427   return 1 if $self->true;
 428
 429   # $SELF is true under $WHEN if each conditional component of $SELF
 430   # exists in $WHEN.
 431   foreach my $cond ($self->conds)
 432     {
 433       return 0 unless $when->_has ($cond);
 434     }
 435   return 1;
 436 }
 437
 438 =item C<$cond-E<gt>redundant_wrt (@conds)>
 439
 440 Return 1 iff C<$cond> is true for any condition in C<@conds>.
 441 If @conds is empty, return 1 iff C<$cond> is C<FALSE>.
 442 Return 0 otherwise.
 443
 444 =cut
 445
 446 sub redundant_wrt ($@)
 447 {
 448   my ($self, @conds) = @_;
 449
 450   foreach my $cond (@conds)
 451     {
 452       return 1 if $self->true_when ($cond);
 453     }
 454   return $self->false;
 455 }
 456
 457 =item C<$cond-E<gt>implies_any (@conds)>
 458
 459 Return 1 iff C<$cond> implies any of the conditions in C<@conds>.
 460 Return 0 otherwise.
 461
 462 =cut
 463
 464 sub implies_any ($@)
 465 {
 466   my ($self, @conds) = @_;
 467
 468   foreach my $cond (@conds)
 469     {
 470       return 1 if $cond->true_when ($self);
 471     }
 472   return 0;
 473 }
 474
 475 =item C<$cond-E<gt>not>
 476
 477 Return a negation of C<$cond> as a list of C<Condition>s.
 478 This list should be used to construct a C<DisjConditions>
 479 (we cannot return a C<DisjConditions> from C<Automake::Condition>,
 480 because that would make these two packages interdependent).
 481
 482 =cut
 483
 484 sub not ($ )
 485 {
 486   my ($self) = @_;
 487   return @{$self->{'not'}} if defined $self->{'not'};
 488   my @res =
 489     map { new Automake::Condition &conditional_negate ($_) } $self->conds;
 490   $self->{'not'} = [@res];
 491   return @res;
 492 }
 493
 494 =item C<$cond-E<gt>multiply (@conds)>
 495
 496 Assumption: C<@conds> represent a disjunction of conditions.
 497
 498 Return the result of multiplying C<$cond> with that disjunction.
 499 The result will be a list of conditions suitable to construct a
 500 C<DisjConditions>.
 501
 502 =cut
 503
 504 sub multiply ($@)
 505 {
 506   my ($self, @set) = @_;
 507   my %res = ();
 508   for my $cond (@set)
 509     {
 510       my $ans = $self->merge ($cond);
 511       $res{$ans} = $ans;
 512     }
 513
 514   # FALSE can always be removed from a disjunction.
 515   delete $res{FALSE};
 516
 517   # Now, $self is a common factor of the remaining conditions.
 518   # If one of the conditions is $self, we can discard the rest.
 519   return ($self, ())
 520     if exists $res{$self};
 521
 522   return (values %res);
 523 }
 524
 525 =back
 526
 527 =head2 Other helper functions
 528
 529 =over 4
 530
 531 =item C<TRUE>
 532
 533 The C<"TRUE"> conditional.
 534
 535 =item C<FALSE>
 536
 537 The C<"FALSE"> conditional.
 538
 539 =cut
 540
 541 use constant TRUE => new Automake::Condition "TRUE";
 542 use constant FALSE => new Automake::Condition "FALSE";
 543
 544 =item C<reduce_and (@conds)>
 545
 546 Return a subset of @conds with the property that the conjunction of
 547 the subset is the same as the conjunction of @conds.  For example, if
 548 both C<COND1_TRUE COND2_TRUE> and C<COND1_TRUE> are in the list,
 549 discard the latter.  If the input list is empty, return C<(TRUE)>.
 550
 551 =cut
 552
 553 sub reduce_and (@)
 554 {
 555   my (@conds) = @_;
 556   my @ret = ();
 557   my $cond;
 558   while (@conds > 0)
 559     {
 560       $cond = shift @conds;
 561
 562       # FALSE is absorbent.
 563       return FALSE
 564         if $cond == FALSE;
 565
 566       if (! $cond->redundant_wrt (@ret, @conds))
 567         {
 568           push (@ret, $cond);
 569         }
 570     }
 571
 572   return TRUE if @ret == 0;
 573   return @ret;
 574 }
 575
 576 =item C<reduce_or (@conds)>
 577
 578 Return a subset of @conds with the property that the disjunction of
 579 the subset is equivalent to the disjunction of @conds.  For example,
 580 if both C<COND1_TRUE COND2_TRUE> and C<COND1_TRUE> are in the list,
 581 discard the former.  If the input list is empty, return C<(FALSE)>.
 582
 583 =cut
 584
 585 sub reduce_or (@)
 586 {
 587   my (@conds) = @_;
 588   my @ret = ();
 589   my $cond;
 590   while (@conds > 0)
 591     {
 592       $cond = shift @conds;
 593
 594       next
 595        if $cond == FALSE;
 596       return TRUE
 597        if $cond == TRUE;
 598
 599       push (@ret, $cond)
 600        unless $cond->implies_any (@ret, @conds);
 601     }
 602
 603   return FALSE if @ret == 0;
 604   return @ret;
 605 }
 606
 607 =item C<conditional_negate ($condstr)>
 608
 609 Negate a conditional string.
 610
 611 =cut
 612
 613 sub conditional_negate ($)
 614 {
 615   my ($cond) = @_;
 616
 617   $cond =~ s/TRUE$/TRUEO/;
 618   $cond =~ s/FALSE$/TRUE/;
 619   $cond =~ s/TRUEO$/FALSE/;
 620
 621   return $cond;
 622 }
 623
 624 =back
 625
 626 =head1 SEE ALSO
 627
 628 L<Automake::DisjConditions>.
 629
 630 =head1 HISTORY
 631
 632 C<AM_CONDITIONAL>s and supporting code were added to Automake 1.1o by
 633 Ian Lance Taylor <ian@cygnus.org> in 1997.  Since then it has been
 634 improved by Tom Tromey <tromey@redhat.com>, Richard Boulton
 635 <richard@tartarus.org>, Raja R Harinath <harinath@cs.umn.edu>,
 636 Akim Demaille <akim@epita.fr>, and  Alexandre Duret-Lutz <adl@gnu.org>.
 637
 638 =cut
 639
 640 1;
 641
 642 ### Setup "GNU" style for perl-mode and cperl-mode.
 643 ## Local Variables:
 644 ## perl-indent-level: 2
 645 ## perl-continued-statement-offset: 2
 646 ## perl-continued-brace-offset: 0
 647 ## perl-brace-offset: 0
 648 ## perl-brace-imaginary-offset: 0
 649 ## perl-label-offset: -2
 650 ## cperl-indent-level: 2
 651 ## cperl-brace-offset: 0
 652 ## cperl-continued-brace-offset: 0
 653 ## cperl-label-offset: -2
 654 ## cperl-extra-newline-before-brace: t
 655 ## cperl-merge-trailing-else: nil
 656 ## cperl-continued-statement-offset: 2
 657 ## End: