ld/testsuite/ld-sh/arch/arch.exp

   1 # Copyright (C) 2004, 2005
   2 # Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 # Please email any bugs, comments, and/or additions to this file to:
  19 # binutils@sources.redhat.com
  20
  21 # This scripts tests of all available SH architectures with all other SH
  22 # architectures. It ensures that those combinations which should not work
  23 # do not work, and that those that should work produce the correct output
  24 # architecture.
  25 #
  26 # It looks for files in the same directory as this file named sh*.s .
  27 # Each file must contain one or more instructions which uniquely identifies
  28 # that architecture. The architecture name is inferred from the file name.
  29 # It is best to use the same files used by the assembler testsuite.
  30 #
  31 # It also creates another architecture named 'sh-unknown' by modifying
  32 # another arch type (there is no way to assemble such an arch) in order
  33 # to test what the linker would do with an older object file.
  34 #
  35 # The script generates the architecture permutations automatically,
  36 # but it reads the expected results from the file arch_expected.txt (also
  37 # found in the same directory as this script).
  38 #
  39 # The arch_expected.txt file should NOT be hand edited. Whenever the script
  40 # is run (e.g. with 'make check') it creates a new (usually identical) file
  41 # named arch_results.txt in the <objdir>/ld/testsuite directory. When the
  42 # expected results change (or new architectures are added) this new file
  43 # can be used to replace arch_expected.txt with no modification required.
  44
  45
  46 # The procedure extracts the architecture name from the objdump output.
  47 # If there is no architecture name (or objdump output changes significantly)
  48 # then the behaviour is undefined, but it will most likely return junk.
  49
  50 proc get_sh_arch { ofile } {
  51     global OBJDUMP
  52
  53     set cmd "$OBJDUMP -f $ofile"
  54     verbose -log $cmd
  55     catch "exec $cmd" objdump_output
  56     verbose -log $objdump_output
  57
  58     set objdump_output [string replace $objdump_output 0 \
  59             [expr [string first "architecture:" $objdump_output] + 13] ""]
  60
  61     return [string range $objdump_output 0 [expr [string first "," $objdump_output] - 1]]
  62 }
  63
  64
  65 # This procedure runs two tests:
  66 #   Test 1: Check the linker can link the given files.
  67 #   Test 2: Check that the resultant architecture is as expected.
  68 # It also writes an entry to the arch_results.txt file.
  69
  70 proc test_arch { file1 file2 arch resultfile } {
  71     global LD
  72
  73     set name1 [file tail $file1]
  74     set rootname1 [file rootname $name1]
  75
  76     set name2 [file tail $file2]
  77     set rootname2 [file rootname $name2]
  78
  79     set flags [big_or_little_endian]
  80
  81     # This must use -r to prevent LD trying to relocate the (unrealistic) file
  82     send_log "$LD $flags -r -o ${rootname1}_${rootname2}.o $file1 $file2\n"
  83     catch "exec $LD $flags -r -o ${rootname1}_${rootname2}.o $file1 $file2" ld_output
  84     send_log $ld_output
  85
  86     if {[string equal $ld_output ""] == 1} then {
  87         pass "$rootname1 file should link with $rootname2 file"
  88
  89         set result [get_sh_arch "${rootname1}_${rootname2}.o"]
  90         puts $resultfile [format "%-20s %-20s %s" $file1 $file2 $result]
  91
  92         if {$result == $arch} then {
  93             pass "$rootname1 file with $rootname2 file should link to arch $arch"
  94             file delete "${rootname1}_${rootname2}.o"
  95         } else {
  96             fail "$rootname1 file with $rootname2 file should link to arch $arch"
  97         }
  98     } else {
  99         fail "$rootname1 file should link with $rootname2 file"
 100
 101         puts $resultfile [format "%-20s %-20s ERROR" $file1 $file2]
 102         untested "$rootname2 file with $rootname2 file should link to arch $arch"
 103     }
 104
 105 }
 106
 107
 108
 109 # This procedure tests that a pair of files that are not
 110 # suposed to link does, in fact, not link.
 111 # It also writes an entry to the arch_results.txt file.
 112
 113 proc test_arch_error { file1 file2 resultfile} {
 114     global link_output LD
 115
 116     set name1 [file tail $file1]
 117     set rootname1 [file rootname $name1]
 118
 119     set name2 [file tail $file2]
 120     set rootname2 [file rootname $name2]
 121
 122     # This must use -r to prevent LD trying to relocate the (unrealistic) file
 123     send_log "$LD -r -o ${rootname1}_${rootname2}.o $file1 $file2\n"
 124     catch "exec $LD -r -o ${rootname1}_${rootname2}.o $file1 $file2" ld_output
 125     send_log $ld_output
 126
 127     if {[string equal $ld_output ""] == 1} then {
 128         fail "$rootname1 file should NOT link with $rootname2 file"
 129         puts $resultfile [format "%-20s %-20s [get_sh_arch ${rootname1}_${rootname2}.o]" $file1 $file2]
 130     } else {
 131         pass "$rootname1 file should NOT link with $rootname2 file"
 132         puts $resultfile [format "%-20s %-20s ERROR" $file1 $file2]
 133     }
 134 }
 135
 136 # These tests are not suitable for sh-coff because
 137 # coff does not store the architecture information.
 138
 139 if [istarget sh*-*-elf] then {
 140     global subdir srcdir
 141     global AS
 142
 143     # Find all the architectures and assemble all the files
 144     # we will use for the linker tests.
 145
 146     set sfilelist [lsort -ascii [glob "$srcdir/$subdir/sh*.s"]]
 147     set ofilelist {}
 148     foreach sfile $sfilelist {
 149         set ofile "[file rootname [file tail $sfile]].o"
 150         lappend ofilelist $ofile
 151
 152         set endian "-big"
 153         if [string equal [big_or_little_endian] " -EL"] then {
 154             set endian "-little"
 155         }
 156
 157         set cmd "$AS $endian -isa=any $sfile -o $ofile"
 158         verbose -log $cmd
 159         catch "exec $cmd" as_output
 160         if ![file exists $ofile] then {
 161             verbose -log $as_output
 162             perror "$sfile: assembly failed"
 163         }
 164     }
 165
 166     # Create the default arch ofile
 167     # This cannot be created with the assembler
 168     # sh4al-dsp is number 6, sh-unknown is 0
 169
 170     lappend ofilelist "sh-unknown.o"
 171
 172     if [string equal [big_or_little_endian] " -EL"] then {
 173         set cmd {xxd sh4al-dsp.o | sed {s/\(^0000020: .... .... \)06/\100/} | xxd -r - sh-unknown.o}
 174     } else {
 175         set cmd {xxd sh4al-dsp.o | sed {s/\(^0000020: .... .... .... ..\)06/\100/} | xxd -r - sh-unknown.o}
 176     }
 177     verbose -log $cmd
 178     catch "exec $cmd" xxd_output
 179     verbose -log $xxd_output
 180     if [string equal [get_sh_arch "sh-unknown.o"] "sh4al-dsp"] then {
 181         perror "sh-unknown.o not generated correctly"
 182     }
 183
 184
 185     # Initialise the results file
 186
 187     set outfile [open "arch_results.txt" w 0666]
 188     puts $outfile "# Generated file. DO NOT EDIT"
 189     puts $outfile "#"
 190     puts $outfile "# This file is generated by ld/testsuite/ld-sh/arch/arch.exp ."
 191     puts $outfile "# It contains the expected results of the tests."
 192     puts $outfile "# If the tests are failing because the expected results"
 193     puts $outfile "# have changed then run 'make check' and copy the new file"
 194     puts $outfile "# from <objdir>/ld/arch_results.txt"
 195     puts $outfile "# to   <srcdir>/ld/testsuite/ld-sh/arch/arch_expected.txt ."
 196     puts $outfile "# Make sure the new expected results are ALL correct."
 197     puts $outfile "#"
 198     puts $outfile [format "# %-18s %-20s %s" "FILE1" "FILE2" "OUTPUT"]
 199     puts $outfile [format "# %-18s %-20s %s" "-----" "-----" "------"]
 200
 201     # Open the expected results file and skip the header
 202
 203     set infile [open "$srcdir/$subdir/arch_expected.txt" r]
 204     while {[gets $infile line] >= 0 && [string match {\#*} $line]} {verbose -log "reading '$line'"}
 205
 206     foreach file1 $ofilelist {
 207         foreach file2 $ofilelist {
 208             set name1 [file tail $file1]
 209             set rootname1 [file rootname $name1]
 210
 211             set name2 [file tail $file2]
 212             set rootname2 [file rootname $name2]
 213
 214             # Decode the expected result from the file
 215
 216             scan $line "%s %s %s" exfile1 exfile2 exarch
 217             verbose -log "exfile1 = '$exfile1', exfile2 = '$exfile2', exarch = '$exarch'"
 218             verbose -log "  name1 = '$name1',   name2 = '$name2'"
 219
 220             if {[string equal $exfile1 $name1] && [string equal $exfile2 $file2]} then {
 221                 # The expected result file makes sense and
 222                 # appears up-to-date (the file and options match)
 223
 224                 if {[string equal $exarch "ERROR"]} then {
 225                     test_arch_error $file1 $file2 $outfile
 226                 } else {
 227                     test_arch $file1 $file2 $exarch $outfile
 228                 }
 229             } else {
 230                 # The expected result file isn't right somehow
 231                 # so just try any old test. This will cause
 232                 # many failures, but will genrate the results file.
 233
 234                 test_arch $file1 $file2 $rootname1 $outfile
 235             }
 236
 237             # Read the next line from the expected result file.
 238             # This is at the end because the process of skipping
 239             # the header reads the first real line
 240
 241             if [gets $infile line] then {
 242                 verbose -log "reading '$line'"
 243             }
 244         }
 245     }
 246
 247     close $infile
 248     close $outfile
 249
 250     foreach file $ofilelist {
 251         file delete $file
 252     }
 253 }