ld/testsuite/ld-elf/binutils.exp

   1 # Expect script for binutils tests
   2 # Copyright (C) 2006-2015 Free Software Foundation, Inc.
   3 #
   4 # This file is part of the GNU Binutils.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  19 # MA 02110-1301, USA.
  20 #
  21 # Written by H.J. Lu (hongjiu.lu@intel.com)
  22 #
  23
  24 # Make sure that binutils can correctly handle ld output in ELF.
  25
  26 if { ![istarget *-*-linux*]
  27      && ![istarget *-*-nacl*]
  28      && ![istarget *-*-gnu*]} {
  29     return
  30 }
  31
  32 if { [istarget *-*-linux*aout*]
  33      || [istarget *-*-linux*oldld*] } {
  34     return
  35 }
  36
  37 # The optional test_name argument provides a mechanism for the caller
  38 # to hardwire the test name. This is important if ld_options contains
  39 # absolute path names because the default test name is constructed
  40 # from the prog_name and ld_options and we do not want absolute paths
  41 # to appear in the test_name.  The optional readelf_options can be
  42 # used to specify different options for readelf.
  43 proc binutils_test { prog_name ld_options test {test_name ""} {readelf_options "-l"}} {
  44     global as
  45     global ld
  46     global READELF
  47     global objcopy
  48     global strip
  49     global srcdir
  50     global subdir
  51     global link_output
  52
  53     eval set prog \$$prog_name
  54
  55     if { "$test_name" == "" } {
  56       set test_name "$prog_name $ld_options ($test)"
  57     }
  58
  59     if { ![ld_assemble $as $srcdir/$subdir/$test.s tmpdir/$test.o ] } {
  60         unresolved "$test_name"
  61         return
  62     }
  63
  64     if { ![ld_simple_link $ld tmpdir/$test "$ld_options -z stack-size=0 tmpdir/$test.o"] } {
  65         if { [string match "*not supported*" $link_output]
  66              || [string match "*unrecognized option*" $link_output]
  67              || [string match "*-z relro ignored*" $link_output] } {
  68             unsupported "$ld_options is not supported by this target"
  69         } else {
  70             unresolved "$test_name"
  71         }
  72         return
  73     }
  74
  75     send_log "$READELF $readelf_options --wide tmpdir/$test > tmpdir/$test.exp\n"
  76     set got [remote_exec host "$READELF $readelf_options --wide tmpdir/$test" "" "/dev/null" "tmpdir/$test.exp"]
  77     if { [lindex $got 0] != 0 || ![string match "" [lindex $got 1]] } then {
  78         send_log "$got\n"
  79         unresolved "$test_name"
  80         return
  81     }
  82
  83     if [string match "*-z relro*" $ld_options] {
  84         # Check if GNU_RELRO segment is generated.
  85         set got [remote_exec host "grep GNU_RELRO tmpdir/$test.exp"]
  86         if { ![string match "*GNU_RELRO*" $got] } then {
  87             set got [remote_exec host "cat tmpdir/$test.exp"]
  88             if { [string match "*.data.rel.ro*" $got]
  89                  || [string match "*.dynamic*" $got]
  90                  || [string match "*.got*" $got]
  91                  || [string match "*.eh_frame*" $got]
  92                  || [string match "*.gcc_except_table*" $got]
  93                  || [string match "*.exception_ranges*" $got]
  94                  || [string match "*.ctors*" $got]
  95                  || [string match "*.dtors*" $got]
  96                  || [string match "*.tdata*" $got]
  97                  || [string match "*.preinit_array*" $got]
  98                  || [string match "*.init_array*" $got]
  99                  || [string match "*.fini_array*" $got] } then {
 100                 # Fail if GNU_RELRO segment isn't generated, but should.
 101                 fail "$test_name"
 102                 return
 103             }
 104         }
 105     }
 106
 107     send_log "$prog tmpdir/$test\n"
 108     set got [remote_exec host "$prog tmpdir/$test"]
 109     if { [lindex $got 0] != 0 || ![string match "" [lindex $got 1]] } then {
 110         send_log "$got\n"
 111         fail "$test_name"
 112         return
 113     }
 114
 115     send_log "$READELF $readelf_options --wide tmpdir/$test > tmpdir/$test.out\n"
 116     set got [remote_exec host "$READELF $readelf_options --wide tmpdir/$test" "" "/dev/null" "tmpdir/$test.out"]
 117     if { [lindex $got 0] != 0 || ![string match "" [lindex $got 1]] } then {
 118         send_log "$got\n"
 119         unresolved "$test_name"
 120         return
 121     }
 122
 123     if { [catch {exec cmp tmpdir/$test.exp tmpdir/$test.out}] } then {
 124         send_log "tmpdir/$test.exp tmpdir/$test.out differ.\n"
 125         fail "$test_name"
 126         return
 127     }
 128
 129     pass "$test_name"
 130 }
 131
 132 binutils_test strip "-z max-page-size=0x200000" maxpage1
 133 binutils_test strip "-z max-page-size=0x200000 -z common-page-size=0x100000" maxpage1
 134 binutils_test strip "-z max-page-size=0x100000" maxpage1
 135 binutils_test strip "-z max-page-size=0x100000 -z common-page-size=0x1000" maxpage1
 136
 137 binutils_test strip "" maxpage1
 138 binutils_test strip "-shared" maxpage1
 139 binutils_test objcopy "" maxpage1
 140 binutils_test objcopy "-shared" maxpage1
 141
 142 binutils_test strip "-z relro" relro1
 143 binutils_test strip "-z relro -shared" relro1
 144 binutils_test objcopy "-z relro" relro1
 145 binutils_test objcopy "-z relro -shared" relro1
 146 if { ([istarget "i?86-*-elf*"]
 147       || (([istarget "i?86-*-linux*"]
 148            || [istarget "i?86-*-gnu*"])
 149           && ![istarget "*-*-*aout*"]
 150           && ![istarget "*-*-*oldld*"])
 151       || [istarget "x86_64-*-linux*"]
 152       || [istarget "amd64-*-linux*"]
 153       || [istarget "i?86-*nacl*"]
 154       || [istarget "x86_64-*nacl*"]) } {
 155     binutils_test strip "-z relro -shared" relro2
 156     binutils_test objcopy "-z relro -shared" relro2
 157 }
 158
 159 binutils_test strip "-T ${srcdir}/${subdir}/lma.lnk" lma "strip -T lma.lnk"
 160
 161 set tls_tests { "tdata1" "tdata2" }
 162 # hppa64 has its own .tbss section, with different flags.
 163 if { ![istarget "hppa64-*-*"] } {
 164     lappend tls_tests "tdata3" "tbss1" "tbss2" "tbss3"
 165 }
 166 set tls_opts {
 167     ""
 168     "-z relro"
 169     "-shared"
 170     "-shared -z relro"
 171     "-z max-page-size=0x100000"
 172     "-z max-page-size=0x100000 -z common-page-size=0x1000"
 173 }
 174
 175 foreach testitem $tls_tests {
 176     foreach testopt $tls_opts {
 177         binutils_test objcopy $testopt $testitem
 178     }
 179 }
 180
 181 binutils_test strip "-s" gap "" "-lS"