ld/ldlex.l

   1 %{
   2
   3 /* Copyright (C) 1991 Free Software Foundation, Inc.
   4
   5 This file is part of GLD, the Gnu Linker.
   6
   7 GLD is free software; you can redistribute it and/or modify
   8 it under the terms of the GNU General Public License as published by
   9 the Free Software Foundation; either version 2, or (at your option)
  10 any later version.
  11
  12 GLD is distributed in the hope that it will be useful,
  13 but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 GNU General Public License for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GLD; see the file COPYING.  If not, write to
  19 the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  */
  20
  21 /*
  22 This was written by steve chamberlain
  23                     sac@cygnus.com
  24 */
  25
  26
  27 #include <ansidecl.h>
  28 #include <stdio.h>
  29 #include "bfd.h"
  30 #include "ld.h"
  31 #include "ldgram.h"
  32 #include "ldmisc.h"
  33 #include "ldexp.h"
  34 #include "ldlang.h"
  35 #include "ldfile.h"
  36
  37 int ldgram_in_defsym;
  38
  39 int hex_mode;
  40
  41 char *buystring();
  42
  43 unsigned int lineno = 1;
  44 int old;
  45
  46 #undef YY_INPUT
  47 #define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)
  48 #undef YY_FATAL_ERROR
  49 #define YY_FATAL_ERROR(s)
  50 #define MAX_INCLUDE_DEPTH 10
  51 YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  52 char *file_name_stack[MAX_INCLUDE_DEPTH];
  53 unsigned int include_stack_ptr = 0;
  54
  55 static YY_BUFFER_STATE yy_create_string_buffer PARAMS ((const char *string,
  56                                                         int size));
  57 static void yy_input PARAMS ((char *, int *result, int max_size));
  58 static void comment PARAMS ((void));
  59
  60 /* STATES
  61         COMMAND         on command line
  62         COMMENT         in a C comment
  63         EXPRESSION      definiatelyt in an expression
  64         SCRIPT          definately in a script
  65         SOMEWHERE       either EXPRESSION or SCRIPT
  66         MRI             in an MRI script
  67 */
  68 #define RTOKEN(x)  {  yylval.token = x; return x; }
  69 %}
  70
  71 %a 4000
  72 %o 5000
  73
  74 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  75 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  76 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  77 SYMBOLCHARN     [_a-zA-Z\/\.\\0-9]
  78 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  79 FILENAME        {FILENAMECHAR}+
  80 WHITE           [ \t\n]+
  81
  82 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
  83
  84
  85 %s COMMAND
  86 %s SCRIPT
  87 %s EXPRESSION
  88 %s COMMENT
  89 %s BOTH
  90 %s DEFSYMEXP
  91 %s MRI
  92 %%
  93
  94
  95 <BOTH,SCRIPT,EXPRESSION,COMMAND>"/*"    { comment(); }
  96
  97
  98 <DEFSYMEXP>"-"                  { RTOKEN('-');}
  99 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 100 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = buystring(yytext); return NAME; }
 101 <DEFSYMEXP>[ \t]                { RTOKEN(DEFSYMEND); }
 102 <DEFSYMEXP>"="                  { RTOKEN('='); }
 103 <COMMAND>"--help"               { return OPTION_help; }
 104 <COMMAND>"--version"            { return OPTION_version; }
 105 <COMMAND>"-defsym"{WHITE}*      { return OPTION_defsym; }
 106 <COMMAND>"-format"              { return OPTION_format; }
 107 <COMMAND>"-noinhibit-exec"      { return OPTION_noinhibit_exec; }
 108 <COMMAND>"-noinhibit_exec"      { return OPTION_noinhibit_exec; }
 109 <COMMAND>"-oformat"             { return OPTION_oformat; }
 110 <COMMAND>"-sort-common"         { return OPTION_sort_common;}
 111 <COMMAND>"-sort_common"         { return OPTION_sort_common;}
 112 <COMMAND>"-warn-common"         { return OPTION_warn_common;}
 113 <COMMAND>"-n"                   { return OPTION_n; }
 114 <COMMAND>"-N"                   { return OPTION_N; }
 115 <COMMAND>"-r"                   { return OPTION_r; }
 116 <COMMAND>"-relax"               { return OPTION_relax; }
 117 <COMMAND>"-i"                   { return OPTION_r; }
 118 <COMMAND>"-Ur"                  { return OPTION_Ur; }
 119 <COMMAND>"-o"                   { return OPTION_o; }
 120 <COMMAND>"-g"                   { return OPTION_g; }
 121 <COMMAND>"-e"                   { return OPTION_e; }
 122 <COMMAND>"-b"                   { return OPTION_b; }
 123 <COMMAND>"-dc"                  { return OPTION_dc; }
 124 <COMMAND>"-dp"                  { return OPTION_dp; }
 125 <COMMAND>"-d"                   { return OPTION_d; }
 126 <COMMAND>"-v"                   { return OPTION_v; }
 127 <COMMAND>"-V"                   { return OPTION_V; }
 128 <COMMAND>"-m"                   { return OPTION_m; }
 129 <COMMAND>"-m"{FILENAME}         { return OPTION_memul; }
 130 <COMMAND>"-M"                   { return OPTION_M; }
 131 <COMMAND>"-Map"                 { return OPTION_Map;}
 132 <COMMAND>"-t"                   { return OPTION_t; }
 133 <COMMAND>"-X"                   { return OPTION_X; }
 134 <COMMAND>"-x"                   { return OPTION_x; }
 135 <COMMAND>"-c"                   { return OPTION_c; }
 136 <COMMAND>"-R"                   { return OPTION_R; }
 137 <COMMAND>"-u"                   { return OPTION_u; }
 138 <COMMAND>"-s"                   { return OPTION_s; }
 139 <COMMAND>"-S"                   { return OPTION_S; }
 140 <COMMAND>"-Bstat"               { return OPTION_Bstatic; }
 141 <COMMAND>"-B"{FILENAME}         { /* Ignored */ }
 142 <COMMAND>"-l"{FILENAME}         {
 143                                         yylval.name = buystring(yytext+2);
 144                                         return OPTION_l;
 145                                 }
 146
 147 <COMMAND>"-L"{FILENAME}         {
 148                                         yylval.name = buystring(yytext+2);
 149                                         return OPTION_Lfile;
 150                                 }
 151 <COMMAND>"-L"                   { return OPTION_L; }
 152 <COMMAND>"-Ttext"               {
 153                                  yylval.name = ".text";
 154                                  return OPTION_Texp;
 155                                 }
 156 <COMMAND>"-Tdata"               {
 157                                  yylval.name = ".data";
 158                                  return OPTION_Texp;
 159                                }
 160 <COMMAND>"-Tbss"                {
 161                                  yylval.name = ".bss";
 162                                  return OPTION_Texp;
 163                                }
 164 <COMMAND>"-O"([0-9])+           {
 165                                         yylval.integer = atoi (yytext + 2);
 166                                         return OPTION_Oval;
 167                                 }
 168 <COMMAND>"-O"{FILENAME}         {
 169                                 yylval.name = buystring(yytext+2);
 170                                 return OPTION_Texp;
 171                                 }
 172
 173 <COMMAND>"-T"{FILENAME}         {
 174                                  yylval.name = buystring(yytext+2);
 175                                  return OPTION_Tfile;
 176                                }
 177 <COMMAND>"-T"                   {
 178                                  return OPTION_T;
 179                                }
 180
 181 <COMMAND>"-F"{FILENAME}         {
 182                                  return OPTION_F;
 183                                }
 184 <COMMAND>"-F"                   {
 185                                  return OPTION_F;
 186                                }
 187
 188 <COMMAND>"-y"{FILENAME}         {
 189                                         yylval.name = buystring(yytext+2);
 190                                         return OPTION_y;
 191                                 }
 192
 193 <COMMAND>"-A"{FILENAME}         {
 194                                         yylval.name = buystring(yytext+2);
 195                                         return OPTION_Aarch;
 196                                 }
 197
 198 <COMMAND>"-retain-symbols-file" { return OPTION_RETAIN_SYMBOLS_FILE; }
 199
 200 <COMMAND>"-EB"                  {
 201                                         return OPTION_EB;
 202                                 }
 203 <COMMAND>"-EL"                  {
 204                                         return OPTION_EL;
 205                                 }
 206 <COMMAND>"-G"                   {
 207                                         return OPTION_G;
 208                                 }
 209 <COMMAND>"-G"([0-9])+           {
 210                                         yylval.integer = atoi (yytext + 2);
 211                                         return OPTION_Gval;
 212                                 }
 213
 214 <COMMAND>"-Qy"                  {       return OPTION_Qy; }
 215 <COMMAND>"-dn"                  {       return OPTION_dn; }
 216 <COMMAND>"-Y"                   {       return OPTION_Y;  }
 217 <COMMAND>"-YP,"{FILENAME}       {
 218                                         yylval.name = buystring (yytext+4);
 219                                         return OPTION_YP;
 220                                 }
 221 <COMMAND>"-non_shared"          {       return OPTION_non_shared; }
 222 <COMMAND>"-call_shared"         {       return OPTION_call_shared; }
 223
 224 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 225                                 yylval.integer = bfd_scan_vma (yytext+1, 0,16);
 226                                 return INT;
 227                         }
 228
 229 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|X|B|O|D) {
 230                                    int base ;
 231                                    switch (yytext[yyleng-1]) {
 232                                     case 'X':
 233                                     case 'H':
 234                                      base = 16;
 235                                      break;
 236                                     case 'O':
 237                                      base = 8;
 238                                      break;
 239                                     case 'B':
 240                                      base = 2;
 241                                      break;
 242                                     default:
 243                                      base = 10;
 244                                    }
 245                                    yylval.integer = bfd_scan_vma (yytext+1, 0,
 246                                                                   base);
 247                                    return INT;
 248                                  }
 249 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>"$"?"0x"?([0-9A-Fa-f])+(M|K|m|k)? {
 250                                   yylval.integer = bfd_scan_vma (yytext, 0,
 251                                                                  hex_mode);
 252                                   if (yytext[yyleng-1]=='M'
 253                                         || yytext[yyleng-1] == 'm') {
 254                                       yylval.integer *= 1024*1024;
 255                                     }
 256                                   if (yytext[yyleng-1]=='K'
 257                                 || yytext[yyleng-1]=='k') {
 258                                       yylval.integer *= 1024;
 259                                     }
 260                                   return INT;
 261                                 }
 262 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 263 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 264 <BOTH,SCRIPT,EXPRESSION>"<<="   { RTOKEN(LSHIFTEQ);}
 265 <BOTH,SCRIPT,EXPRESSION>">>="   { RTOKEN(RSHIFTEQ);}
 266 <BOTH,SCRIPT,EXPRESSION>"||"    { RTOKEN(OROR);}
 267 <BOTH,SCRIPT,EXPRESSION>"=="    { RTOKEN(EQ);}
 268 <BOTH,SCRIPT,EXPRESSION>"!="    { RTOKEN(NE);}
 269 <BOTH,SCRIPT,EXPRESSION>">="    { RTOKEN(GE);}
 270 <BOTH,SCRIPT,EXPRESSION>"<="    { RTOKEN(LE);}
 271 <BOTH,SCRIPT,EXPRESSION>"<<"    { RTOKEN(LSHIFT);}
 272 <BOTH,SCRIPT,EXPRESSION>">>"    { RTOKEN(RSHIFT);}
 273 <BOTH,SCRIPT,EXPRESSION>"+="    { RTOKEN(PLUSEQ);}
 274 <BOTH,SCRIPT,EXPRESSION>"-="    { RTOKEN(MINUSEQ);}
 275 <BOTH,SCRIPT,EXPRESSION>"*="    { RTOKEN(MULTEQ);}
 276 <BOTH,SCRIPT,EXPRESSION>"/="    { RTOKEN(DIVEQ);}
 277 <BOTH,SCRIPT,EXPRESSION>"&="    { RTOKEN(ANDEQ);}
 278 <BOTH,SCRIPT,EXPRESSION>"|="    { RTOKEN(OREQ);}
 279 <BOTH,SCRIPT,EXPRESSION>"&&"    { RTOKEN(ANDAND);}
 280 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 281 <MRI,BOTH,SCRIPT,EXPRESSION>","         { RTOKEN(',');}
 282 <BOTH,SCRIPT,EXPRESSION>"&"             { RTOKEN('&');}
 283 <BOTH,SCRIPT,EXPRESSION>"|"             { RTOKEN('|');}
 284 <BOTH,SCRIPT,EXPRESSION>"~"             { RTOKEN('~');}
 285 <BOTH,SCRIPT,EXPRESSION>"!"             { RTOKEN('!');}
 286 <BOTH,SCRIPT,EXPRESSION>"?"             { RTOKEN('?');}
 287 <BOTH,SCRIPT,EXPRESSION>"*"             { RTOKEN('*');}
 288 <BOTH,SCRIPT,EXPRESSION>"+"             { RTOKEN('+');}
 289 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 290 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 291 <BOTH,SCRIPT,EXPRESSION>"%"             { RTOKEN('%');}
 292 <BOTH,SCRIPT,EXPRESSION>"<"             { RTOKEN('<');}
 293 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 294 <MRI,BOTH,SCRIPT,EXPRESSION>"="          { RTOKEN('=');}
 295 <BOTH,SCRIPT,EXPRESSION>"}"                     { RTOKEN('}') ; }
 296 <BOTH,SCRIPT,EXPRESSION>"{"                     { RTOKEN('{'); }
 297 <BOTH,SCRIPT,EXPRESSION>")"                     { RTOKEN(')');}
 298 <BOTH,SCRIPT,EXPRESSION>"("                     { RTOKEN('(');}
 299 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 300 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 301 <BOTH,SCRIPT,EXPRESSION>":"             { RTOKEN(':'); }
 302 <BOTH,SCRIPT,EXPRESSION>";"             { RTOKEN(';');}
 303 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 304 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 305 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 306 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 307 <BOTH,SCRIPT>"BLOCK"                    { RTOKEN(BLOCK);}
 308 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 309 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 310 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 311 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 312 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 313 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 314 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 315 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 316 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 317 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 318 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 319 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 320 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 321 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 322 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 323 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 324 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 325 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 326 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 327 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 328 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 329 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 330 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 331 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 332 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 333 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 334 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 335 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 336 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 337 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"                { RTOKEN(NOLOAD);}
 338 <BOTH,SCRIPT>"DSECT"                    { RTOKEN(DSECT);}
 339 <BOTH,SCRIPT>"COPY"                     { RTOKEN(COPY);}
 340 <BOTH,SCRIPT>"INFO"                     { RTOKEN(INFO);}
 341 <BOTH,SCRIPT>"OVERLAY"          { RTOKEN(OVERLAY);}
 342 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 343 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 344 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 345 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 346 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 347 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 348 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 349 <MRI>"*".*                      { /* Mri comment line */ }
 350 <MRI>"END"                      { RTOKEN(ENDWORD); }
 351 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 352 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 353
 354 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 355 <MRI>"BASE"                     { RTOKEN(BASE); }
 356 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 357 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 358 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 359 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 360 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 361 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 362 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 363 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 364 <MRI>"SECT"                     { RTOKEN(SECT); }
 365 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 366 <MRI>"end"                      { RTOKEN(ENDWORD); }
 367 <MRI>"chip"                     { RTOKEN(CHIP); }
 368 <MRI>"load"                     { RTOKEN(LOAD); }
 369 <MRI>"order"                    { RTOKEN(ORDER); }
 370 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 371 <MRI>"format"                   { RTOKEN(FORMAT); }
 372 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 373 <MRI>"sect"                     { RTOKEN(SECT); }
 374 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 375
 376 <COMMAND>{CMDFILENAMECHAR1}{CMDFILENAMECHAR}*   {
 377                                  yylval.name = buystring(yytext);
 378                                   return NAME;
 379                                 }
 380
 381
 382 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 383 /* Filename without commas, needed to parse mri stuff */
 384                                  yylval.name = buystring(yytext);
 385                                   return NAME;
 386                                 }
 387
 388
 389 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 390                                  yylval.name = buystring(yytext);
 391                                   return NAME;
 392                                 }
 393 <SCRIPT,COMMAND>{FILENAMECHAR}* { yylval.name = buystring(yytext);
 394                                   return NAME;
 395                                 }
 396
 397 <EXPRESSION,BOTH,COMMAND,SCRIPT>"\""[^\"]*"\"" {
 398                                         /* No matter the state, quotes
 399                                            give what's inside */
 400                                         yylval.name = buystring(yytext+1);
 401                                         yylval.name[yyleng-2] = 0;
 402                                         return NAME;
 403                                 }
 404 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 405 <MRI,COMMAND,BOTH,SCRIPT,EXPRESSION>[ \t]
 406
 407 <<EOF>> {
 408   include_stack_ptr--;
 409
 410   if (include_stack_ptr == 0)
 411   {
 412     yyterminate();
 413   }
 414   else
 415   {
 416     yy_switch_to_buffer(include_stack[include_stack_ptr]);
 417
 418   }
 419   if (include_stack_ptr==1)
 420   {
 421     BEGIN(COMMAND);
 422   }
 423   else
 424   {
 425     BEGIN(SCRIPT);
 426     ldfile_input_filename = file_name_stack[include_stack_ptr-1];
 427   }
 428
 429   return END;
 430 }
 431
 432 %%
 433
 434 void
 435 lex_push_file (file, name)
 436      FILE *file;
 437      char *name;
 438 {
 439   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 440   {
 441     einfo("%F:includes nested too deeply\n");
 442   }
 443   file_name_stack[include_stack_ptr] = name;
 444   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 445
 446   include_stack_ptr++;
 447   yyin = file;
 448   yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 449
 450   BEGIN(SCRIPT);
 451 }
 452
 453 static YY_BUFFER_STATE
 454 yy_create_string_buffer (string,  size)
 455      CONST char *string;
 456      int size;
 457 {
 458   YY_BUFFER_STATE b;
 459
 460   b = (YY_BUFFER_STATE) malloc( sizeof( struct yy_buffer_state ) );
 461   b->yy_input_file = 0;
 462
 463   if ( ! b )
 464    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 465
 466   b->yy_buf_size = size;
 467
 468   /* yy_ch_buf has to be 2 characters longer than the size given because
 469    * we need to put in 2 end-of-buffer characters.
 470    */
 471   b->yy_ch_buf = (YY_CHAR *) malloc( (unsigned) (b->yy_buf_size + 3) );
 472
 473   if ( ! b->yy_ch_buf )
 474    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 475
 476
 477   b->yy_ch_buf[0] = '\n';
 478   strcpy(b->yy_ch_buf+1,  string);
 479   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 480   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 481     b->yy_n_chars = size+1;
 482   b->yy_buf_pos = &b->yy_ch_buf[1];
 483
 484   b->yy_eof_status = EOF_NOT_SEEN;
 485
 486   return ( b );
 487 }
 488
 489
 490
 491 void
 492 lex_redirect (string)
 493      CONST  char *string;
 494 {
 495   YY_BUFFER_STATE tmp;
 496
 497   int len = strlen(string);
 498   yy_init = 0  ;
 499   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 500   {
 501     einfo("%F: macros nested too deeply\n");
 502   }
 503   file_name_stack[include_stack_ptr] = "redirect";
 504   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 505   include_stack_ptr++;
 506   tmp =   yy_create_string_buffer(string, len);
 507
 508   yy_switch_to_buffer(tmp);
 509   BEGIN(COMMAND);
 510   yyout = stdout;
 511 }
 512
 513 int state_stack[20];
 514 int *state_stack_p = state_stack;
 515
 516 void
 517 ldlex_script ()
 518 {
 519   *(state_stack_p)++ = yy_start;
 520
 521   BEGIN(SCRIPT);
 522 }
 523
 524
 525 void
 526 ldlex_mri_script ()
 527 {
 528   *(state_stack_p)++ = yy_start;
 529   BEGIN(MRI);
 530 }
 531
 532 void
 533 ldlex_defsym ()
 534 {
 535   *(state_stack_p)++ = yy_start;
 536   BEGIN(DEFSYMEXP);
 537 }
 538
 539 void
 540 ldlex_expression ()
 541 {
 542   *(state_stack_p)++ = yy_start;
 543   BEGIN(EXPRESSION);
 544
 545 }
 546 void
 547 ldlex_both ()
 548 {
 549   *(state_stack_p)++ = yy_start;
 550   BEGIN(BOTH);
 551 }
 552 void
 553 ldlex_command ()
 554 {
 555   *(state_stack_p)++ = yy_start;
 556   BEGIN(COMMAND);
 557 }
 558
 559 void
 560 ldlex_popstate ()
 561 {
 562   yy_start = *(--state_stack_p);
 563 }
 564
 565 static void
 566 yy_input(buf, result, max_size)
 567 char *buf;
 568 int *result;
 569 int max_size;
 570 {
 571   *result = 0;
 572   if (yy_current_buffer->yy_input_file)
 573   {
 574     if (yyin)
 575      if ( (*result = read( fileno(yyin), (char *) buf, max_size )) < 0 )
 576       YY_FATAL_ERROR( "read() in flex scanner failed" );
 577   }
 578 }
 579
 580 static void
 581 comment ()
 582 {
 583   int c;
 584   while (1)
 585   {
 586     c = input();
 587     while (c !='*' && c != EOF)
 588     {
 589       if (c == '\n') lineno++;
 590       c = input();
 591     }
 592
 593
 594     if (c == '*')
 595     {
 596       c = input();
 597       while ( c == '*')
 598        c = input();
 599       if ( c == '/' )
 600        break;                   /* found the end */
 601     }
 602
 603     if ( c == EOF )
 604     {
 605       einfo( "%F%P :EOF in comment\n");
 606       break;
 607     }
 608   }
 609 }