ld/ldlex.l

   1 %{
   2
   3 /* Copyright (C) 1991 Free Software Foundation, Inc.
   4
   5 This file is part of GLD, the Gnu Linker.
   6
   7 GLD is free software; you can redistribute it and/or modify
   8 it under the terms of the GNU General Public License as published by
   9 the Free Software Foundation; either version 2, or (at your option)
  10 any later version.
  11
  12 GLD is distributed in the hope that it will be useful,
  13 but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 GNU General Public License for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GLD; see the file COPYING.  If not, write to
  19 the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  */
  20
  21 /*
  22 This was written by steve chamberlain
  23                     sac@cygnus.com
  24 */
  25
  26
  27 #include <ansidecl.h>
  28 #include "bfd.h"
  29 #include "ldgram.h"
  30
  31 int ldgram_in_defsym;
  32 int ldgram_had_equals;
  33 int ldgram_in_script;
  34
  35 int hex_mode;
  36 extern int fgetc();
  37 extern int yyparse();
  38
  39
  40
  41 char *buystring();
  42
  43 unsigned int lineno = 1;
  44 int old;
  45
  46 static comment();
  47
  48 #undef YY_INPUT
  49 #define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)
  50 #undef YY_FATAL_ERROR
  51 #define YY_FATAL_ERROR ;
  52 #define MAX_INCLUDE_DEPTH 10
  53 YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  54 char *file_name_stack[MAX_INCLUDE_DEPTH];
  55 unsigned int include_stack_ptr = 0;
  56
  57
  58 /* STATES
  59         COMMAND         on command line
  60         COMMENT         in a C comment
  61         EXPRESSION      definiatelyt in an expression
  62         SCRIPT          definately in a script
  63         SOMEWHERE       either EXPRESSION or SCRIPT
  64         MRI             in an MRI script
  65 */
  66 #define RTOKEN(x)  {  yylval.token = x; return x; }
  67 %}
  68
  69 %a 4000
  70 %o 5000
  71
  72 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  73 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  74 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  75 SYMBOLCHARN     [_a-zA-Z\/\.\\0-9]
  76 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  77 FILENAME        {FILENAMECHAR}+
  78 WHITE           [ \t\n]+
  79
  80 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
  81
  82
  83 %s COMMAND
  84 %s SCRIPT
  85 %s EXPRESSION
  86 %s COMMENT
  87 %s BOTH
  88 %s DEFSYMEXP
  89 %s MRI
  90 %%
  91
  92
  93 <BOTH,SCRIPT,EXPRESSION,COMMAND>"/*"    { comment(); }
  94
  95
  96 <DEFSYMEXP>"-"                  { RTOKEN('-');}
  97 <DEFSYMEXP>"+"                  { RTOKEN('+');}
  98 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = buystring(yytext); return NAME; }
  99 <DEFSYMEXP>[ \t]                { RTOKEN(DEFSYMEND); }
 100 <DEFSYMEXP>"="                  { RTOKEN('='); }
 101 <COMMAND>"--help"               { return OPTION_help; }
 102 <COMMAND>"--version"            { return OPTION_version; }
 103 <COMMAND>"-defsym"{WHITE}*      { return OPTION_defsym; }
 104 <COMMAND>"-format"              { return OPTION_format; }
 105 <COMMAND>"-noinhibit-exec"      { return OPTION_noinhibit_exec; }
 106 <COMMAND>"-noinhibit_exec"      { return OPTION_noinhibit_exec; }
 107 <COMMAND>"-oformat"             { return OPTION_oformat; }
 108 <COMMAND>"-sort-common"         { return OPTION_sort_common;}
 109 <COMMAND>"-sort_common"         { return OPTION_sort_common;}
 110 <COMMAND>"-n"                   { return OPTION_n; }
 111 <COMMAND>"-N"                   { return OPTION_N; }
 112 <COMMAND>"-r"                   { return OPTION_r; }
 113 <COMMAND>"-relax"               { return OPTION_relax; }
 114 <COMMAND>"-i"                   { return OPTION_r; }
 115 <COMMAND>"-Ur"                  { return OPTION_Ur; }
 116 <COMMAND>"-o"                   { return OPTION_o; }
 117 <COMMAND>"-g"                   { return OPTION_g; }
 118 <COMMAND>"-e"                   { return OPTION_e; }
 119 <COMMAND>"-b"                   { return OPTION_b; }
 120 <COMMAND>"-dc"                  { return OPTION_dc; }
 121 <COMMAND>"-dp"                  { return OPTION_dp; }
 122 <COMMAND>"-d"                   { return OPTION_d; }
 123 <COMMAND>"-v"                   { return OPTION_v; }
 124 <COMMAND>"-V"                   { return OPTION_V; }
 125 <COMMAND>"-m"                   { return OPTION_m; }
 126 <COMMAND>"-m"{FILENAME}         { return OPTION_memul; }
 127 <COMMAND>"-M"                   { return OPTION_M; }
 128 <COMMAND>"-Map"                 { return OPTION_Map;}
 129 <COMMAND>"-t"                   { return OPTION_t; }
 130 <COMMAND>"-X"                   { return OPTION_X; }
 131 <COMMAND>"-x"                   { return OPTION_x; }
 132 <COMMAND>"-c"                   { return OPTION_c; }
 133 <COMMAND>"-R"                   { return OPTION_R; }
 134 <COMMAND>"-u"                   { return OPTION_u; }
 135 <COMMAND>"-s"                   { return OPTION_s; }
 136 <COMMAND>"-S"                   { return OPTION_S; }
 137 <COMMAND>"-Bstat"               { return OPTION_Bstatic; }
 138 <COMMAND>"-B"{FILENAME}         { /* Ignored */ }
 139 <COMMAND>"-l"{FILENAME}         {
 140                                         yylval.name = buystring(yytext+2);
 141                                         return OPTION_l;
 142                                 }
 143
 144 <COMMAND>"-L"{FILENAME}         {
 145                                         yylval.name = buystring(yytext+2);
 146                                         return OPTION_L;
 147                                 }
 148 <COMMAND>"-Ttext"               {
 149                                  yylval.name = ".text";
 150                                  return OPTION_Texp;
 151                                 }
 152 <COMMAND>"-Tdata"               {
 153                                  yylval.name = ".data";
 154                                  return OPTION_Texp;
 155                                }
 156 <COMMAND>"-Tbss"                {
 157                                  yylval.name = ".bss";
 158                                  return OPTION_Texp;
 159                                }
 160 <COMMAND>"-O"{FILENAME}         {
 161                                 yylval.name = buystring(yytext+2);
 162                                 return OPTION_Texp;
 163                                 }
 164
 165 <COMMAND>"-T"{FILENAME}         {
 166                                  yylval.name = buystring(yytext+2);
 167                                  return OPTION_Tfile;
 168                                }
 169 <COMMAND>"-T"                   {
 170                                  return OPTION_T;
 171                                }
 172
 173 <COMMAND>"-F"{FILENAME}         {
 174                                  return OPTION_F;
 175                                }
 176 <COMMAND>"-F"                   {
 177                                  return OPTION_F;
 178                                }
 179
 180 <COMMAND>"-y"{FILENAME}         {
 181                                         yylval.name = buystring(yytext+2);
 182                                         return OPTION_y;
 183                                 }
 184
 185 <COMMAND>"-A"{FILENAME}         {
 186                                         yylval.name = buystring(yytext+2);
 187                                         return OPTION_Aarch;
 188                                 }
 189
 190 <COMMAND>"-retain-symbols-file" { return OPTION_RETAIN_SYMBOLS_FILE; }
 191
 192 <COMMAND>"-EB"                  {
 193                                         return OPTION_EB;
 194                                 }
 195 <COMMAND>"-EL"                  {
 196                                         return OPTION_EL;
 197                                 }
 198 <COMMAND>"-G"                   {
 199                                         return OPTION_G;
 200                                 }
 201 <COMMAND>"-G"([0-9])+           {
 202                                         yylval.integer = atoi (yytext + 2);
 203                                         return OPTION_Gval;
 204                                 }
 205 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 206                                 yylval.integer = strtoul(yytext+1, 0,16);
 207                                 return INT;
 208                         }
 209
 210 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|X|B|O|D) {
 211                                    int base ;
 212                                    switch (yytext[yyleng-1]) {
 213                                     case 'X':
 214                                     case 'H':
 215                                      base = 16;
 216                                      break;
 217                                     case 'O':
 218                                      base = 8;
 219                                      break;
 220                                     case 'B':
 221                                      base = 2;
 222                                      break;
 223                                     default:
 224                                      base = 10;
 225                                    }
 226                                    yylval.integer = strtoul(yytext+1, 0, base);
 227                                    return INT;
 228                                  }
 229 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>"$"?"0x"?([0-9A-Fa-f])+(M|K|m|k)? {
 230                                   yylval.integer = strtoul(yytext,0,hex_mode);
 231                                   if (yytext[yyleng-1]=='M'
 232                                         || yytext[yyleng-1] == 'm') {
 233                                       yylval.integer *= 1024*1024;
 234                                     }
 235                                   if (yytext[yyleng-1]=='K'
 236                                 || yytext[yyleng-1]=='k') {
 237                                       yylval.integer *= 1024;
 238                                     }
 239                                   return INT;
 240                                 }
 241 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 242 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 243 <BOTH,SCRIPT,EXPRESSION>"<<="   { RTOKEN(LSHIFTEQ);}
 244 <BOTH,SCRIPT,EXPRESSION>">>="   { RTOKEN(RSHIFTEQ);}
 245 <BOTH,SCRIPT,EXPRESSION>"||"    { RTOKEN(OROR);}
 246 <BOTH,SCRIPT,EXPRESSION>"=="    { RTOKEN(EQ);}
 247 <BOTH,SCRIPT,EXPRESSION>"!="    { RTOKEN(NE);}
 248 <BOTH,SCRIPT,EXPRESSION>">="    { RTOKEN(GE);}
 249 <BOTH,SCRIPT,EXPRESSION>"<="    { RTOKEN(LE);}
 250 <BOTH,SCRIPT,EXPRESSION>"<<"    { RTOKEN(LSHIFT);}
 251 <BOTH,SCRIPT,EXPRESSION>">>"    { RTOKEN(RSHIFT);}
 252 <BOTH,SCRIPT,EXPRESSION>"+="    { RTOKEN(PLUSEQ);}
 253 <BOTH,SCRIPT,EXPRESSION>"-="    { RTOKEN(MINUSEQ);}
 254 <BOTH,SCRIPT,EXPRESSION>"*="    { RTOKEN(MULTEQ);}
 255 <BOTH,SCRIPT,EXPRESSION>"/="    { RTOKEN(DIVEQ);}
 256 <BOTH,SCRIPT,EXPRESSION>"&="    { RTOKEN(ANDEQ);}
 257 <BOTH,SCRIPT,EXPRESSION>"|="    { RTOKEN(OREQ);}
 258 <BOTH,SCRIPT,EXPRESSION>"&&"    { RTOKEN(ANDAND);}
 259 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 260 <MRI,BOTH,SCRIPT,EXPRESSION>","         { RTOKEN(',');}
 261 <BOTH,SCRIPT,EXPRESSION>"&"             { RTOKEN('&');}
 262 <BOTH,SCRIPT,EXPRESSION>"|"             { RTOKEN('|');}
 263 <BOTH,SCRIPT,EXPRESSION>"~"             { RTOKEN('~');}
 264 <BOTH,SCRIPT,EXPRESSION>"!"             { RTOKEN('!');}
 265 <BOTH,SCRIPT,EXPRESSION>"?"             { RTOKEN('?');}
 266 <BOTH,SCRIPT,EXPRESSION>"*"             { RTOKEN('*');}
 267 <BOTH,SCRIPT,EXPRESSION>"+"             { RTOKEN('+');}
 268 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 269 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 270 <BOTH,SCRIPT,EXPRESSION>"%"             { RTOKEN('%');}
 271 <BOTH,SCRIPT,EXPRESSION>"<"             { RTOKEN('<');}
 272 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 273 <MRI,BOTH,SCRIPT,EXPRESSION>"="          { RTOKEN('=');}
 274 <BOTH,SCRIPT,EXPRESSION>"}"                     { RTOKEN('}') ; }
 275 <BOTH,SCRIPT,EXPRESSION>"{"                     { RTOKEN('{'); }
 276 <BOTH,SCRIPT,EXPRESSION>")"                     { RTOKEN(')');}
 277 <BOTH,SCRIPT,EXPRESSION>"("                     { RTOKEN('(');}
 278 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 279 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 280 <BOTH,SCRIPT,EXPRESSION>":"             { RTOKEN(':'); }
 281 <BOTH,SCRIPT,EXPRESSION>";"             { RTOKEN(';');}
 282 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 283 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 284 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 285 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 286 <BOTH,SCRIPT>"BLOCK"                    { RTOKEN(BLOCK);}
 287 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 288 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 289 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 290 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 291 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 292 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 293 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 294 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 295 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 296 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 297 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 298 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 299 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 300 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 301 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 302 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 303 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 304 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 305 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 306 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 307 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 308 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 309 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 310 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 311 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 312 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 313 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 314 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 315 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 316 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"                { RTOKEN(NOLOAD);}
 317 <BOTH,SCRIPT>"DSECT"                    { RTOKEN(DSECT);}
 318 <BOTH,SCRIPT>"COPY"                     { RTOKEN(COPY);}
 319 <BOTH,SCRIPT>"INFO"                     { RTOKEN(INFO);}
 320 <BOTH,SCRIPT>"OVERLAY"          { RTOKEN(OVERLAY);}
 321 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 322 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 323 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 324 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 325 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 326 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 327 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 328 <MRI>"*".*                      { /* Mri comment line */ }
 329 <MRI>"END"                      { RTOKEN(ENDWORD); }
 330 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 331 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 332
 333 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 334 <MRI>"BASE"                     { RTOKEN(BASE); }
 335 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 336 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 337 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 338 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 339 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 340 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 341 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 342 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 343 <MRI>"SECT"                     { RTOKEN(SECT); }
 344 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 345 <MRI>"end"                      { RTOKEN(ENDWORD); }
 346 <MRI>"chip"                     { RTOKEN(CHIP); }
 347 <MRI>"load"                     { RTOKEN(LOAD); }
 348 <MRI>"order"                    { RTOKEN(ORDER); }
 349 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 350 <MRI>"format"                   { RTOKEN(FORMAT); }
 351 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 352 <MRI>"sect"                     { RTOKEN(SECT); }
 353 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 354
 355 <COMMAND>{CMDFILENAMECHAR1}{CMDFILENAMECHAR}*   {
 356                                  yylval.name = buystring(yytext);
 357                                   return NAME;
 358                                 }
 359
 360
 361 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 362 /* Filename without commas, needed to parse mri stuff */
 363                                  yylval.name = buystring(yytext);
 364                                   return NAME;
 365                                 }
 366
 367
 368 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 369                                  yylval.name = buystring(yytext);
 370                                   return NAME;
 371                                 }
 372 <SCRIPT,COMMAND>{FILENAMECHAR}* { yylval.name = buystring(yytext);
 373                                   return NAME;
 374                                 }
 375
 376 <EXPRESSION,BOTH,COMMAND,SCRIPT>"\""[^\"]*"\"" {
 377                                         /* No matter the state, quotes
 378                                            give what's inside */
 379                                         yylval.name = buystring(yytext+1);
 380                                         yylval.name[yyleng-2] = 0;
 381                                         return NAME;
 382                                 }
 383 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 384 <MRI,COMMAND,BOTH,SCRIPT,EXPRESSION>[ \t]
 385
 386 <<EOF>> {
 387   extern char *ldfile_input_filename;
 388   include_stack_ptr--;
 389
 390   if (include_stack_ptr == 0)
 391   {
 392     yyterminate();
 393   }
 394   else
 395   {
 396     yy_switch_to_buffer(include_stack[include_stack_ptr]);
 397
 398   }
 399   if (include_stack_ptr==1)
 400   {
 401     BEGIN(COMMAND);
 402   }
 403   else
 404   {
 405     BEGIN(SCRIPT);
 406     ldfile_input_filename = file_name_stack[include_stack_ptr-1];
 407   }
 408
 409   return END;
 410 }
 411
 412 %%
 413
 414 void
 415 lex_push_file (file, name)
 416      FILE *file;
 417      char *name;
 418 {
 419   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 420   {
 421     einfo("%F:includes nested too deeply");
 422   }
 423   file_name_stack[include_stack_ptr] = name;
 424   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 425
 426   include_stack_ptr++;
 427   yyin = file;
 428   yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 429
 430   BEGIN(SCRIPT);
 431 }
 432
 433 YY_BUFFER_STATE
 434 yy_create_string_buffer (string,  size)
 435      CONST char *string;
 436      int size;
 437 {
 438   YY_BUFFER_STATE b;
 439
 440   b = (YY_BUFFER_STATE) malloc( sizeof( struct yy_buffer_state ) );
 441   b->yy_input_file = 0;
 442
 443   if ( ! b )
 444    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 445
 446   b->yy_buf_size = size;
 447
 448   /* yy_ch_buf has to be 2 characters longer than the size given because
 449    * we need to put in 2 end-of-buffer characters.
 450    */
 451   b->yy_ch_buf = (YY_CHAR *) malloc( (unsigned) (b->yy_buf_size + 3) );
 452
 453   if ( ! b->yy_ch_buf )
 454    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 455
 456
 457   b->yy_ch_buf[0] = '\n';
 458   strcpy(b->yy_ch_buf+1,  string);
 459   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 460   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 461     b->yy_n_chars = size+1;
 462   b->yy_buf_pos = &b->yy_ch_buf[1];
 463
 464   b->yy_eof_status = EOF_NOT_SEEN;
 465
 466   return ( b );
 467 }
 468
 469
 470
 471 void
 472 lex_redirect (string)
 473      CONST  char *string;
 474 {
 475   YY_BUFFER_STATE tmp;
 476
 477   int len = strlen(string);
 478   yy_init = 0  ;
 479   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 480   {
 481     einfo("%F: macros nested too deeply");
 482   }
 483   file_name_stack[include_stack_ptr] = "redirect";
 484   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 485   include_stack_ptr++;
 486   tmp =   yy_create_string_buffer(string, len);
 487
 488   yy_switch_to_buffer(tmp);
 489   BEGIN(COMMAND);
 490   yyout = stdout;
 491 }
 492
 493 int state_stack[20];
 494 int *state_stack_p = state_stack;
 495
 496 void
 497 ldlex_script ()
 498 {
 499   *(state_stack_p)++ = yy_start;
 500
 501   BEGIN(SCRIPT);
 502 }
 503
 504
 505 void
 506 ldlex_mri_script ()
 507 {
 508   *(state_stack_p)++ = yy_start;
 509   BEGIN(MRI);
 510 }
 511
 512 void
 513 ldlex_defsym ()
 514 {
 515   *(state_stack_p)++ = yy_start;
 516   BEGIN(DEFSYMEXP);
 517 }
 518
 519 void
 520 ldlex_expression ()
 521 {
 522   *(state_stack_p)++ = yy_start;
 523   BEGIN(EXPRESSION);
 524
 525 }
 526 void
 527 ldlex_both ()
 528 {
 529   *(state_stack_p)++ = yy_start;
 530   BEGIN(BOTH);
 531 }
 532 void
 533 ldlex_command ()
 534 {
 535   *(state_stack_p)++ = yy_start;
 536   BEGIN(COMMAND);
 537 }
 538
 539 void
 540 ldlex_popstate ()
 541 {
 542   yy_start = *(--state_stack_p);
 543 }
 544
 545 yy_input(buf, result, max_size)
 546 char *buf;
 547 int *result;
 548 int max_size;
 549 {
 550   *result = 0;
 551   if (yy_current_buffer->yy_input_file)
 552   {
 553     if (yyin)
 554      if ( (*result = read( fileno(yyin), (char *) buf, max_size )) < 0 )
 555       YY_FATAL_ERROR( "read() in flex scanner failed" );
 556   }
 557 }
 558
 559 static
 560 comment()
 561 {
 562   int c;
 563   while (1)
 564   {
 565     c = input();
 566     while (c !='*' && c != EOF)
 567     {
 568       if (c == '\n') lineno++;
 569       c = input();
 570     }
 571
 572
 573     if (c == '*')
 574     {
 575       c = input();
 576       while ( c == '*')
 577        c = input();
 578       if ( c == '/' )
 579        break;                   /* found the end */
 580     }
 581
 582     if ( c == EOF )
 583     {
 584       einfo( "%F%P :EOF in comment");
 585       break;
 586     }
 587   }
 588 }