ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6    This file is part of GLD, the Gnu Linker.
   7
   8    GLD is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2, or (at your option)
  11    any later version.
  12
  13    GLD is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with GLD; see the file COPYING.  If not, write to the Free
  20    Software Foundation, 51 Franklin Street - Fifth Floor, Boston, MA
  21    02110-1301, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #include "bfd.h"
  32 #include "sysdep.h"
  33 #include "safe-ctype.h"
  34 #include "bfdlink.h"
  35 #include "ld.h"
  36 #include "ldmisc.h"
  37 #include "ldexp.h"
  38 #include "ldlang.h"
  39 #include <ldgram.h>
  40 #include "ldfile.h"
  41 #include "ldlex.h"
  42 #include "ldmain.h"
  43 #include "libiberty.h"
  44
  45 /* The type of top-level parser input.
  46    yylex and yyparse (indirectly) both check this.  */
  47 input_type parser_input;
  48
  49 /* Line number in the current input file.
  50    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  51 unsigned int lineno = 1;
  52
  53 /* The string we are currently lexing, or NULL if we are reading a
  54    file.  */
  55 const char *lex_string = NULL;
  56
  57 /* Support for flex reading from more than one input file (stream).
  58    `include_stack' is flex's input state for each open file;
  59    `file_name_stack' is the file names.  `lineno_stack' is the current
  60    line numbers.
  61
  62    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  63    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  64
  65 #undef YY_INPUT
  66 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  67
  68 #define YY_NO_UNPUT
  69
  70 #define MAX_INCLUDE_DEPTH 10
  71 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  72 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  73 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  74 static unsigned int include_stack_ptr = 0;
  75 static int vers_node_nesting = 0;
  76
  77 static void yy_input (char *, int *, int);
  78 static void comment (void);
  79 static void lex_warn_invalid (char *where, char *what);
  80
  81 /* STATES
  82         EXPRESSION      definitely in an expression
  83         SCRIPT          definitely in a script
  84         BOTH            either EXPRESSION or SCRIPT
  85         DEFSYMEXP       in an argument to -defsym
  86         MRI             in an MRI script
  87         VERS_START      starting a Sun style mapfile
  88         VERS_SCRIPT     a Sun style mapfile
  89         VERS_NODE       a node within a Sun style mapfile
  90 */
  91 #define RTOKEN(x)  {  yylval.token = x; return x; }
  92
  93 /* Some versions of flex want this.  */
  94 #ifndef yywrap
  95 int yywrap (void) { return 1; }
  96 #endif
  97 %}
  98
  99 %a 4000
 100 %o 5000
 101
 102 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 103 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 104 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 105 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 106 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 107 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 108 WHITE           [ \t\n\r]+
 109
 110 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 111
 112 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 113 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 114
 115 %s SCRIPT
 116 %s EXPRESSION
 117 %s BOTH
 118 %s DEFSYMEXP
 119 %s MRI
 120 %s VERS_START
 121 %s VERS_SCRIPT
 122 %s VERS_NODE
 123 %%
 124
 125   if (parser_input != input_selected)
 126     {
 127       /* The first token of the input determines the initial parser state.  */
 128       input_type t = parser_input;
 129       parser_input = input_selected;
 130       switch (t)
 131         {
 132         case input_script: return INPUT_SCRIPT; break;
 133         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 134         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 135         case input_defsym: return INPUT_DEFSYM; break;
 136         default: abort ();
 137         }
 138     }
 139
 140 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 141
 142
 143 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 144 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 145 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 146 <DEFSYMEXP>"="                  { RTOKEN('='); }
 147
 148 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 149                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 150                                 yylval.bigint.str = NULL;
 151                                 return INT;
 152                         }
 153
 154 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 155                                    int ibase ;
 156                                    switch (yytext[yyleng - 1]) {
 157                                     case 'X':
 158                                     case 'x':
 159                                     case 'H':
 160                                     case 'h':
 161                                      ibase = 16;
 162                                      break;
 163                                     case 'O':
 164                                     case 'o':
 165                                      ibase = 8;
 166                                      break;
 167                                     case 'B':
 168                                     case 'b':
 169                                      ibase = 2;
 170                                      break;
 171                                     default:
 172                                      ibase = 10;
 173                                    }
 174                                    yylval.integer = bfd_scan_vma (yytext, 0,
 175                                                                   ibase);
 176                                    yylval.bigint.str = NULL;
 177                                    return INT;
 178                                  }
 179 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 180                                   char *s = yytext;
 181                                   int ibase = 0;
 182
 183                                   if (*s == '$')
 184                                     {
 185                                       ++s;
 186                                       ibase = 16;
 187                                     }
 188                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 189                                   yylval.bigint.str = NULL;
 190                                   if (yytext[yyleng - 1] == 'M'
 191                                       || yytext[yyleng - 1] == 'm')
 192                                     {
 193                                       yylval.integer *= 1024 * 1024;
 194                                     }
 195                                   else if (yytext[yyleng - 1] == 'K'
 196                                       || yytext[yyleng - 1]=='k')
 197                                     {
 198                                       yylval.integer *= 1024;
 199                                     }
 200                                   else if (yytext[0] == '0'
 201                                            && (yytext[1] == 'x'
 202                                                || yytext[1] == 'X'))
 203                                     {
 204                                       yylval.bigint.str = xstrdup (yytext + 2);
 205                                     }
 206                                   return INT;
 207                                 }
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 242 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 243 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 244 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 245 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 246 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 247 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 248 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 249 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 250 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 251 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 252 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 256 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 257 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 258 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 259 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 260 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 261 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 262 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 263 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 264 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 265 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 266 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 267 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 268 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 269 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 270 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 271 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 272 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 273 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 274 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 275 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 276 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 277 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 278 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 280 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 281 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 282 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 283 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 284 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 285 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 286 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 287 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 288 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 289 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 290 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 291 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 292 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 293 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 294 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 295 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 296 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 297 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 298 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 299 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 300 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 301 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 302 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 303 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 304 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 305 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 306 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 307 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 308 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 309 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 310 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 311 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 312 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 313 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 314 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 315 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 316 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 317 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 318 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 319 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 320 <MRI>"#".*\n?                   { ++ lineno; }
 321 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 322 <MRI>"*".*                      { /* Mri comment line */ }
 323 <MRI>";".*                      { /* Mri comment line */ }
 324 <MRI>"END"                      { RTOKEN(ENDWORD); }
 325 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 326 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 327 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 328 <MRI>"BASE"                     { RTOKEN(BASE); }
 329 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 330 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 331 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 332 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 333 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 334 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 335 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 336 <MRI>"CASE"                     { RTOKEN(CASE); }
 337 <MRI>"START"                    { RTOKEN(START); }
 338 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 339 <MRI>"SECT"                     { RTOKEN(SECT); }
 340 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 341 <MRI>"end"                      { RTOKEN(ENDWORD); }
 342 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 343 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 344 <MRI>"chip"                     { RTOKEN(CHIP); }
 345 <MRI>"base"                     { RTOKEN(BASE); }
 346 <MRI>"alias"                    { RTOKEN(ALIAS); }
 347 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 348 <MRI>"load"                     { RTOKEN(LOAD); }
 349 <MRI>"public"                   { RTOKEN(PUBLIC); }
 350 <MRI>"order"                    { RTOKEN(ORDER); }
 351 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 352 <MRI>"format"                   { RTOKEN(FORMAT); }
 353 <MRI>"case"                     { RTOKEN(CASE); }
 354 <MRI>"extern"                   { RTOKEN(EXTERN); }
 355 <MRI>"start"                    { RTOKEN(START); }
 356 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 357 <MRI>"sect"                     { RTOKEN(SECT); }
 358 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 359
 360 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 361 /* Filename without commas, needed to parse mri stuff */
 362                                  yylval.name = xstrdup (yytext);
 363                                   return NAME;
 364                                 }
 365
 366
 367 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 368                                  yylval.name = xstrdup (yytext);
 369                                   return NAME;
 370                                 }
 371 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 372                                   yylval.name = xstrdup (yytext + 2);
 373                                   return LNAME;
 374                                 }
 375 <SCRIPT>{WILDCHAR}* {
 376                 /* Annoyingly, this pattern can match comments, and we have
 377                    longest match issues to consider.  So if the first two
 378                    characters are a comment opening, put the input back and
 379                    try again.  */
 380                 if (yytext[0] == '/' && yytext[1] == '*')
 381                   {
 382                     yyless (2);
 383                     comment ();
 384                   }
 385                 else
 386                   {
 387                     yylval.name = xstrdup (yytext);
 388                     return NAME;
 389                   }
 390         }
 391
 392 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 393                                         /* No matter the state, quotes
 394                                            give what's inside */
 395                                         yylval.name = xstrdup (yytext + 1);
 396                                         yylval.name[yyleng - 2] = 0;
 397                                         return NAME;
 398                                 }
 399 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 400 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 401
 402 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 403
 404 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 405
 406 <VERS_NODE>local                { RTOKEN(LOCAL); }
 407
 408 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 409
 410 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 411                                   return VERS_IDENTIFIER; }
 412
 413 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 414                                   return VERS_TAG; }
 415
 416 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 417
 418 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 419                                   vers_node_nesting = 0;
 420                                   return *yytext;
 421                                 }
 422 <VERS_SCRIPT>"}"                { return *yytext; }
 423 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 424 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 425                                     BEGIN(VERS_SCRIPT);
 426                                   return *yytext;
 427                                 }
 428
 429 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 430
 431 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 432
 433 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 434
 435 <<EOF>> {
 436   include_stack_ptr--;
 437
 438   if (include_stack_ptr == 0)
 439   {
 440     yyterminate ();
 441   }
 442   else
 443   {
 444     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 445   }
 446
 447   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 448   lineno = lineno_stack[include_stack_ptr];
 449
 450   return END;
 451 }
 452
 453 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 454 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 455
 456 %%
 457 \f
 458
 459 /* Switch flex to reading script file NAME, open on FILE,
 460    saving the current input info on the include stack.  */
 461
 462 void
 463 lex_push_file (FILE *file, const char *name)
 464 {
 465   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 466     {
 467       einfo ("%F:includes nested too deeply\n");
 468     }
 469   file_name_stack[include_stack_ptr] = name;
 470   lineno_stack[include_stack_ptr] = lineno;
 471   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 472
 473   include_stack_ptr++;
 474   lineno = 1;
 475   yyin = file;
 476   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 477 }
 478
 479 /* Return a newly created flex input buffer containing STRING,
 480    which is SIZE bytes long.  */
 481
 482 static YY_BUFFER_STATE
 483 yy_create_string_buffer (const char *string, size_t size)
 484 {
 485   YY_BUFFER_STATE b;
 486
 487   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 488   b = malloc (sizeof (struct yy_buffer_state));
 489   b->yy_input_file = 0;
 490   b->yy_buf_size = size;
 491
 492   /* yy_ch_buf has to be 2 characters longer than the size given because
 493      we need to put in 2 end-of-buffer characters.  */
 494   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 495
 496   b->yy_ch_buf[0] = '\n';
 497   strcpy (b->yy_ch_buf+1, string);
 498   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 499   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 500   b->yy_n_chars = size+1;
 501   b->yy_buf_pos = &b->yy_ch_buf[1];
 502
 503   b->yy_is_our_buffer = 1;
 504   b->yy_is_interactive = 0;
 505   b->yy_at_bol = 1;
 506   b->yy_fill_buffer = 0;
 507
 508   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 509      a flex internal interface in the first place!  */
 510 #ifdef YY_BUFFER_NEW
 511   b->yy_buffer_status = YY_BUFFER_NEW;
 512 #else
 513   b->yy_eof_status = EOF_NOT_SEEN;
 514 #endif
 515
 516   return b;
 517 }
 518
 519 /* Switch flex to reading from STRING, saving the current input info
 520    on the include stack.  */
 521
 522 void
 523 lex_redirect (const char *string)
 524 {
 525   YY_BUFFER_STATE tmp;
 526
 527   yy_init = 0;
 528   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 529     {
 530       einfo("%F: macros nested too deeply\n");
 531     }
 532   file_name_stack[include_stack_ptr] = "redirect";
 533   lineno_stack[include_stack_ptr] = lineno;
 534   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 535   include_stack_ptr++;
 536   lineno = 1;
 537   tmp = yy_create_string_buffer (string, strlen (string));
 538   yy_switch_to_buffer (tmp);
 539 }
 540 \f
 541 /* Functions to switch to a different flex start condition,
 542    saving the current start condition on `state_stack'.  */
 543
 544 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 545 static int *state_stack_p = state_stack;
 546
 547 void
 548 ldlex_script (void)
 549 {
 550   *(state_stack_p)++ = yy_start;
 551   BEGIN (SCRIPT);
 552 }
 553
 554 void
 555 ldlex_mri_script (void)
 556 {
 557   *(state_stack_p)++ = yy_start;
 558   BEGIN (MRI);
 559 }
 560
 561 void
 562 ldlex_version_script (void)
 563 {
 564   *(state_stack_p)++ = yy_start;
 565   BEGIN (VERS_START);
 566 }
 567
 568 void
 569 ldlex_version_file (void)
 570 {
 571   *(state_stack_p)++ = yy_start;
 572   BEGIN (VERS_SCRIPT);
 573 }
 574
 575 void
 576 ldlex_defsym (void)
 577 {
 578   *(state_stack_p)++ = yy_start;
 579   BEGIN (DEFSYMEXP);
 580 }
 581
 582 void
 583 ldlex_expression (void)
 584 {
 585   *(state_stack_p)++ = yy_start;
 586   BEGIN (EXPRESSION);
 587 }
 588
 589 void
 590 ldlex_both (void)
 591 {
 592   *(state_stack_p)++ = yy_start;
 593   BEGIN (BOTH);
 594 }
 595
 596 void
 597 ldlex_popstate (void)
 598 {
 599   yy_start = *(--state_stack_p);
 600 }
 601 \f
 602
 603 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 604    either the number of characters read, or 0 to indicate EOF.  */
 605
 606 static void
 607 yy_input (char *buf, int *result, int max_size)
 608 {
 609   *result = 0;
 610   if (YY_CURRENT_BUFFER->yy_input_file)
 611     {
 612       if (yyin)
 613         {
 614           *result = fread (buf, 1, max_size, yyin);
 615           if (*result < max_size && ferror (yyin))
 616             einfo ("%F%P: read in flex scanner failed\n");
 617         }
 618     }
 619 }
 620
 621 /* Eat the rest of a C-style comment.  */
 622
 623 static void
 624 comment (void)
 625 {
 626   int c;
 627
 628   while (1)
 629   {
 630     c = input();
 631     while (c != '*' && c != EOF)
 632     {
 633       if (c == '\n')
 634         lineno++;
 635       c = input();
 636     }
 637
 638     if (c == '*')
 639     {
 640       c = input();
 641       while (c == '*')
 642        c = input();
 643       if (c == '/')
 644        break;                   /* found the end */
 645     }
 646
 647     if (c == '\n')
 648       lineno++;
 649
 650     if (c == EOF)
 651     {
 652       einfo( "%F%P: EOF in comment\n");
 653       break;
 654     }
 655   }
 656 }
 657
 658 /* Warn the user about a garbage character WHAT in the input
 659    in context WHERE.  */
 660
 661 static void
 662 lex_warn_invalid (char *where, char *what)
 663 {
 664   char buf[5];
 665
 666   /* If we have found an input file whose format we do not recognize,
 667      and we are therefore treating it as a linker script, and we find
 668      an invalid character, then most likely this is a real object file
 669      of some different format.  Treat it as such.  */
 670   if (ldfile_assumed_script)
 671     {
 672       bfd_set_error (bfd_error_file_not_recognized);
 673       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 674     }
 675
 676   if (! ISPRINT (*what))
 677     {
 678       sprintf (buf, "\\%03o", (unsigned int) *what);
 679       what = buf;
 680     }
 681
 682   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 683 }