ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003  Free Software Foundation, Inc.
   5
   6 This file is part of GLD, the Gnu Linker.
   7
   8 GLD is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU General Public License as published by
  10 the Free Software Foundation; either version 2, or (at your option)
  11 any later version.
  12
  13 GLD is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GLD; see the file COPYING.  If not, write to the Free
  20 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 02111-1307, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #include "bfd.h"
  32 #include "sysdep.h"
  33 #include "safe-ctype.h"
  34 #include "bfdlink.h"
  35 #include "ld.h"
  36 #include "ldmisc.h"
  37 #include "ldexp.h"
  38 #include "ldlang.h"
  39 #include <ldgram.h>
  40 #include "ldfile.h"
  41 #include "ldlex.h"
  42 #include "ldmain.h"
  43 #include "libiberty.h"
  44
  45 /* The type of top-level parser input.
  46    yylex and yyparse (indirectly) both check this.  */
  47 input_type parser_input;
  48
  49 /* Line number in the current input file.
  50    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  51 unsigned int lineno = 1;
  52
  53 /* The string we are currently lexing, or NULL if we are reading a
  54    file.  */
  55 const char *lex_string = NULL;
  56
  57 /* Support for flex reading from more than one input file (stream).
  58    `include_stack' is flex's input state for each open file;
  59    `file_name_stack' is the file names.  `lineno_stack' is the current
  60    line numbers.
  61
  62    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  63    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  64
  65 #undef YY_INPUT
  66 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  67
  68 #define MAX_INCLUDE_DEPTH 10
  69 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  70 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  71 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  72 static unsigned int include_stack_ptr = 0;
  73 static int vers_node_nesting = 0;
  74
  75 static void yy_input (char *, int *, int);
  76 static void comment (void);
  77 static void lex_warn_invalid (char *where, char *what);
  78
  79 /* STATES
  80         EXPRESSION      definitely in an expression
  81         SCRIPT          definitely in a script
  82         BOTH            either EXPRESSION or SCRIPT
  83         DEFSYMEXP       in an argument to -defsym
  84         MRI             in an MRI script
  85         VERS_START      starting a Sun style mapfile
  86         VERS_SCRIPT     a Sun style mapfile
  87         VERS_NODE       a node within a Sun style mapfile
  88 */
  89 #define RTOKEN(x)  {  yylval.token = x; return x; }
  90
  91 /* Some versions of flex want this.  */
  92 #ifndef yywrap
  93 int yywrap (void) { return 1; }
  94 #endif
  95 %}
  96
  97 %a 4000
  98 %o 5000
  99
 100 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 101 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 102 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 103 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 104 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 105 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 106 WHITE           [ \t\n\r]+
 107
 108 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 109
 110 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 111 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 112
 113 %s SCRIPT
 114 %s EXPRESSION
 115 %s BOTH
 116 %s DEFSYMEXP
 117 %s MRI
 118 %s VERS_START
 119 %s VERS_SCRIPT
 120 %s VERS_NODE
 121 %%
 122
 123   if (parser_input != input_selected)
 124     {
 125       /* The first token of the input determines the initial parser state.  */
 126       input_type t = parser_input;
 127       parser_input = input_selected;
 128       switch (t)
 129         {
 130         case input_script: return INPUT_SCRIPT; break;
 131         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 132         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 133         case input_defsym: return INPUT_DEFSYM; break;
 134         default: abort ();
 135         }
 136     }
 137
 138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 139
 140
 141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 144 <DEFSYMEXP>"="                  { RTOKEN('='); }
 145
 146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 148                                 yylval.bigint.str = NULL;
 149                                 return INT;
 150                         }
 151
 152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 153                                    int ibase ;
 154                                    switch (yytext[yyleng - 1]) {
 155                                     case 'X':
 156                                     case 'x':
 157                                     case 'H':
 158                                     case 'h':
 159                                      ibase = 16;
 160                                      break;
 161                                     case 'O':
 162                                     case 'o':
 163                                      ibase = 8;
 164                                      break;
 165                                     case 'B':
 166                                     case 'b':
 167                                      ibase = 2;
 168                                      break;
 169                                     default:
 170                                      ibase = 10;
 171                                    }
 172                                    yylval.integer = bfd_scan_vma (yytext, 0,
 173                                                                   ibase);
 174                                    yylval.bigint.str = NULL;
 175                                    return INT;
 176                                  }
 177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 178                                   char *s = yytext;
 179                                   int ibase = 0;
 180
 181                                   if (*s == '$')
 182                                     {
 183                                       ++s;
 184                                       ibase = 16;
 185                                     }
 186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 187                                   yylval.bigint.str = NULL;
 188                                   if (yytext[yyleng - 1] == 'M'
 189                                       || yytext[yyleng - 1] == 'm')
 190                                     {
 191                                       yylval.integer *= 1024 * 1024;
 192                                     }
 193                                   else if (yytext[yyleng - 1] == 'K'
 194                                       || yytext[yyleng - 1]=='k')
 195                                     {
 196                                       yylval.integer *= 1024;
 197                                     }
 198                                   else if (yytext[0] == '0'
 199                                            && (yytext[1] == 'x'
 200                                                || yytext[1] == 'X'))
 201                                     {
 202                                       yylval.bigint.str = xstrdup (yytext + 2);
 203                                     }
 204                                   return INT;
 205                                 }
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"                 { RTOKEN('}') ; }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"                 { RTOKEN('{'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>")"                 { RTOKEN(')');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"("                 { RTOKEN('(');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 244 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 245 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 246 <BOTH,SCRIPT>"VERSION"          { RTOKEN(VERSIONK);}
 247 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 248 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 249 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 250 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 252 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 254 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 255 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"              { RTOKEN(LOADADDR);}
 256 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 257 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 258 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 265 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 266 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 267 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 268 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 269 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 270 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 271 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 272 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 273 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 274 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 275 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 276 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 277 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 278 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 279 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 280 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 281 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 282 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 283 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 284 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 285 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 286 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 287 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 288 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 289 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 290 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 291 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 292 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT); }
 293 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 294 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 295 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 296 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 297 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 298 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 299 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 300 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 301 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 302 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 303 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 304 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 305 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 306 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 307 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"              { RTOKEN(SUBALIGN);}
 308 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"               { RTOKEN(PROVIDE); }
 309 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 310 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
 311 <MRI>"#".*\n?                   { ++ lineno; }
 312 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 313 <MRI>"*".*                      { /* Mri comment line */ }
 314 <MRI>";".*                      { /* Mri comment line */ }
 315 <MRI>"END"                      { RTOKEN(ENDWORD); }
 316 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 317 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 318 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 319 <MRI>"BASE"                     { RTOKEN(BASE); }
 320 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 321 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 322 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 323 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 324 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 325 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 326 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 327 <MRI>"CASE"                     { RTOKEN(CASE); }
 328 <MRI>"START"                    { RTOKEN(START); }
 329 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 330 <MRI>"SECT"                     { RTOKEN(SECT); }
 331 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 332 <MRI>"end"                      { RTOKEN(ENDWORD); }
 333 <MRI>"alignmod"         { RTOKEN(ALIGNMOD);}
 334 <MRI>"align"            { RTOKEN(ALIGN_K);}
 335 <MRI>"chip"                     { RTOKEN(CHIP); }
 336 <MRI>"base"                     { RTOKEN(BASE); }
 337 <MRI>"alias"                     { RTOKEN(ALIAS); }
 338 <MRI>"truncate"                     { RTOKEN(TRUNCATE); }
 339 <MRI>"load"                     { RTOKEN(LOAD); }
 340 <MRI>"public"                   { RTOKEN(PUBLIC); }
 341 <MRI>"order"                    { RTOKEN(ORDER); }
 342 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 343 <MRI>"format"                   { RTOKEN(FORMAT); }
 344 <MRI>"case"                     { RTOKEN(CASE); }
 345 <MRI>"extern"                   { RTOKEN(EXTERN); }
 346 <MRI>"start"                    { RTOKEN(START); }
 347 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 348 <MRI>"sect"                     { RTOKEN(SECT); }
 349 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 350
 351 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 352 /* Filename without commas, needed to parse mri stuff */
 353                                  yylval.name = xstrdup (yytext);
 354                                   return NAME;
 355                                 }
 356
 357
 358 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 359                                  yylval.name = xstrdup (yytext);
 360                                   return NAME;
 361                                 }
 362 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 363                                   yylval.name = xstrdup (yytext + 2);
 364                                   return LNAME;
 365                                 }
 366 <SCRIPT>{WILDCHAR}* {
 367                 /* Annoyingly, this pattern can match comments, and we have
 368                    longest match issues to consider.  So if the first two
 369                    characters are a comment opening, put the input back and
 370                    try again.  */
 371                 if (yytext[0] == '/' && yytext[1] == '*')
 372                   {
 373                     yyless (2);
 374                     comment ();
 375                   }
 376                 else
 377                   {
 378                     yylval.name = xstrdup (yytext);
 379                     return NAME;
 380                   }
 381         }
 382
 383 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 384                                         /* No matter the state, quotes
 385                                            give what's inside */
 386                                         yylval.name = xstrdup (yytext + 1);
 387                                         yylval.name[yyleng - 2] = 0;
 388                                         return NAME;
 389                                 }
 390 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 391 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 392
 393 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 394
 395 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 396
 397 <VERS_NODE>local                { RTOKEN(LOCAL); }
 398
 399 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 400
 401 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 402                                   return VERS_IDENTIFIER; }
 403
 404 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 405                                   return VERS_TAG; }
 406
 407 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 408
 409 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 410                                   vers_node_nesting = 0;
 411                                   return *yytext;
 412                                 }
 413 <VERS_SCRIPT>"}"                { return *yytext; }
 414 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 415 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 416                                     BEGIN(VERS_SCRIPT);
 417                                   return *yytext;
 418                                 }
 419
 420 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 421
 422 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 423
 424 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 425
 426 <<EOF>> {
 427   include_stack_ptr--;
 428
 429   if (include_stack_ptr == 0)
 430   {
 431     yyterminate ();
 432   }
 433   else
 434   {
 435     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 436   }
 437
 438   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 439   lineno = lineno_stack[include_stack_ptr];
 440
 441   return END;
 442 }
 443
 444 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 445 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 446
 447 %%
 448 \f
 449
 450 /* Switch flex to reading script file NAME, open on FILE,
 451    saving the current input info on the include stack.  */
 452
 453 void
 454 lex_push_file (FILE *file, const char *name)
 455 {
 456   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 457     {
 458       einfo ("%F:includes nested too deeply\n");
 459     }
 460   file_name_stack[include_stack_ptr] = name;
 461   lineno_stack[include_stack_ptr] = lineno;
 462   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 463
 464   include_stack_ptr++;
 465   lineno = 1;
 466   yyin = file;
 467   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 468 }
 469
 470 /* Return a newly created flex input buffer containing STRING,
 471    which is SIZE bytes long.  */
 472
 473 static YY_BUFFER_STATE
 474 yy_create_string_buffer (const char *string, size_t size)
 475 {
 476   YY_BUFFER_STATE b;
 477
 478   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 479   b = malloc (sizeof (struct yy_buffer_state));
 480   b->yy_input_file = 0;
 481   b->yy_buf_size = size;
 482
 483   /* yy_ch_buf has to be 2 characters longer than the size given because
 484      we need to put in 2 end-of-buffer characters.  */
 485   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 486
 487   b->yy_ch_buf[0] = '\n';
 488   strcpy (b->yy_ch_buf+1, string);
 489   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 490   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 491   b->yy_n_chars = size+1;
 492   b->yy_buf_pos = &b->yy_ch_buf[1];
 493
 494   b->yy_is_our_buffer = 1;
 495   b->yy_is_interactive = 0;
 496   b->yy_at_bol = 1;
 497   b->yy_fill_buffer = 0;
 498
 499   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 500      a flex internal interface in the first place!  */
 501 #ifdef YY_BUFFER_NEW
 502   b->yy_buffer_status = YY_BUFFER_NEW;
 503 #else
 504   b->yy_eof_status = EOF_NOT_SEEN;
 505 #endif
 506
 507   return b;
 508 }
 509
 510 /* Switch flex to reading from STRING, saving the current input info
 511    on the include stack.  */
 512
 513 void
 514 lex_redirect (const char *string)
 515 {
 516   YY_BUFFER_STATE tmp;
 517
 518   yy_init = 0;
 519   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 520     {
 521       einfo("%F: macros nested too deeply\n");
 522     }
 523   file_name_stack[include_stack_ptr] = "redirect";
 524   lineno_stack[include_stack_ptr] = lineno;
 525   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 526   include_stack_ptr++;
 527   lineno = 1;
 528   tmp = yy_create_string_buffer (string, strlen (string));
 529   yy_switch_to_buffer (tmp);
 530 }
 531 \f
 532 /* Functions to switch to a different flex start condition,
 533    saving the current start condition on `state_stack'.  */
 534
 535 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 536 static int *state_stack_p = state_stack;
 537
 538 void
 539 ldlex_script (void)
 540 {
 541   *(state_stack_p)++ = yy_start;
 542   BEGIN (SCRIPT);
 543 }
 544
 545 void
 546 ldlex_mri_script (void)
 547 {
 548   *(state_stack_p)++ = yy_start;
 549   BEGIN (MRI);
 550 }
 551
 552 void
 553 ldlex_version_script (void)
 554 {
 555   *(state_stack_p)++ = yy_start;
 556   BEGIN (VERS_START);
 557 }
 558
 559 void
 560 ldlex_version_file (void)
 561 {
 562   *(state_stack_p)++ = yy_start;
 563   BEGIN (VERS_SCRIPT);
 564 }
 565
 566 void
 567 ldlex_defsym (void)
 568 {
 569   *(state_stack_p)++ = yy_start;
 570   BEGIN (DEFSYMEXP);
 571 }
 572
 573 void
 574 ldlex_expression (void)
 575 {
 576   *(state_stack_p)++ = yy_start;
 577   BEGIN (EXPRESSION);
 578 }
 579
 580 void
 581 ldlex_both (void)
 582 {
 583   *(state_stack_p)++ = yy_start;
 584   BEGIN (BOTH);
 585 }
 586
 587 void
 588 ldlex_popstate (void)
 589 {
 590   yy_start = *(--state_stack_p);
 591 }
 592 \f
 593
 594 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 595    either the number of characters read, or 0 to indicate EOF.  */
 596
 597 static void
 598 yy_input (char *buf, int *result, int max_size)
 599 {
 600   *result = 0;
 601   if (YY_CURRENT_BUFFER->yy_input_file)
 602     {
 603       if (yyin)
 604         {
 605           *result = fread (buf, 1, max_size, yyin);
 606           if (*result < max_size && ferror (yyin))
 607             einfo ("%F%P: read in flex scanner failed\n");
 608         }
 609     }
 610 }
 611
 612 /* Eat the rest of a C-style comment.  */
 613
 614 static void
 615 comment (void)
 616 {
 617   int c;
 618
 619   while (1)
 620   {
 621     c = input();
 622     while (c != '*' && c != EOF)
 623     {
 624       if (c == '\n')
 625         lineno++;
 626       c = input();
 627     }
 628
 629     if (c == '*')
 630     {
 631       c = input();
 632       while (c == '*')
 633        c = input();
 634       if (c == '/')
 635        break;                   /* found the end */
 636     }
 637
 638     if (c == '\n')
 639       lineno++;
 640
 641     if (c == EOF)
 642     {
 643       einfo( "%F%P: EOF in comment\n");
 644       break;
 645     }
 646   }
 647 }
 648
 649 /* Warn the user about a garbage character WHAT in the input
 650    in context WHERE.  */
 651
 652 static void
 653 lex_warn_invalid (char *where, char *what)
 654 {
 655   char buf[5];
 656
 657   /* If we have found an input file whose format we do not recognize,
 658      and we are therefore treating it as a linker script, and we find
 659      an invalid character, then most likely this is a real object file
 660      of some different format.  Treat it as such.  */
 661   if (ldfile_assumed_script)
 662     {
 663       bfd_set_error (bfd_error_file_not_recognized);
 664       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 665     }
 666
 667   if (! ISPRINT (*what))
 668     {
 669       sprintf (buf, "\\%03o", (unsigned int) *what);
 670       what = buf;
 671     }
 672
 673   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 674 }