ld/ldlex.l

   1 %option nounput noyywrap
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2017 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.  */
  43 unsigned int lineno;
  44
  45 /* The string we are currently lexing, or NULL if we are reading a
  46    file.  */
  47 const char *lex_string = NULL;
  48
  49 /* Support for flex reading from more than one input file (stream).
  50    `include_stack' is flex's input state for each open file;
  51    `file_name_stack' is the file names.  `lineno_stack' is the current
  52    line numbers.
  53
  54    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  55    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  56
  57 #undef YY_INPUT
  58 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  59
  60 #ifndef YY_NO_UNPUT
  61 #define YY_NO_UNPUT
  62 #endif
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int include_stack_ptr = 0;
  70 static int vers_node_nesting = 0;
  71
  72 static int yy_input (char *, int);
  73 static void comment (void);
  74 static void lex_warn_invalid (char *where, char *what);
  75
  76 /* STATES
  77         EXPRESSION      definitely in an expression
  78         SCRIPT          definitely in a script
  79         INPUTLIST       definitely in a script, a filename-list
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 %}
  90
  91 %a 4000
  92 %o 5000
  93
  94 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  95 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  96 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  97 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
  98 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  99 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 100 WHITE           [ \t\n\r]+
 101
 102 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 103
 104 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 105 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 106
 107 %s SCRIPT
 108 %s INPUTLIST
 109 %s EXPRESSION
 110 %s BOTH
 111 %s DEFSYMEXP
 112 %s MRI
 113 %s VERS_START
 114 %s VERS_SCRIPT
 115 %s VERS_NODE
 116 %%
 117
 118   if (parser_input != input_selected)
 119     {
 120       /* The first token of the input determines the initial parser state.  */
 121       input_type t = parser_input;
 122       parser_input = input_selected;
 123       switch (t)
 124         {
 125         case input_script: return INPUT_SCRIPT; break;
 126         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 127         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 128         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 129         case input_defsym: return INPUT_DEFSYM; break;
 130         default: abort ();
 131         }
 132     }
 133
 134 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 135
 136
 137 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 138 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 139 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 140 <DEFSYMEXP>"="                  { RTOKEN('='); }
 141
 142 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 143                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 144                                 yylval.bigint.str = NULL;
 145                                 return INT;
 146                         }
 147
 148 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 149                                    int ibase ;
 150                                    switch (yytext[yyleng - 1]) {
 151                                     case 'X':
 152                                     case 'x':
 153                                     case 'H':
 154                                     case 'h':
 155                                      ibase = 16;
 156                                      break;
 157                                     case 'O':
 158                                     case 'o':
 159                                      ibase = 8;
 160                                      break;
 161                                     case 'B':
 162                                     case 'b':
 163                                      ibase = 2;
 164                                      break;
 165                                     default:
 166                                      ibase = 10;
 167                                    }
 168                                    yylval.integer = bfd_scan_vma (yytext, 0,
 169                                                                   ibase);
 170                                    yylval.bigint.str = NULL;
 171                                    return INT;
 172                                  }
 173 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 174                                   char *s = yytext;
 175                                   int ibase = 0;
 176
 177                                   if (*s == '$')
 178                                     {
 179                                       ++s;
 180                                       ibase = 16;
 181                                     }
 182                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 183                                   yylval.bigint.str = NULL;
 184                                   if (yytext[yyleng - 1] == 'M'
 185                                       || yytext[yyleng - 1] == 'm')
 186                                     {
 187                                       yylval.integer *= 1024 * 1024;
 188                                     }
 189                                   else if (yytext[yyleng - 1] == 'K'
 190                                       || yytext[yyleng - 1]=='k')
 191                                     {
 192                                       yylval.integer *= 1024;
 193                                     }
 194                                   else if (yytext[0] == '0'
 195                                            && (yytext[1] == 'x'
 196                                                || yytext[1] == 'X'))
 197                                     {
 198                                       yylval.bigint.str = xstrdup (yytext + 2);
 199                                     }
 200                                   return INT;
 201                                 }
 202 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 221 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 236 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 240 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 241 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 242 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 243 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 244 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 246 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 247 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 248 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 252 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 254 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 255 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 256 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 257 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 258 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 265 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 267 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 268 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 269 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 270 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 271 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 272 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 273 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 274 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 275 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 276 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 277 <BOTH,SCRIPT>"FORCE_GROUP_ALLOCATION"   { RTOKEN(FORCE_GROUP_ALLOCATION);}
 278 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 280 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 281 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 282 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 283 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 284 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 285 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 286 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 287 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 288 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 289 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 290 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 291 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 292 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 293 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 294 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 295 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 296 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 297 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 298 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 299 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 300 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 301 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 302 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 303 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 304 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 305 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 306 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 307 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 308 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 309 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 310 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 311 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 312 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 313 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 314 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 315 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 316 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 317 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 318 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 319 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 320 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 321 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 322 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 323 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 324 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 325 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 326 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 327 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 328 <MRI>"#".*\n?                   { ++ lineno; }
 329 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 330 <MRI>"*".*                      { /* Mri comment line */ }
 331 <MRI>";".*                      { /* Mri comment line */ }
 332 <MRI>"END"                      { RTOKEN(ENDWORD); }
 333 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 334 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 335 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 336 <MRI>"BASE"                     { RTOKEN(BASE); }
 337 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 338 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 339 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 340 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 341 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 342 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 343 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 344 <MRI>"CASE"                     { RTOKEN(CASE); }
 345 <MRI>"START"                    { RTOKEN(START); }
 346 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 347 <MRI>"SECT"                     { RTOKEN(SECT); }
 348 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 349 <MRI>"end"                      { RTOKEN(ENDWORD); }
 350 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 351 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 352 <MRI>"chip"                     { RTOKEN(CHIP); }
 353 <MRI>"base"                     { RTOKEN(BASE); }
 354 <MRI>"alias"                    { RTOKEN(ALIAS); }
 355 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 356 <MRI>"load"                     { RTOKEN(LOAD); }
 357 <MRI>"public"                   { RTOKEN(PUBLIC); }
 358 <MRI>"order"                    { RTOKEN(ORDER); }
 359 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 360 <MRI>"format"                   { RTOKEN(FORMAT); }
 361 <MRI>"case"                     { RTOKEN(CASE); }
 362 <MRI>"extern"                   { RTOKEN(EXTERN); }
 363 <MRI>"start"                    { RTOKEN(START); }
 364 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 365 <MRI>"sect"                     { RTOKEN(SECT); }
 366 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 367
 368 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 369 /* Filename without commas, needed to parse mri stuff */
 370                                  yylval.name = xstrdup (yytext);
 371                                   return NAME;
 372                                 }
 373
 374
 375 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 376                                  yylval.name = xstrdup (yytext);
 377                                   return NAME;
 378                                 }
 379 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 380 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 381                                  yylval.name = xstrdup (yytext);
 382                                   return NAME;
 383                                 }
 384 <INPUTLIST>"$SYSROOT"{FILENAMECHAR1}{FILENAMECHAR}*     {
 385 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 386                                  yylval.name = xstrdup (yytext);
 387                                   return NAME;
 388                                 }
 389 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 390                                   yylval.name = xstrdup (yytext + 2);
 391                                   return LNAME;
 392                                 }
 393 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 394                                  yylval.name = xstrdup (yytext);
 395                                   return NAME;
 396                                 }
 397 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 398                                   yylval.name = xstrdup (yytext + 2);
 399                                   return LNAME;
 400                                 }
 401 <SCRIPT>{WILDCHAR}* {
 402                 /* Annoyingly, this pattern can match comments, and we have
 403                    longest match issues to consider.  So if the first two
 404                    characters are a comment opening, put the input back and
 405                    try again.  */
 406                 if (yytext[0] == '/' && yytext[1] == '*')
 407                   {
 408                     yyless (2);
 409                     comment ();
 410                   }
 411                 else
 412                   {
 413                     yylval.name = xstrdup (yytext);
 414                     return NAME;
 415                   }
 416         }
 417
 418 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 419                                         /* No matter the state, quotes
 420                                            give what's inside.  */
 421                                         bfd_size_type len;
 422                                         yylval.name = xstrdup (yytext + 1);
 423                                         /* PR ld/20906.  A corrupt input file
 424                                            can contain bogus strings.  */
 425                                         len = strlen (yylval.name);
 426                                         if (len > yyleng - 2)
 427                                           len = yyleng - 2;
 428                                         yylval.name[len] = 0;
 429                                         return NAME;
 430                                 }
 431 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 432 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 433
 434 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 435
 436 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 437
 438 <VERS_NODE>local                { RTOKEN(LOCAL); }
 439
 440 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 441
 442 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 443                                   return VERS_IDENTIFIER; }
 444
 445 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 446                                   return VERS_TAG; }
 447
 448 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 449
 450 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 451                                   vers_node_nesting = 0;
 452                                   return *yytext;
 453                                 }
 454 <VERS_SCRIPT>"}"                { return *yytext; }
 455 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 456 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 457                                     BEGIN(VERS_SCRIPT);
 458                                   return *yytext;
 459                                 }
 460
 461 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 462
 463 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 464
 465 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 466
 467 <<EOF>> {
 468   include_stack_ptr--;
 469   if (include_stack_ptr == 0)
 470     {
 471       lineno = 0;
 472       yyterminate ();
 473     }
 474   else
 475     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 476
 477   lineno = lineno_stack[include_stack_ptr];
 478   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 479
 480   return END;
 481 }
 482
 483 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 484 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 485
 486 %%
 487 \f
 488
 489 /* Switch flex to reading script file NAME, open on FILE,
 490    saving the current input info on the include stack.  */
 491
 492 void
 493 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 494 {
 495   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 496     {
 497       einfo ("%F:includes nested too deeply\n");
 498     }
 499   file_name_stack[include_stack_ptr] = name;
 500   lineno_stack[include_stack_ptr] = lineno;
 501   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 502   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 503
 504   include_stack_ptr++;
 505   lineno = 1;
 506   input_flags.sysrooted = sysrooted;
 507   yyin = file;
 508   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 509 }
 510
 511 /* Return a newly created flex input buffer containing STRING,
 512    which is SIZE bytes long.  */
 513
 514 static YY_BUFFER_STATE
 515 yy_create_string_buffer (const char *string, size_t size)
 516 {
 517   YY_BUFFER_STATE b;
 518
 519   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 520   b = malloc (sizeof (struct yy_buffer_state));
 521   b->yy_input_file = 0;
 522   b->yy_buf_size = size;
 523
 524   /* yy_ch_buf has to be 2 characters longer than the size given because
 525      we need to put in 2 end-of-buffer characters.  */
 526   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 527
 528   b->yy_ch_buf[0] = '\n';
 529   strcpy (b->yy_ch_buf+1, string);
 530   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 531   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 532   b->yy_n_chars = size+1;
 533   b->yy_buf_pos = &b->yy_ch_buf[1];
 534
 535   b->yy_is_our_buffer = 1;
 536   b->yy_is_interactive = 0;
 537   b->yy_at_bol = 1;
 538   b->yy_fill_buffer = 0;
 539
 540   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 541      a flex internal interface in the first place!  */
 542 #ifdef YY_BUFFER_NEW
 543   b->yy_buffer_status = YY_BUFFER_NEW;
 544 #else
 545   b->yy_eof_status = EOF_NOT_SEEN;
 546 #endif
 547
 548   return b;
 549 }
 550
 551 /* Switch flex to reading from STRING, saving the current input info
 552    on the include stack.  */
 553
 554 void
 555 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 556 {
 557   YY_BUFFER_STATE tmp;
 558
 559   yy_init = 0;
 560   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 561     {
 562       einfo("%F: macros nested too deeply\n");
 563     }
 564   file_name_stack[include_stack_ptr] = fake_filename;
 565   lineno_stack[include_stack_ptr] = lineno;
 566   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 567   include_stack_ptr++;
 568   lineno = count;
 569   tmp = yy_create_string_buffer (string, strlen (string));
 570   yy_switch_to_buffer (tmp);
 571 }
 572 \f
 573 /* Functions to switch to a different flex start condition,
 574    saving the current start condition on `state_stack'.  */
 575
 576 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 577 static int *state_stack_p = state_stack;
 578
 579 void
 580 ldlex_script (void)
 581 {
 582   *(state_stack_p)++ = yy_start;
 583   BEGIN (SCRIPT);
 584 }
 585
 586 void
 587 ldlex_inputlist (void)
 588 {
 589   *(state_stack_p)++ = yy_start;
 590   BEGIN (INPUTLIST);
 591 }
 592
 593 void
 594 ldlex_mri_script (void)
 595 {
 596   *(state_stack_p)++ = yy_start;
 597   BEGIN (MRI);
 598 }
 599
 600 void
 601 ldlex_version_script (void)
 602 {
 603   *(state_stack_p)++ = yy_start;
 604   BEGIN (VERS_START);
 605 }
 606
 607 void
 608 ldlex_version_file (void)
 609 {
 610   *(state_stack_p)++ = yy_start;
 611   BEGIN (VERS_SCRIPT);
 612 }
 613
 614 void
 615 ldlex_defsym (void)
 616 {
 617   *(state_stack_p)++ = yy_start;
 618   BEGIN (DEFSYMEXP);
 619 }
 620
 621 void
 622 ldlex_expression (void)
 623 {
 624   *(state_stack_p)++ = yy_start;
 625   BEGIN (EXPRESSION);
 626 }
 627
 628 void
 629 ldlex_both (void)
 630 {
 631   *(state_stack_p)++ = yy_start;
 632   BEGIN (BOTH);
 633 }
 634
 635 void
 636 ldlex_popstate (void)
 637 {
 638   yy_start = *(--state_stack_p);
 639 }
 640
 641 /* Return the current file name, or the previous file if no file is
 642    current.  */
 643
 644 const char*
 645 ldlex_filename (void)
 646 {
 647   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 648 }
 649 \f
 650
 651 /* Place up to MAX_SIZE characters in BUF and return
 652    either the number of characters read, or 0 to indicate EOF.  */
 653
 654 static int
 655 yy_input (char *buf, int max_size)
 656 {
 657   int result = 0;
 658   if (YY_CURRENT_BUFFER->yy_input_file)
 659     {
 660       if (yyin)
 661         {
 662           result = fread (buf, 1, max_size, yyin);
 663           if (result < max_size && ferror (yyin))
 664             einfo ("%F%P: read in flex scanner failed\n");
 665         }
 666     }
 667   return result;
 668 }
 669
 670 /* Eat the rest of a C-style comment.  */
 671
 672 static void
 673 comment (void)
 674 {
 675   int c;
 676
 677   while (1)
 678   {
 679     c = input();
 680     while (c != '*' && c != EOF)
 681     {
 682       if (c == '\n')
 683         lineno++;
 684       c = input();
 685     }
 686
 687     if (c == '*')
 688     {
 689       c = input();
 690       while (c == '*')
 691        c = input();
 692       if (c == '/')
 693        break;                   /* found the end */
 694     }
 695
 696     if (c == '\n')
 697       lineno++;
 698
 699     if (c == EOF)
 700     {
 701       einfo( "%F%P: EOF in comment\n");
 702       break;
 703     }
 704   }
 705 }
 706
 707 /* Warn the user about a garbage character WHAT in the input
 708    in context WHERE.  */
 709
 710 static void
 711 lex_warn_invalid (char *where, char *what)
 712 {
 713   char buf[5];
 714
 715   /* If we have found an input file whose format we do not recognize,
 716      and we are therefore treating it as a linker script, and we find
 717      an invalid character, then most likely this is a real object file
 718      of some different format.  Treat it as such.  */
 719   if (ldfile_assumed_script)
 720     {
 721       bfd_set_error (bfd_error_file_not_recognized);
 722       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 723     }
 724
 725   if (! ISPRINT (*what))
 726     {
 727       sprintf (buf, "\\%03o", *(unsigned char *) what);
 728       what = buf;
 729     }
 730
 731   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 732 }