ld/ldlex.l

   1 %option nounput noyywrap
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2019 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.  */
  43 unsigned int lineno;
  44
  45 /* The string we are currently lexing, or NULL if we are reading a
  46    file.  */
  47 const char *lex_string = NULL;
  48
  49 /* Support for flex reading from more than one input file (stream).
  50    `include_stack' is flex's input state for each open file;
  51    `file_name_stack' is the file names.  `lineno_stack' is the current
  52    line numbers.
  53
  54    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  55    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  56
  57 #undef YY_INPUT
  58 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  59
  60 #ifndef YY_NO_UNPUT
  61 #define YY_NO_UNPUT
  62 #endif
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int include_stack_ptr = 0;
  70 static int vers_node_nesting = 0;
  71
  72 static int yy_input (char *, int);
  73 static void comment (void);
  74 static void lex_warn_invalid (char *where, char *what);
  75
  76 /* STATES
  77         EXPRESSION      definitely in an expression
  78         SCRIPT          definitely in a script
  79         INPUTLIST       definitely in a script, a filename-list
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 %}
  90
  91 %a 4000
  92 %o 5000
  93
  94 WILDCHAR        [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=\?\*\^\!]
  95 FILENAMECHAR    [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=]
  96 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]]
  97 SYMBOLNAMECHAR  [_a-zA-Z0-9\/\.\\\$\~]
  98 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\~]
  99 SYMBOLNAMECHAR1 [_a-zA-Z\.\\\$]
 100 WHITE           [ \t\n\r]+
 101
 102 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 103 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 104
 105 %s SCRIPT
 106 %s INPUTLIST
 107 %s EXPRESSION
 108 %s BOTH
 109 %s DEFSYMEXP
 110 %s MRI
 111 %s VERS_START
 112 %s VERS_SCRIPT
 113 %s VERS_NODE
 114 %%
 115
 116   if (parser_input != input_selected)
 117     {
 118       /* The first token of the input determines the initial parser state.  */
 119       input_type t = parser_input;
 120       parser_input = input_selected;
 121       switch (t)
 122         {
 123         case input_script: return INPUT_SCRIPT; break;
 124         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 125         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 126         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 127         case input_defsym: return INPUT_DEFSYM; break;
 128         default: abort ();
 129         }
 130     }
 131
 132 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 133
 134
 135 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 136 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 137 <DEFSYMEXP>{SYMBOLNAMECHAR1}{SYMBOLNAMECHAR}* { yylval.name = xstrdup (yytext);
 138                                                 return NAME; }
 139 <DEFSYMEXP>"="                  { RTOKEN('='); }
 140
 141 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 142                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 143                                 yylval.bigint.str = NULL;
 144                                 return INT;
 145                         }
 146
 147 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 148                                    int ibase ;
 149                                    switch (yytext[yyleng - 1]) {
 150                                     case 'X':
 151                                     case 'x':
 152                                     case 'H':
 153                                     case 'h':
 154                                      ibase = 16;
 155                                      break;
 156                                     case 'O':
 157                                     case 'o':
 158                                      ibase = 8;
 159                                      break;
 160                                     case 'B':
 161                                     case 'b':
 162                                      ibase = 2;
 163                                      break;
 164                                     default:
 165                                      ibase = 10;
 166                                    }
 167                                    yylval.integer = bfd_scan_vma (yytext, 0,
 168                                                                   ibase);
 169                                    yylval.bigint.str = NULL;
 170                                    return INT;
 171                                  }
 172 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 173                                   char *s = yytext;
 174                                   int ibase = 0;
 175
 176                                   if (*s == '$')
 177                                     {
 178                                       ++s;
 179                                       ibase = 16;
 180                                     }
 181                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 182                                   yylval.bigint.str = NULL;
 183                                   if (yytext[yyleng - 1] == 'M'
 184                                       || yytext[yyleng - 1] == 'm')
 185                                     {
 186                                       yylval.integer *= 1024 * 1024;
 187                                     }
 188                                   else if (yytext[yyleng - 1] == 'K'
 189                                       || yytext[yyleng - 1]=='k')
 190                                     {
 191                                       yylval.integer *= 1024;
 192                                     }
 193                                   else if (yytext[0] == '0'
 194                                            && (yytext[1] == 'x'
 195                                                || yytext[1] == 'X'))
 196                                     {
 197                                       yylval.bigint.str = xstrdup (yytext + 2);
 198                                     }
 199                                   return INT;
 200                                 }
 201 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 202 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 220 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 235 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 238 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 239 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 240 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 241 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 242 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 243 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 244 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 246 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 247 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 248 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 252 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 254 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 255 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 256 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 257 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 258 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 259 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 260 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 261 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 262 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 264 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 265 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 266 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 267 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 268 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 269 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 270 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 271 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 272 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 273 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 274 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 275 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 276 <BOTH,SCRIPT>"FORCE_GROUP_ALLOCATION"   { RTOKEN(FORCE_GROUP_ALLOCATION);}
 277 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 278 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 279 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 280 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 281 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 282 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 283 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 284 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 285 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 286 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 287 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 288 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 289 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 290 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 291 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 292 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 293 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 294 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 295 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 296 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 297 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 298 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 299 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 300 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 301 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 302 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 303 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 304 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 305 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 306 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 307 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 308 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 309 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 310 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 311 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 312 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 313 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 314 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 315 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 316 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 317 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 318 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 319 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 320 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 321 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 322 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 323 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 324 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 325 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 326 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 327 <MRI>"#".*\n?                   { ++ lineno; }
 328 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 329 <MRI>"*".*                      { /* Mri comment line */ }
 330 <MRI>";".*                      { /* Mri comment line */ }
 331 <MRI>"END"                      { RTOKEN(ENDWORD); }
 332 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 333 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 334 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 335 <MRI>"BASE"                     { RTOKEN(BASE); }
 336 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 337 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 338 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 339 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 340 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 341 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 342 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 343 <MRI>"CASE"                     { RTOKEN(CASE); }
 344 <MRI>"START"                    { RTOKEN(START); }
 345 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 346 <MRI>"SECT"                     { RTOKEN(SECT); }
 347 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 348 <MRI>"end"                      { RTOKEN(ENDWORD); }
 349 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 350 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 351 <MRI>"chip"                     { RTOKEN(CHIP); }
 352 <MRI>"base"                     { RTOKEN(BASE); }
 353 <MRI>"alias"                    { RTOKEN(ALIAS); }
 354 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 355 <MRI>"load"                     { RTOKEN(LOAD); }
 356 <MRI>"public"                   { RTOKEN(PUBLIC); }
 357 <MRI>"order"                    { RTOKEN(ORDER); }
 358 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 359 <MRI>"format"                   { RTOKEN(FORMAT); }
 360 <MRI>"case"                     { RTOKEN(CASE); }
 361 <MRI>"extern"                   { RTOKEN(EXTERN); }
 362 <MRI>"start"                    { RTOKEN(START); }
 363 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 364 <MRI>"sect"                     { RTOKEN(SECT); }
 365 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 366
 367 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 368 /* Filename without commas, needed to parse mri stuff */
 369                                   yylval.name = xstrdup (yytext);
 370                                   return NAME;
 371                                 }
 372
 373
 374 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 375                                   yylval.name = xstrdup (yytext);
 376                                   return NAME;
 377                                 }
 378 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 379 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 380                                   yylval.name = xstrdup (yytext);
 381                                   return NAME;
 382                                 }
 383 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 384                                   yylval.name = xstrdup (yytext + 2);
 385                                   return LNAME;
 386                                 }
 387 <EXPRESSION>{SYMBOLNAMECHAR1}{NOCFILENAMECHAR}* {
 388                                   yylval.name = xstrdup (yytext);
 389                                   return NAME;
 390                                 }
 391 <EXPRESSION>"/DISCARD/"         {
 392                                   yylval.name = xstrdup (yytext);
 393                                   return NAME;
 394                                 }
 395 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 396                                   yylval.name = xstrdup (yytext + 2);
 397                                   return LNAME;
 398                                 }
 399 <SCRIPT>{WILDCHAR}* {
 400                 /* Annoyingly, this pattern can match comments, and we have
 401                    longest match issues to consider.  So if the first two
 402                    characters are a comment opening, put the input back and
 403                    try again.  */
 404                 if (yytext[0] == '/' && yytext[1] == '*')
 405                   {
 406                     yyless (2);
 407                     comment ();
 408                   }
 409                 else
 410                   {
 411                     yylval.name = xstrdup (yytext);
 412                     return NAME;
 413                   }
 414         }
 415
 416 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 417                                         /* No matter the state, quotes
 418                                            give what's inside.  */
 419                                         bfd_size_type len;
 420                                         yylval.name = xstrdup (yytext + 1);
 421                                         /* PR ld/20906.  A corrupt input file
 422                                            can contain bogus strings.  */
 423                                         len = strlen (yylval.name);
 424                                         if (len > (bfd_size_type) yyleng - 2)
 425                                           len = yyleng - 2;
 426                                         yylval.name[len] = 0;
 427                                         return NAME;
 428                                 }
 429 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 430 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 431
 432 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 433
 434 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 435
 436 <VERS_NODE>local                { RTOKEN(LOCAL); }
 437
 438 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 439
 440 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 441                                   return VERS_IDENTIFIER; }
 442
 443 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 444                                   return VERS_TAG; }
 445
 446 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 447
 448 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 449                                   vers_node_nesting = 0;
 450                                   return *yytext;
 451                                 }
 452 <VERS_SCRIPT>"}"                { return *yytext; }
 453 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 454 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 455                                     BEGIN(VERS_SCRIPT);
 456                                   return *yytext;
 457                                 }
 458
 459 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 460
 461 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 462
 463 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 464
 465 <<EOF>> {
 466   include_stack_ptr--;
 467   if (include_stack_ptr == 0)
 468     {
 469       lineno = 0;
 470       yyterminate ();
 471     }
 472   else
 473     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 474
 475   lineno = lineno_stack[include_stack_ptr];
 476   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 477
 478   return END;
 479 }
 480
 481 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 482 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 483
 484 %%
 485 \f
 486
 487 /* Switch flex to reading script file NAME, open on FILE,
 488    saving the current input info on the include stack.  */
 489
 490 void
 491 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 492 {
 493   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 494     {
 495       einfo (_("%F:includes nested too deeply\n"));
 496     }
 497   file_name_stack[include_stack_ptr] = name;
 498   lineno_stack[include_stack_ptr] = lineno;
 499   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 500   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 501
 502   include_stack_ptr++;
 503   lineno = 1;
 504   input_flags.sysrooted = sysrooted;
 505   yyin = file;
 506   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 507 }
 508
 509 /* Return a newly created flex input buffer containing STRING,
 510    which is SIZE bytes long.  */
 511
 512 static YY_BUFFER_STATE
 513 yy_create_string_buffer (const char *string, size_t size)
 514 {
 515   YY_BUFFER_STATE b;
 516
 517   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 518   b = malloc (sizeof (struct yy_buffer_state));
 519   b->yy_input_file = 0;
 520   b->yy_buf_size = size;
 521
 522   /* yy_ch_buf has to be 2 characters longer than the size given because
 523      we need to put in 2 end-of-buffer characters.  */
 524   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 525
 526   b->yy_ch_buf[0] = '\n';
 527   strcpy (b->yy_ch_buf+1, string);
 528   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 529   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 530   b->yy_n_chars = size+1;
 531   b->yy_buf_pos = &b->yy_ch_buf[1];
 532
 533   b->yy_is_our_buffer = 1;
 534   b->yy_is_interactive = 0;
 535   b->yy_at_bol = 1;
 536   b->yy_fill_buffer = 0;
 537
 538   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 539      a flex internal interface in the first place!  */
 540 #ifdef YY_BUFFER_NEW
 541   b->yy_buffer_status = YY_BUFFER_NEW;
 542 #else
 543   b->yy_eof_status = EOF_NOT_SEEN;
 544 #endif
 545
 546   return b;
 547 }
 548
 549 /* Switch flex to reading from STRING, saving the current input info
 550    on the include stack.  */
 551
 552 void
 553 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 554 {
 555   YY_BUFFER_STATE tmp;
 556
 557   yy_init = 0;
 558   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 559     {
 560       einfo (_("%F: macros nested too deeply\n"));
 561     }
 562   file_name_stack[include_stack_ptr] = fake_filename;
 563   lineno_stack[include_stack_ptr] = lineno;
 564   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 565   include_stack_ptr++;
 566   lineno = count;
 567   tmp = yy_create_string_buffer (string, strlen (string));
 568   yy_switch_to_buffer (tmp);
 569 }
 570 \f
 571 /* Functions to switch to a different flex start condition,
 572    saving the current start condition on `state_stack'.  */
 573
 574 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 575 static int *state_stack_p = state_stack;
 576
 577 void
 578 ldlex_script (void)
 579 {
 580   *(state_stack_p)++ = yy_start;
 581   BEGIN (SCRIPT);
 582 }
 583
 584 void
 585 ldlex_inputlist (void)
 586 {
 587   *(state_stack_p)++ = yy_start;
 588   BEGIN (INPUTLIST);
 589 }
 590
 591 void
 592 ldlex_mri_script (void)
 593 {
 594   *(state_stack_p)++ = yy_start;
 595   BEGIN (MRI);
 596 }
 597
 598 void
 599 ldlex_version_script (void)
 600 {
 601   *(state_stack_p)++ = yy_start;
 602   BEGIN (VERS_START);
 603 }
 604
 605 void
 606 ldlex_version_file (void)
 607 {
 608   *(state_stack_p)++ = yy_start;
 609   BEGIN (VERS_SCRIPT);
 610 }
 611
 612 void
 613 ldlex_defsym (void)
 614 {
 615   *(state_stack_p)++ = yy_start;
 616   BEGIN (DEFSYMEXP);
 617 }
 618
 619 void
 620 ldlex_expression (void)
 621 {
 622   *(state_stack_p)++ = yy_start;
 623   BEGIN (EXPRESSION);
 624 }
 625
 626 void
 627 ldlex_both (void)
 628 {
 629   *(state_stack_p)++ = yy_start;
 630   BEGIN (BOTH);
 631 }
 632
 633 void
 634 ldlex_popstate (void)
 635 {
 636   yy_start = *(--state_stack_p);
 637 }
 638
 639 /* Return the current file name, or the previous file if no file is
 640    current.  */
 641
 642 const char*
 643 ldlex_filename (void)
 644 {
 645   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 646 }
 647 \f
 648
 649 /* Place up to MAX_SIZE characters in BUF and return
 650    either the number of characters read, or 0 to indicate EOF.  */
 651
 652 static int
 653 yy_input (char *buf, int max_size)
 654 {
 655   int result = 0;
 656   if (YY_CURRENT_BUFFER->yy_input_file)
 657     {
 658       if (yyin)
 659         {
 660           result = fread (buf, 1, max_size, yyin);
 661           if (result < max_size && ferror (yyin))
 662             einfo (_("%F%P: read in flex scanner failed\n"));
 663         }
 664     }
 665   return result;
 666 }
 667
 668 /* Eat the rest of a C-style comment.  */
 669
 670 static void
 671 comment (void)
 672 {
 673   int c;
 674
 675   while (1)
 676     {
 677       c = input();
 678       while (c != '*' && c != 0)
 679         {
 680           if (c == '\n')
 681             lineno++;
 682           c = input();
 683         }
 684
 685       if (c == '*')
 686         {
 687           c = input();
 688           while (c == '*')
 689             c = input();
 690           if (c == '/')
 691             break;                      /* found the end */
 692         }
 693
 694       if (c == '\n')
 695         lineno++;
 696
 697       if (c == 0)
 698         {
 699           einfo (_("%F%P: EOF in comment\n"));
 700           break;
 701         }
 702     }
 703 }
 704
 705 /* Warn the user about a garbage character WHAT in the input
 706    in context WHERE.  */
 707
 708 static void
 709 lex_warn_invalid (char *where, char *what)
 710 {
 711   char buf[5];
 712
 713   /* If we have found an input file whose format we do not recognize,
 714      and we are therefore treating it as a linker script, and we find
 715      an invalid character, then most likely this is a real object file
 716      of some different format.  Treat it as such.  */
 717   if (ldfile_assumed_script)
 718     {
 719       bfd_set_error (bfd_error_file_not_recognized);
 720       einfo (_("%F%s: file not recognized: %E\n"), ldlex_filename ());
 721     }
 722
 723   if (! ISPRINT (*what))
 724     {
 725       sprintf (buf, "\\%03o", *(unsigned char *) what);
 726       what = buf;
 727     }
 728
 729   einfo (_("%P:%pS: ignoring invalid character `%s'%s\n"), NULL, what, where);
 730 }