ld/ldlex.l

   1 %{
   2
   3 /* Copyright (C) 1991 Free Software Foundation, Inc.
   4
   5 This file is part of GLD, the Gnu Linker.
   6
   7 GLD is free software; you can redistribute it and/or modify
   8 it under the terms of the GNU General Public License as published by
   9 the Free Software Foundation; either version 2, or (at your option)
  10 any later version.
  11
  12 GLD is distributed in the hope that it will be useful,
  13 but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 GNU General Public License for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GLD; see the file COPYING.  If not, write to
  19 the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  */
  20
  21 /*
  22 This was written by steve chamberlain
  23                     sac@cygnus.com
  24 */
  25
  26
  27 #include <ansidecl.h>
  28 #include "bfd.h"
  29 #include "ldgram.h"
  30
  31 int ldgram_in_defsym;
  32 extern int ldgram_had_equals;
  33 extern int ldgram_in_script;
  34
  35 int hex_mode;
  36 extern int fgetc();
  37 extern int yyparse();
  38
  39
  40
  41 char *buystring();
  42
  43 unsigned int lineno = 1;
  44 int old;
  45
  46 static comment();
  47
  48 #undef YY_INPUT
  49 #define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)
  50 #undef YY_FATAL_ERROR
  51 #define YY_FATAL_ERROR ;
  52 #define MAX_INCLUDE_DEPTH 10
  53 YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  54 char *file_name_stack[MAX_INCLUDE_DEPTH];
  55 unsigned int include_stack_ptr = 0;
  56
  57
  58 /* STATES
  59         COMMAND         on command line
  60         COMMENT         in a C comment
  61         EXPRESSION      definiatelyt in an expression
  62         SCRIPT          definately in a script
  63         SOMEWHERE       either EXPRESSION or SCRIPT
  64         MRI             in an MRI script
  65 */
  66 #define RTOKEN(x)  {  yylval.token = x; return x; }
  67 %}
  68
  69 %a 4000
  70 %o 5000
  71
  72 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  73 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  74 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  75 SYMBOLCHARN     [_a-zA-Z\/\.\\0-9]
  76 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  77 FILENAME        {FILENAMECHAR}+
  78 WHITE           [ \t\n]+
  79
  80 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
  81
  82
  83 %s COMMAND
  84 %s SCRIPT
  85 %s EXPRESSION
  86 %s COMMENT
  87 %s BOTH
  88 %s DEFSYMEXP
  89 %s MRI
  90 %%
  91
  92
  93 <BOTH,SCRIPT,EXPRESSION,COMMAND>"/*"    { comment(); }
  94
  95
  96 <DEFSYMEXP>"-"                  { RTOKEN('-');}
  97 <DEFSYMEXP>"+"                  { RTOKEN('+');}
  98 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = buystring(yytext); return NAME; }
  99 <DEFSYMEXP>[ \t]                { RTOKEN(DEFSYMEND); }
 100 <DEFSYMEXP>"="                  { RTOKEN('='); }
 101 <COMMAND>"--help"               { return OPTION_help; }
 102 <COMMAND>"--version"            { return OPTION_version; }
 103 <COMMAND>"-defsym"{WHITE}*      { return OPTION_defsym; }
 104 <COMMAND>"-format"              { return OPTION_format; }
 105 <COMMAND>"-noinhibit-exec"      { return OPTION_noinhibit_exec; }
 106 <COMMAND>"-noinhibit_exec"      { return OPTION_noinhibit_exec; }
 107 <COMMAND>"-oformat"             { return OPTION_oformat; }
 108 <COMMAND>"-sort-common"         { return OPTION_sort_common;}
 109 <COMMAND>"-sort_common"         { return OPTION_sort_common;}
 110 <COMMAND>"-warn-common"         { return OPTION_warn_common;}
 111 <COMMAND>"-n"                   { return OPTION_n; }
 112 <COMMAND>"-N"                   { return OPTION_N; }
 113 <COMMAND>"-r"                   { return OPTION_r; }
 114 <COMMAND>"-relax"               { return OPTION_relax; }
 115 <COMMAND>"-i"                   { return OPTION_r; }
 116 <COMMAND>"-Ur"                  { return OPTION_Ur; }
 117 <COMMAND>"-o"                   { return OPTION_o; }
 118 <COMMAND>"-g"                   { return OPTION_g; }
 119 <COMMAND>"-e"                   { return OPTION_e; }
 120 <COMMAND>"-b"                   { return OPTION_b; }
 121 <COMMAND>"-dc"                  { return OPTION_dc; }
 122 <COMMAND>"-dp"                  { return OPTION_dp; }
 123 <COMMAND>"-d"                   { return OPTION_d; }
 124 <COMMAND>"-v"                   { return OPTION_v; }
 125 <COMMAND>"-V"                   { return OPTION_V; }
 126 <COMMAND>"-m"                   { return OPTION_m; }
 127 <COMMAND>"-m"{FILENAME}         { return OPTION_memul; }
 128 <COMMAND>"-M"                   { return OPTION_M; }
 129 <COMMAND>"-Map"                 { return OPTION_Map;}
 130 <COMMAND>"-t"                   { return OPTION_t; }
 131 <COMMAND>"-X"                   { return OPTION_X; }
 132 <COMMAND>"-x"                   { return OPTION_x; }
 133 <COMMAND>"-c"                   { return OPTION_c; }
 134 <COMMAND>"-R"                   { return OPTION_R; }
 135 <COMMAND>"-u"                   { return OPTION_u; }
 136 <COMMAND>"-s"                   { return OPTION_s; }
 137 <COMMAND>"-S"                   { return OPTION_S; }
 138 <COMMAND>"-Bstat"               { return OPTION_Bstatic; }
 139 <COMMAND>"-B"{FILENAME}         { /* Ignored */ }
 140 <COMMAND>"-l"{FILENAME}         {
 141                                         yylval.name = buystring(yytext+2);
 142                                         return OPTION_l;
 143                                 }
 144
 145 <COMMAND>"-L"{FILENAME}         {
 146                                         yylval.name = buystring(yytext+2);
 147                                         return OPTION_Lfile;
 148                                 }
 149 <COMMAND>"-L"                   { return OPTION_L; }
 150 <COMMAND>"-Ttext"               {
 151                                  yylval.name = ".text";
 152                                  return OPTION_Texp;
 153                                 }
 154 <COMMAND>"-Tdata"               {
 155                                  yylval.name = ".data";
 156                                  return OPTION_Texp;
 157                                }
 158 <COMMAND>"-Tbss"                {
 159                                  yylval.name = ".bss";
 160                                  return OPTION_Texp;
 161                                }
 162 <COMMAND>"-O"{FILENAME}         {
 163                                 yylval.name = buystring(yytext+2);
 164                                 return OPTION_Texp;
 165                                 }
 166
 167 <COMMAND>"-T"{FILENAME}         {
 168                                  yylval.name = buystring(yytext+2);
 169                                  return OPTION_Tfile;
 170                                }
 171 <COMMAND>"-T"                   {
 172                                  return OPTION_T;
 173                                }
 174
 175 <COMMAND>"-F"{FILENAME}         {
 176                                  return OPTION_F;
 177                                }
 178 <COMMAND>"-F"                   {
 179                                  return OPTION_F;
 180                                }
 181
 182 <COMMAND>"-y"{FILENAME}         {
 183                                         yylval.name = buystring(yytext+2);
 184                                         return OPTION_y;
 185                                 }
 186
 187 <COMMAND>"-A"{FILENAME}         {
 188                                         yylval.name = buystring(yytext+2);
 189                                         return OPTION_Aarch;
 190                                 }
 191
 192 <COMMAND>"-retain-symbols-file" { return OPTION_RETAIN_SYMBOLS_FILE; }
 193
 194 <COMMAND>"-EB"                  {
 195                                         return OPTION_EB;
 196                                 }
 197 <COMMAND>"-EL"                  {
 198                                         return OPTION_EL;
 199                                 }
 200 <COMMAND>"-G"                   {
 201                                         return OPTION_G;
 202                                 }
 203 <COMMAND>"-G"([0-9])+           {
 204                                         yylval.integer = atoi (yytext + 2);
 205                                         return OPTION_Gval;
 206                                 }
 207
 208 <COMMAND>"-Qy"                  {       return OPTION_Qy; }
 209 <COMMAND>"-dn"                  {       return OPTION_dn; }
 210 <COMMAND>"-Y"                   {       return OPTION_Y;  }
 211 <COMMAND>"-YP,"{FILENAME}       {
 212                                         yylval.name = buystring (yytext+4);
 213                                         return OPTION_YP;
 214                                 }
 215 <COMMAND>"-non_shared"          {       return OPTION_non_shared; }
 216 <COMMAND>"-call_shared"         {       return OPTION_call_shared; }
 217
 218 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 219                                 yylval.integer = bfd_scan_vma (yytext+1, 0,16);
 220                                 return INT;
 221                         }
 222
 223 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|X|B|O|D) {
 224                                    int base ;
 225                                    switch (yytext[yyleng-1]) {
 226                                     case 'X':
 227                                     case 'H':
 228                                      base = 16;
 229                                      break;
 230                                     case 'O':
 231                                      base = 8;
 232                                      break;
 233                                     case 'B':
 234                                      base = 2;
 235                                      break;
 236                                     default:
 237                                      base = 10;
 238                                    }
 239                                    yylval.integer = bfd_scan_vma (yytext+1, 0,
 240                                                                   base);
 241                                    return INT;
 242                                  }
 243 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>"$"?"0x"?([0-9A-Fa-f])+(M|K|m|k)? {
 244                                   yylval.integer = bfd_scan_vma (yytext, 0,
 245                                                                  hex_mode);
 246                                   if (yytext[yyleng-1]=='M'
 247                                         || yytext[yyleng-1] == 'm') {
 248                                       yylval.integer *= 1024*1024;
 249                                     }
 250                                   if (yytext[yyleng-1]=='K'
 251                                 || yytext[yyleng-1]=='k') {
 252                                       yylval.integer *= 1024;
 253                                     }
 254                                   return INT;
 255                                 }
 256 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 257 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 258 <BOTH,SCRIPT,EXPRESSION>"<<="   { RTOKEN(LSHIFTEQ);}
 259 <BOTH,SCRIPT,EXPRESSION>">>="   { RTOKEN(RSHIFTEQ);}
 260 <BOTH,SCRIPT,EXPRESSION>"||"    { RTOKEN(OROR);}
 261 <BOTH,SCRIPT,EXPRESSION>"=="    { RTOKEN(EQ);}
 262 <BOTH,SCRIPT,EXPRESSION>"!="    { RTOKEN(NE);}
 263 <BOTH,SCRIPT,EXPRESSION>">="    { RTOKEN(GE);}
 264 <BOTH,SCRIPT,EXPRESSION>"<="    { RTOKEN(LE);}
 265 <BOTH,SCRIPT,EXPRESSION>"<<"    { RTOKEN(LSHIFT);}
 266 <BOTH,SCRIPT,EXPRESSION>">>"    { RTOKEN(RSHIFT);}
 267 <BOTH,SCRIPT,EXPRESSION>"+="    { RTOKEN(PLUSEQ);}
 268 <BOTH,SCRIPT,EXPRESSION>"-="    { RTOKEN(MINUSEQ);}
 269 <BOTH,SCRIPT,EXPRESSION>"*="    { RTOKEN(MULTEQ);}
 270 <BOTH,SCRIPT,EXPRESSION>"/="    { RTOKEN(DIVEQ);}
 271 <BOTH,SCRIPT,EXPRESSION>"&="    { RTOKEN(ANDEQ);}
 272 <BOTH,SCRIPT,EXPRESSION>"|="    { RTOKEN(OREQ);}
 273 <BOTH,SCRIPT,EXPRESSION>"&&"    { RTOKEN(ANDAND);}
 274 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 275 <MRI,BOTH,SCRIPT,EXPRESSION>","         { RTOKEN(',');}
 276 <BOTH,SCRIPT,EXPRESSION>"&"             { RTOKEN('&');}
 277 <BOTH,SCRIPT,EXPRESSION>"|"             { RTOKEN('|');}
 278 <BOTH,SCRIPT,EXPRESSION>"~"             { RTOKEN('~');}
 279 <BOTH,SCRIPT,EXPRESSION>"!"             { RTOKEN('!');}
 280 <BOTH,SCRIPT,EXPRESSION>"?"             { RTOKEN('?');}
 281 <BOTH,SCRIPT,EXPRESSION>"*"             { RTOKEN('*');}
 282 <BOTH,SCRIPT,EXPRESSION>"+"             { RTOKEN('+');}
 283 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 284 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 285 <BOTH,SCRIPT,EXPRESSION>"%"             { RTOKEN('%');}
 286 <BOTH,SCRIPT,EXPRESSION>"<"             { RTOKEN('<');}
 287 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 288 <MRI,BOTH,SCRIPT,EXPRESSION>"="          { RTOKEN('=');}
 289 <BOTH,SCRIPT,EXPRESSION>"}"                     { RTOKEN('}') ; }
 290 <BOTH,SCRIPT,EXPRESSION>"{"                     { RTOKEN('{'); }
 291 <BOTH,SCRIPT,EXPRESSION>")"                     { RTOKEN(')');}
 292 <BOTH,SCRIPT,EXPRESSION>"("                     { RTOKEN('(');}
 293 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 294 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 295 <BOTH,SCRIPT,EXPRESSION>":"             { RTOKEN(':'); }
 296 <BOTH,SCRIPT,EXPRESSION>";"             { RTOKEN(';');}
 297 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 298 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 299 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 300 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 301 <BOTH,SCRIPT>"BLOCK"                    { RTOKEN(BLOCK);}
 302 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 303 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 304 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 305 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 306 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 307 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 308 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 309 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 310 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 311 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 312 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 313 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 314 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 315 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 316 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 317 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 318 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 319 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 320 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 321 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 322 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 323 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 324 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 325 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 326 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 327 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 328 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 329 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 330 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 331 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"                { RTOKEN(NOLOAD);}
 332 <BOTH,SCRIPT>"DSECT"                    { RTOKEN(DSECT);}
 333 <BOTH,SCRIPT>"COPY"                     { RTOKEN(COPY);}
 334 <BOTH,SCRIPT>"INFO"                     { RTOKEN(INFO);}
 335 <BOTH,SCRIPT>"OVERLAY"          { RTOKEN(OVERLAY);}
 336 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 337 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 338 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 339 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 340 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 341 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 342 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 343 <MRI>"*".*                      { /* Mri comment line */ }
 344 <MRI>"END"                      { RTOKEN(ENDWORD); }
 345 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 346 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 347
 348 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 349 <MRI>"BASE"                     { RTOKEN(BASE); }
 350 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 351 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 352 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 353 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 354 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 355 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 356 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 357 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 358 <MRI>"SECT"                     { RTOKEN(SECT); }
 359 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 360 <MRI>"end"                      { RTOKEN(ENDWORD); }
 361 <MRI>"chip"                     { RTOKEN(CHIP); }
 362 <MRI>"load"                     { RTOKEN(LOAD); }
 363 <MRI>"order"                    { RTOKEN(ORDER); }
 364 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 365 <MRI>"format"                   { RTOKEN(FORMAT); }
 366 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 367 <MRI>"sect"                     { RTOKEN(SECT); }
 368 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 369
 370 <COMMAND>{CMDFILENAMECHAR1}{CMDFILENAMECHAR}*   {
 371                                  yylval.name = buystring(yytext);
 372                                   return NAME;
 373                                 }
 374
 375
 376 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 377 /* Filename without commas, needed to parse mri stuff */
 378                                  yylval.name = buystring(yytext);
 379                                   return NAME;
 380                                 }
 381
 382
 383 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 384                                  yylval.name = buystring(yytext);
 385                                   return NAME;
 386                                 }
 387 <SCRIPT,COMMAND>{FILENAMECHAR}* { yylval.name = buystring(yytext);
 388                                   return NAME;
 389                                 }
 390
 391 <EXPRESSION,BOTH,COMMAND,SCRIPT>"\""[^\"]*"\"" {
 392                                         /* No matter the state, quotes
 393                                            give what's inside */
 394                                         yylval.name = buystring(yytext+1);
 395                                         yylval.name[yyleng-2] = 0;
 396                                         return NAME;
 397                                 }
 398 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 399 <MRI,COMMAND,BOTH,SCRIPT,EXPRESSION>[ \t]
 400
 401 <<EOF>> {
 402   extern char *ldfile_input_filename;
 403   include_stack_ptr--;
 404
 405   if (include_stack_ptr == 0)
 406   {
 407     yyterminate();
 408   }
 409   else
 410   {
 411     yy_switch_to_buffer(include_stack[include_stack_ptr]);
 412
 413   }
 414   if (include_stack_ptr==1)
 415   {
 416     BEGIN(COMMAND);
 417   }
 418   else
 419   {
 420     BEGIN(SCRIPT);
 421     ldfile_input_filename = file_name_stack[include_stack_ptr-1];
 422   }
 423
 424   return END;
 425 }
 426
 427 %%
 428
 429 void
 430 lex_push_file (file, name)
 431      FILE *file;
 432      char *name;
 433 {
 434   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 435   {
 436     einfo("%F:includes nested too deeply\n");
 437   }
 438   file_name_stack[include_stack_ptr] = name;
 439   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 440
 441   include_stack_ptr++;
 442   yyin = file;
 443   yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 444
 445   BEGIN(SCRIPT);
 446 }
 447
 448 YY_BUFFER_STATE
 449 yy_create_string_buffer (string,  size)
 450      CONST char *string;
 451      int size;
 452 {
 453   YY_BUFFER_STATE b;
 454
 455   b = (YY_BUFFER_STATE) malloc( sizeof( struct yy_buffer_state ) );
 456   b->yy_input_file = 0;
 457
 458   if ( ! b )
 459    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 460
 461   b->yy_buf_size = size;
 462
 463   /* yy_ch_buf has to be 2 characters longer than the size given because
 464    * we need to put in 2 end-of-buffer characters.
 465    */
 466   b->yy_ch_buf = (YY_CHAR *) malloc( (unsigned) (b->yy_buf_size + 3) );
 467
 468   if ( ! b->yy_ch_buf )
 469    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 470
 471
 472   b->yy_ch_buf[0] = '\n';
 473   strcpy(b->yy_ch_buf+1,  string);
 474   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 475   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 476     b->yy_n_chars = size+1;
 477   b->yy_buf_pos = &b->yy_ch_buf[1];
 478
 479   b->yy_eof_status = EOF_NOT_SEEN;
 480
 481   return ( b );
 482 }
 483
 484
 485
 486 void
 487 lex_redirect (string)
 488      CONST  char *string;
 489 {
 490   YY_BUFFER_STATE tmp;
 491
 492   int len = strlen(string);
 493   yy_init = 0  ;
 494   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 495   {
 496     einfo("%F: macros nested too deeply\n");
 497   }
 498   file_name_stack[include_stack_ptr] = "redirect";
 499   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 500   include_stack_ptr++;
 501   tmp =   yy_create_string_buffer(string, len);
 502
 503   yy_switch_to_buffer(tmp);
 504   BEGIN(COMMAND);
 505   yyout = stdout;
 506 }
 507
 508 int state_stack[20];
 509 int *state_stack_p = state_stack;
 510
 511 void
 512 ldlex_script ()
 513 {
 514   *(state_stack_p)++ = yy_start;
 515
 516   BEGIN(SCRIPT);
 517 }
 518
 519
 520 void
 521 ldlex_mri_script ()
 522 {
 523   *(state_stack_p)++ = yy_start;
 524   BEGIN(MRI);
 525 }
 526
 527 void
 528 ldlex_defsym ()
 529 {
 530   *(state_stack_p)++ = yy_start;
 531   BEGIN(DEFSYMEXP);
 532 }
 533
 534 void
 535 ldlex_expression ()
 536 {
 537   *(state_stack_p)++ = yy_start;
 538   BEGIN(EXPRESSION);
 539
 540 }
 541 void
 542 ldlex_both ()
 543 {
 544   *(state_stack_p)++ = yy_start;
 545   BEGIN(BOTH);
 546 }
 547 void
 548 ldlex_command ()
 549 {
 550   *(state_stack_p)++ = yy_start;
 551   BEGIN(COMMAND);
 552 }
 553
 554 void
 555 ldlex_popstate ()
 556 {
 557   yy_start = *(--state_stack_p);
 558 }
 559
 560 yy_input(buf, result, max_size)
 561 char *buf;
 562 int *result;
 563 int max_size;
 564 {
 565   *result = 0;
 566   if (yy_current_buffer->yy_input_file)
 567   {
 568     if (yyin)
 569      if ( (*result = read( fileno(yyin), (char *) buf, max_size )) < 0 )
 570       YY_FATAL_ERROR( "read() in flex scanner failed" );
 571   }
 572 }
 573
 574 static
 575 comment()
 576 {
 577   int c;
 578   while (1)
 579   {
 580     c = input();
 581     while (c !='*' && c != EOF)
 582     {
 583       if (c == '\n') lineno++;
 584       c = input();
 585     }
 586
 587
 588     if (c == '*')
 589     {
 590       c = input();
 591       while ( c == '*')
 592        c = input();
 593       if ( c == '/' )
 594        break;                   /* found the end */
 595     }
 596
 597     if ( c == EOF )
 598     {
 599       einfo( "%F%P :EOF in comment\n");
 600       break;
 601     }
 602   }
 603 }