ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREG(2.5)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7
   8 AM_INIT_AUTOMAKE(ld, 2.9.4)
   9
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(targets,
  13 [  --enable-targets        alternative target configurations],
  14 [case "${enableval}" in
  15   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  16             ;;
  17   no)       enable_targets= ;;
  18   *)        enable_targets=$enableval ;;
  19 esac])dnl
  20 AC_ARG_ENABLE(64-bit-bfd,
  21 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  22 [case "${enableval}" in
  23   yes)  want64=true  ;;
  24   no)   want64=false ;;
  25   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  26 esac],[want64=false])dnl
  27
  28 AM_CONFIG_HEADER(config.h:config.in)
  29
  30 if test -z "$target" ; then
  31     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  32 fi
  33 if test -z "$host" ; then
  34     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  35 fi
  36
  37 # host-specific stuff:
  38
  39 AC_PROG_CC
  40 AM_PROG_INSTALL
  41
  42 ALL_LINGUAS=
  43 CY_GNU_GETTEXT
  44
  45 AM_EXEEXT
  46
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49
  50 AM_MAINTAINER_MODE
  51
  52 . ${srcdir}/configure.host
  53
  54 AC_SUBST(HDEFINES)
  55 AC_SUBST(HOSTING_CRT0)
  56 AC_SUBST(HOSTING_LIBS)
  57 AC_SUBST(NATIVE_LIB_DIRS)
  58
  59 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
  60 AC_CHECK_FUNCS(sbrk)
  61 AC_HEADER_DIRENT
  62
  63 BFD_BINARY_FOPEN
  64
  65 BFD_NEED_DECLARATION(strstr)
  66 BFD_NEED_DECLARATION(free)
  67 BFD_NEED_DECLARATION(sbrk)
  68 BFD_NEED_DECLARATION(getenv)
  69
  70 # target-specific stuff:
  71
  72 all_targets=
  73 EMUL=
  74 all_emuls=
  75 all_emul_extras=
  76
  77 dnl We need to get an arbitrary number of tdir definitions into
  78 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
  79 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
  80 dnl file.
  81 rm -f tdirs
  82
  83 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
  84 do
  85   if test "$targ_alias" = "all"; then
  86     all_targets=true
  87   else
  88     # Canonicalize the secondary target names.
  89     result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ_alias 2>/dev/null`
  90     if test -n "$result"; then
  91         targ=$result
  92     else
  93         targ=$targ_alias
  94     fi
  95
  96     . ${srcdir}/configure.tgt
  97
  98     if test "$targ" = "$target"; then
  99       EMUL=$targ_emul
 100     fi
 101
 102     for i in $targ_emul $targ_extra_emuls; do
 103         case " $all_emuls " in
 104         *" e${i}.o "*) ;;
 105         *)
 106           all_emuls="$all_emuls e${i}.o"
 107           eval result=\$tdir_$i
 108           test -z "$result" && result=$targ_alias
 109           echo tdir_$i=$result >> tdirs
 110           ;;
 111         esac
 112     done
 113
 114     for i in $targ_extra_ofiles; do
 115         case " $all_emul_extras " in
 116         *" ${i} "*) ;;
 117         *)
 118           all_emul_extras="$all_emul_extras ${i}"
 119           ;;
 120         esac
 121     done
 122   fi
 123 done
 124
 125 AC_SUBST(EMUL)
 126
 127 TDIRS=tdirs
 128 AC_SUBST_FILE(TDIRS)
 129
 130 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 131 dnl target, and in those cases we should also build the 64 bit
 132 dnl emulations.
 133 if test x${all_targets} = xtrue; then
 134   if test x${want64} = xtrue; then
 135     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 136   else
 137     EMULATION_OFILES='$(ALL_EMULATIONS)'
 138   fi
 139   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 140 else
 141   EMULATION_OFILES=$all_emuls
 142   EMUL_EXTRA_OFILES=$all_emul_extras
 143 fi
 144 AC_SUBST(EMULATION_OFILES)
 145 AC_SUBST(EMUL_EXTRA_OFILES)
 146
 147 if test x${enable_static} = xno; then
 148   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 149 else
 150   TESTBFDLIB="../bfd/.libs/libbfd.a"
 151 fi
 152 AC_SUBST(TESTBFDLIB)
 153
 154 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 155 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])