ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREG(2.13)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7
   8 AM_INIT_AUTOMAKE(ld, 2.9.5)
   9
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(targets,
  13 [  --enable-targets        alternative target configurations],
  14 [case "${enableval}" in
  15   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  16             ;;
  17   no)       enable_targets= ;;
  18   *)        enable_targets=$enableval ;;
  19 esac])dnl
  20 AC_ARG_ENABLE(64-bit-bfd,
  21 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  22 [case "${enableval}" in
  23   yes)  want64=true  ;;
  24   no)   want64=false ;;
  25   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  26 esac],[want64=false])dnl
  27
  28 AM_CONFIG_HEADER(config.h:config.in)
  29
  30 if test -z "$target" ; then
  31     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  32 fi
  33 if test -z "$host" ; then
  34     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  35 fi
  36
  37 # host-specific stuff:
  38
  39 AC_PROG_CC
  40 AC_PROG_INSTALL
  41
  42 ALL_LINGUAS=
  43 CY_GNU_GETTEXT
  44
  45 AC_EXEEXT
  46
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49
  50 AM_MAINTAINER_MODE
  51
  52 . ${srcdir}/configure.host
  53
  54 AC_SUBST(HDEFINES)
  55 AC_SUBST(HOSTING_CRT0)
  56 AC_SUBST(HOSTING_LIBS)
  57 AC_SUBST(NATIVE_LIB_DIRS)
  58
  59 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
  60 AC_CHECK_FUNCS(sbrk)
  61 AC_HEADER_DIRENT
  62
  63 BFD_BINARY_FOPEN
  64
  65 BFD_NEED_DECLARATION(strstr)
  66 BFD_NEED_DECLARATION(free)
  67 BFD_NEED_DECLARATION(sbrk)
  68 BFD_NEED_DECLARATION(getenv)
  69 BFD_NEED_DECLARATION(environ)
  70
  71 # When converting linker scripts into strings for use in emulation
  72 # files, use astring.sed if the compiler supports ANSI string
  73 # concatenation, or ostring.sed otherwise.  This is to support the
  74 # broken Microsoft MSVC compiler, which limits the length of string
  75 # constants, while still supporting pre-ANSI compilers which do not
  76 # support string concatenation.
  77 AC_MSG_CHECKING([whether ANSI C string concatenation works])
  78 AC_CACHE_VAL(ld_cv_string_concatenation,
  79 [AC_TRY_COMPILE(,[char *a = "a" "a";],
  80   [ld_cv_string_concatenation=yes],
  81   [ld_cv_string_concatenation=no])])
  82 AC_MSG_RESULT($ld_cv_string_concatenation)
  83 if test "$ld_cv_string_concatenation" = "yes"; then
  84   STRINGIFY=astring.sed
  85 else
  86   STRINGIFY=ostring.sed
  87 fi
  88 AC_SUBST(STRINGIFY)
  89
  90 # target-specific stuff:
  91
  92 all_targets=
  93 EMUL=
  94 all_emuls=
  95 all_emul_extras=
  96 all_libpath=
  97
  98 dnl We need to get an arbitrary number of tdir definitions into
  99 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 100 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 101 dnl file.
 102 rm -f tdirs
 103
 104 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 105 do
 106   if test "$targ_alias" = "all"; then
 107     all_targets=true
 108   else
 109     # Canonicalize the secondary target names.
 110     result=`$ac_config_sub $targ_alias 2>/dev/null`
 111     if test -n "$result"; then
 112         targ=$result
 113     else
 114         targ=$targ_alias
 115     fi
 116
 117     . ${srcdir}/configure.tgt
 118
 119     if test "$targ" = "$target"; then
 120       EMUL=$targ_emul
 121     fi
 122
 123     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 124         case " $all_emuls " in
 125         *" e${i}.o "*) ;;
 126         *)
 127           all_emuls="$all_emuls e${i}.o"
 128           eval result=\$tdir_$i
 129           test -z "$result" && result=$targ_alias
 130           echo tdir_$i=$result >> tdirs
 131           ;;
 132         esac
 133     done
 134
 135     for i in $targ_emul $targ_extra_libpath; do
 136         case " $all_libpath " in
 137         *" ${i} "*) ;;
 138         *)
 139           if test -z "$all_libpath"; then
 140             all_libpath=${i}
 141           else
 142             all_libpath="$all_libpath ${i}"
 143           fi
 144           ;;
 145         esac
 146     done
 147
 148     for i in $targ_extra_ofiles; do
 149         case " $all_emul_extras " in
 150         *" ${i} "*) ;;
 151         *)
 152           all_emul_extras="$all_emul_extras ${i}"
 153           ;;
 154         esac
 155     done
 156   fi
 157 done
 158
 159 AC_SUBST(EMUL)
 160
 161 TDIRS=tdirs
 162 AC_SUBST_FILE(TDIRS)
 163
 164 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 165 dnl target, and in those cases we should also build the 64 bit
 166 dnl emulations.
 167 if test x${all_targets} = xtrue; then
 168   if test x${want64} = xtrue; then
 169     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 170   else
 171     EMULATION_OFILES='$(ALL_EMULATIONS)'
 172   fi
 173   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 174 else
 175   EMULATION_OFILES=$all_emuls
 176   EMUL_EXTRA_OFILES=$all_emul_extras
 177 fi
 178 AC_SUBST(EMULATION_OFILES)
 179 AC_SUBST(EMUL_EXTRA_OFILES)
 180
 181 EMULATION_LIBPATH=$all_libpath
 182 AC_SUBST(EMULATION_LIBPATH)
 183
 184 if test x${enable_static} = xno; then
 185   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 186 else
 187   TESTBFDLIB="../bfd/.libs/libbfd.a"
 188 fi
 189 AC_SUBST(TESTBFDLIB)
 190
 191 target_vendor=${target_vendor=$host_vendor}
 192 case "$target_vendor" in
 193   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 194   *)  EXTRA_SHLIB_EXTENSION= ;;
 195 esac
 196 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 197   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 198    [Additional extension a shared object might have.])
 199 fi
 200
 201 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 202 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])