ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREG(2.0)
   4 AC_INIT(ldmain.c)
   5
   6 AC_ARG_ENABLE(targets,
   7 [  --enable-targets        alternative target configurations],
   8 [case "${enableval}" in
   9   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  10             ;;
  11   no)       enable_targets= ;;
  12   *)        enable_targets=$enableval ;;
  13 esac])dnl
  14 AC_ARG_ENABLE(shared,
  15 [  --enable-shared         build shared BFD library],
  16 [case "${enableval}" in
  17   yes) shared=true ;;
  18   no)  shared=false ;;
  19   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  20 esac])dnl
  21
  22 AC_CONFIG_HEADER(config.h:config.in)
  23
  24 AC_CONFIG_AUX_DIR(`cd $srcdir/..; pwd`)
  25 AC_CANONICAL_SYSTEM
  26 if test -z "$target" ; then
  27     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  28 fi
  29 if test -z "$host" ; then
  30     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  31 fi
  32 AC_ARG_PROGRAM
  33
  34 # host-specific stuff:
  35
  36 . ${srcdir}/configure.host
  37
  38 AC_PROG_CC
  39 AC_SUBST(CFLAGS)
  40 AC_SUBST(HLDFLAGS)
  41 AC_SUBST(HDEFINES)
  42 AC_SUBST(HOSTING_CRT0)
  43 AC_SUBST(HOSTING_LIBS)
  44 AC_SUBST(NATIVE_LIB_DIRS)
  45
  46 # For most hosts we can use a simple definition to pick up the BFD and
  47 # opcodes libraries.  However, if we are building shared libraries, we
  48 # need to handle some hosts specially.
  49 BFDLIB='-L../bfd -lbfd'
  50 if test "${shared}" = "true"; then
  51   case "${host}" in
  52   *-*-sunos*)
  53     # On SunOS, we must link against the name we are going to install,
  54     # not -lbfd, since SunOS does not support SONAME.
  55     BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
  56     ;;
  57   esac
  58 fi
  59 AC_SUBST(BFDLIB)
  60
  61 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
  62 AC_CHECK_FUNCS(sbrk)
  63 AC_HEADER_DIRENT
  64
  65 BFD_BINARY_FOPEN
  66
  67 BFD_NEED_DECLARATION(free)
  68
  69 # target-specific stuff:
  70
  71 # Canonicalize the secondary target names.
  72 if test -n "$enable_targets"; then
  73     for targ in `echo $enable_targets | sed 's/,/ /g'`
  74     do
  75         result=`$ac_config_sub $targ 2>/dev/null`
  76         if test -n "$result"; then
  77             canon_targets="$canon_targets $result"
  78         else
  79             # Allow targets that config.sub doesn't recognize, like "all".
  80             canon_targets="$canon_targets $targ"
  81         fi
  82     done
  83 fi
  84
  85 all_targets=false
  86 EMUL=
  87 all_emuls=
  88
  89 for targ in $target $canon_targets
  90 do
  91     if test "x$targ" = "xall"; then
  92         all_targets=true
  93     else
  94         . ${srcdir}/configure.tgt
  95
  96         if test "x$targ" = "x$target"; then
  97             EMUL=${targ_emul}
  98         fi
  99
 100         all_emuls="${all_emuls} ${targ_emul} ${targ_extra_emuls}"
 101     fi
 102 done
 103
 104 AC_SUBST(EMUL)
 105
 106 if test x${all_targets} = xfalse; then
 107     # uniq the list.
 108     f=""
 109     for i in $all_emuls ; do
 110         case " $f " in
 111         *" e$i.o "*) ;;
 112         *) f="$f e$i.o" ;;
 113         esac
 114     done
 115
 116     EMULATION_OFILES="$f"
 117
 118 else    # all_targets is true
 119     EMULATION_OFILES='$(ALL_EMULATIONS)'
 120 fi      # all_targets is true
 121
 122 AC_SUBST(EMULATION_OFILES)
 123
 124 AC_OUTPUT(Makefile,
 125 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])