ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_BUILD
   9 AC_ISC_POSIX
  10
  11 changequote(,)dnl
  12 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  13 changequote([,])dnl
  14 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  15 AM_MAINTAINER_MODE
  16
  17 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  18 AC_ARG_ENABLE(targets,
  19 [  --enable-targets        alternative target configurations],
  20 [case "${enableval}" in
  21   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(64-bit-bfd,
  27 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  28 [case "${enableval}" in
  29   yes)  want64=true  ;;
  30   no)   want64=false ;;
  31   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  32 esac],[want64=false])dnl
  33
  34 AC_ARG_WITH(sysroot,
  35 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  36 [
  37  case ${with_sysroot} in
  38  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  39  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  40  esac
  41
  42  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  43  use_sysroot=yes
  44
  45  if test "x$prefix" = xNONE; then
  46   test_prefix=/usr/local
  47  else
  48   test_prefix=$prefix
  49  fi
  50  if test "x$exec_prefix" = xNONE; then
  51   test_exec_prefix=$test_prefix
  52  else
  53   test_exec_prefix=$exec_prefix
  54  fi
  55  case ${TARGET_SYSTEM_ROOT} in
  56  "${test_prefix}"|"${test_prefix}/"*|\
  57  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  58  '${prefix}'|'${prefix}/'*|\
  59  '${exec_prefix}'|'${exec_prefix}/'*)
  60    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  61    TARGET_SYSTEM_ROOT_DEFINE="$t"
  62    ;;
  63  esac
  64 ], [
  65  use_sysroot=no
  66  TARGET_SYSTEM_ROOT=
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  68 ])
  69 AC_SUBST(use_sysroot)
  70 AC_SUBST(TARGET_SYSTEM_ROOT)
  71 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  72
  73 dnl Use --enable-gold to decide if this linker should be the default.
  74 dnl "install_as_default" is set to false if gold is the default linker.
  75 dnl "installed_linker" is the installed BFD linker name.
  76 AC_ARG_ENABLE(gold,
  77 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  78 [case "${enableval}" in
  79  default)
  80    install_as_default=no
  81    installed_linker=ld.bfd
  82    ;;
  83  yes|no)
  84    install_as_default=yes
  85    installed_linker=ld.bfd
  86    ;;
  87  *)
  88    AC_MSG_ERROR([invalid --enable-gold argument])
  89    ;;
  90  esac],
  91 [install_as_default=yes
  92  installed_linker=ld.bfd])
  93 AC_SUBST(install_as_default)
  94 AC_SUBST(installed_linker)
  95
  96 AC_ARG_ENABLE([got],
  97 AS_HELP_STRING([--enable-got=<type>],
  98                [GOT handling scheme (target, single, negative, multigot)]),
  99 [case "${enableval}" in
 100   target | single | negative | multigot)  got_handling=$enableval ;;
 101   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 102 esac],
 103 [got_handling=target])
 104
 105 case "${got_handling}" in
 106   target)
 107     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 108               [Define to choose default GOT handling scheme]) ;;
 109   single)
 110     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 111               [Define to choose default GOT handling scheme]) ;;
 112   negative)
 113     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 114               [Define to choose default GOT handling scheme]) ;;
 115   multigot)
 116     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 117               [Define to choose default GOT handling scheme]) ;;
 118   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 119 esac
 120
 121 AM_BINUTILS_WARNINGS
 122
 123 AM_LC_MESSAGES
 124
 125 AC_CONFIG_HEADERS([config.h:config.in])
 126
 127 if test -z "$target" ; then
 128     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 129 fi
 130 if test -z "$host" ; then
 131     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 132 fi
 133
 134 # host-specific stuff:
 135
 136 AC_PROG_CC
 137 AC_PROG_CXX
 138 AC_GNU_SOURCE
 139 AC_USE_SYSTEM_EXTENSIONS
 140 ACX_LARGEFILE
 141 AC_PROG_INSTALL
 142
 143 LT_INIT
 144
 145 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it"
 146 ZW_GNU_GETTEXT_SISTER_DIR
 147 AM_PO_SUBDIRS
 148
 149 AC_EXEEXT
 150
 151 AC_PROG_YACC
 152 AM_PROG_LEX
 153
 154 AM_MAINTAINER_MODE
 155 AM_CONDITIONAL(GENINSRC_NEVER, false)
 156 ACX_PROG_CMP_IGNORE_INITIAL
 157
 158 . ${srcdir}/configure.host
 159
 160 AC_SUBST(HDEFINES)
 161 AC_SUBST(HOSTING_CRT0)
 162 AC_SUBST(HOSTING_LIBS)
 163 AC_SUBST(NATIVE_LIB_DIRS)
 164
 165 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 166 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 167 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 168 AC_CHECK_FUNCS(open lseek close)
 169 AC_HEADER_DIRENT
 170
 171 # Check for dlopen support and enable plugins if possible.
 172 enable_plugins=yes
 173 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 174 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 175 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 176 # We also support plugins on Windows (MinGW).
 177 if test x$enable_plugins = xno ; then
 178   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 179 fi
 180 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 181
 182 AC_ARG_ENABLE(initfini-array,
 183         [  --enable-initfini-array      use .init_array/.fini_array sections],
 184         [], [
 185 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 186                  gcc_cv_initfini_array, [dnl
 187   if test "x${build}" = "x${target}" ; then
 188     AC_RUN_IFELSE([AC_LANG_SOURCE([
 189 static int x = -1;
 190 int main (void) { return x; }
 191 int foo (void) { x = 0; }
 192 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 193              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 194              [gcc_cv_initfini_array=no])
 195    else
 196      gcc_cv_initfini_array=no
 197    fi])
 198   enable_initfini_array=$gcc_cv_initfini_array
 199 ])
 200 AC_SUBST(enable_initfini_array)
 201 if test $enable_initfini_array = yes; then
 202   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 203     [Define .init_array/.fini_array sections are available and working.])
 204 fi
 205
 206 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 207 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 208 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 209 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 210 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 211 if test $ld_cv_decl_getopt_unistd_h = yes; then
 212   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 213             [Is the prototype for getopt in <unistd.h> in the expected format?])
 214 fi
 215
 216 BFD_BINARY_FOPEN
 217
 218 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 219
 220 # Link in zlib if we can.  This is needed only for the bootstrap tests
 221 # right now, since those tests use libbfd, which depends on zlib.
 222 AM_ZLIB
 223
 224 # When converting linker scripts into strings for use in emulation
 225 # files, use astring.sed if the compiler supports ANSI string
 226 # concatenation, or ostring.sed otherwise.  This is to support the
 227 # broken Microsoft MSVC compiler, which limits the length of string
 228 # constants, while still supporting pre-ANSI compilers which do not
 229 # support string concatenation.
 230 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 231 AC_CACHE_VAL(ld_cv_string_concatenation,
 232 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 233   ld_cv_string_concatenation=yes,
 234   ld_cv_string_concatenation=no)])
 235 AC_MSG_RESULT($ld_cv_string_concatenation)
 236 if test "$ld_cv_string_concatenation" = "yes"; then
 237   STRINGIFY=astring.sed
 238 else
 239   STRINGIFY=ostring.sed
 240 fi
 241 AC_SUBST(STRINGIFY)
 242
 243 # target-specific stuff:
 244
 245 all_targets=
 246 EMUL=
 247 all_emuls=
 248 all_emul_extras=
 249 all_libpath=
 250
 251 dnl We need to get an arbitrary number of tdir definitions into
 252 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 253 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 254 dnl file.
 255 rm -f tdirs
 256
 257 # If the host is 64-bit, then we enable 64-bit targets by default.
 258 # This is consistent with what ../bfd/configure.in does.
 259 if test x${want64} = xfalse; then
 260   AC_CHECK_SIZEOF(void *)
 261   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 262     want64=true
 263   fi
 264 fi
 265
 266 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 267 do
 268   if test "$targ_alias" = "all"; then
 269     all_targets=true
 270   else
 271     # Canonicalize the secondary target names.
 272     result=`$ac_config_sub $targ_alias 2>/dev/null`
 273     if test -n "$result"; then
 274         targ=$result
 275     else
 276         targ=$targ_alias
 277     fi
 278
 279     . ${srcdir}/configure.tgt
 280
 281     if test "$targ" = "$target"; then
 282       EMUL=$targ_emul
 283     fi
 284
 285     if test x${want64} = xfalse; then
 286       . ${srcdir}/../bfd/config.bfd
 287     fi
 288
 289     if test x${want64} = xtrue; then
 290       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 291       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 292     fi
 293
 294     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 295         case " $all_emuls " in
 296         *" e${i}.o "*) ;;
 297         *)
 298           all_emuls="$all_emuls e${i}.o"
 299           eval result=\$tdir_$i
 300           test -z "$result" && result=$targ_alias
 301           echo tdir_$i=$result >> tdirs
 302           ;;
 303         esac
 304     done
 305
 306     for i in $targ_emul $targ_extra_libpath; do
 307         case " $all_libpath " in
 308         *" ${i} "*) ;;
 309         *)
 310           if test -z "$all_libpath"; then
 311             all_libpath=${i}
 312           else
 313             all_libpath="$all_libpath ${i}"
 314           fi
 315           ;;
 316         esac
 317     done
 318
 319     for i in $targ_extra_ofiles; do
 320         case " $all_emul_extras " in
 321         *" ${i} "*) ;;
 322         *)
 323           all_emul_extras="$all_emul_extras ${i}"
 324           ;;
 325         esac
 326     done
 327   fi
 328 done
 329
 330 AC_SUBST(EMUL)
 331
 332 TDIRS=tdirs
 333 AC_SUBST_FILE(TDIRS)
 334
 335 if test x${all_targets} = xtrue; then
 336   if test x${want64} = xtrue; then
 337     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 338   else
 339     EMULATION_OFILES='$(ALL_EMULATIONS)'
 340   fi
 341   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 342 else
 343   EMULATION_OFILES=$all_emuls
 344   EMUL_EXTRA_OFILES=$all_emul_extras
 345 fi
 346 AC_SUBST(EMULATION_OFILES)
 347 AC_SUBST(EMUL_EXTRA_OFILES)
 348 AC_SUBST(LIB_PATH)
 349
 350 EMULATION_LIBPATH=$all_libpath
 351 AC_SUBST(EMULATION_LIBPATH)
 352
 353 if test x${enable_static} = xno; then
 354   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 355 else
 356   TESTBFDLIB="../bfd/.libs/libbfd.a"
 357 fi
 358 AC_SUBST(TESTBFDLIB)
 359
 360 target_vendor=${target_vendor=$host_vendor}
 361 case "$target_vendor" in
 362   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 363   *)  EXTRA_SHLIB_EXTENSION= ;;
 364 esac
 365
 366 case "$target_os" in
 367   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 368 esac
 369
 370 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 371   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 372    [Additional extension a shared object might have.])
 373 fi
 374
 375 dnl Required by html, pdf, install-pdf and install-html
 376 AC_SUBST(datarootdir)
 377 AC_SUBST(docdir)
 378 AC_SUBST(htmldir)
 379 AC_SUBST(pdfdir)
 380
 381 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 382 AC_OUTPUT