ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  15 AC_ARG_ENABLE(targets,
  16 [  --enable-targets        alternative target configurations],
  17 [case "${enableval}" in
  18   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  19             ;;
  20   no)       enable_targets= ;;
  21   *)        enable_targets=$enableval ;;
  22 esac])dnl
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30
  31 AC_ARG_WITH(sysroot,
  32 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  33 [
  34  case ${with_sysroot} in
  35  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  36  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  37  esac
  38
  39  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  40  use_sysroot=yes
  41
  42  if test "x$prefix" = xNONE; then
  43   test_prefix=/usr/local
  44  else
  45   test_prefix=$prefix
  46  fi
  47  if test "x$exec_prefix" = xNONE; then
  48   test_exec_prefix=$test_prefix
  49  else
  50   test_exec_prefix=$exec_prefix
  51  fi
  52  case ${TARGET_SYSTEM_ROOT} in
  53  "${test_prefix}"|"${test_prefix}/"*|\
  54  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  55  '${prefix}'|'${prefix}/'*|\
  56  '${exec_prefix}'|'${exec_prefix}/'*)
  57    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  58    TARGET_SYSTEM_ROOT_DEFINE="$t"
  59    ;;
  60  esac
  61 ], [
  62  use_sysroot=no
  63  TARGET_SYSTEM_ROOT=
  64  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  65 ])
  66 AC_SUBST(use_sysroot)
  67 AC_SUBST(TARGET_SYSTEM_ROOT)
  68 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  69
  70 AC_ARG_ENABLE([got],
  71 AS_HELP_STRING([--enable-got=<type>],
  72                [GOT handling scheme (target, single, negative, multigot)]),
  73 [case "${enableval}" in
  74   target | single | negative | multigot)  got_handling=$enableval ;;
  75   *)  AC_ERROR(bad value ${enableval} for --enable-got option) ;;
  76 esac],
  77 [got_handling=target])
  78
  79 case "${got_handling}" in
  80   target)
  81     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  82               [Define to choose default GOT handling scheme]) ;;
  83   single)
  84     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  85               [Define to choose default GOT handling scheme]) ;;
  86   negative)
  87     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  88               [Define to choose default GOT handling scheme]) ;;
  89   multigot)
  90     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  91               [Define to choose default GOT handling scheme]) ;;
  92   *)  AC_ERROR(bad value ${got_handling} for --enable-got option) ;;
  93 esac
  94
  95 AM_BINUTILS_WARNINGS
  96
  97 AM_CONFIG_HEADER(config.h:config.in)
  98
  99 if test -z "$target" ; then
 100     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 101 fi
 102 if test -z "$host" ; then
 103     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 104 fi
 105
 106 # host-specific stuff:
 107
 108 AC_PROG_CC
 109 AC_GNU_SOURCE
 110 AC_PROG_INSTALL
 111
 112 AM_PROG_LIBTOOL
 113
 114 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi"
 115 ZW_GNU_GETTEXT_SISTER_DIR
 116 AM_PO_SUBDIRS
 117
 118 AC_EXEEXT
 119
 120 AC_PROG_YACC
 121 AM_PROG_LEX
 122
 123 AM_MAINTAINER_MODE
 124 AM_CONDITIONAL(GENINSRC_NEVER, false)
 125
 126 . ${srcdir}/configure.host
 127
 128 AC_SUBST(HDEFINES)
 129 AC_SUBST(HOSTING_CRT0)
 130 AC_SUBST(HOSTING_LIBS)
 131 AC_SUBST(NATIVE_LIB_DIRS)
 132
 133 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 134 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 135 AC_HEADER_DIRENT
 136
 137 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 138 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 139 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 140 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 141 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 142 if test $ld_cv_decl_getopt_unistd_h = yes; then
 143   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 144             [Is the prototype for getopt in <unistd.h> in the expected format?])
 145 fi
 146
 147 BFD_BINARY_FOPEN
 148
 149 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 150
 151 # When converting linker scripts into strings for use in emulation
 152 # files, use astring.sed if the compiler supports ANSI string
 153 # concatenation, or ostring.sed otherwise.  This is to support the
 154 # broken Microsoft MSVC compiler, which limits the length of string
 155 # constants, while still supporting pre-ANSI compilers which do not
 156 # support string concatenation.
 157 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 158 AC_CACHE_VAL(ld_cv_string_concatenation,
 159 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 160   [ld_cv_string_concatenation=yes],
 161   [ld_cv_string_concatenation=no])])
 162 AC_MSG_RESULT($ld_cv_string_concatenation)
 163 if test "$ld_cv_string_concatenation" = "yes"; then
 164   STRINGIFY=astring.sed
 165 else
 166   STRINGIFY=ostring.sed
 167 fi
 168 AC_SUBST(STRINGIFY)
 169
 170 # target-specific stuff:
 171
 172 all_targets=
 173 EMUL=
 174 all_emuls=
 175 all_emul_extras=
 176 all_libpath=
 177
 178 dnl We need to get an arbitrary number of tdir definitions into
 179 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 180 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 181 dnl file.
 182 rm -f tdirs
 183
 184 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 185 do
 186   if test "$targ_alias" = "all"; then
 187     all_targets=true
 188   else
 189     # Canonicalize the secondary target names.
 190     result=`$ac_config_sub $targ_alias 2>/dev/null`
 191     if test -n "$result"; then
 192         targ=$result
 193     else
 194         targ=$targ_alias
 195     fi
 196
 197     . ${srcdir}/configure.tgt
 198
 199     if test "$targ" = "$target"; then
 200       EMUL=$targ_emul
 201     fi
 202
 203     if test x${want64} = xfalse; then
 204       . ${srcdir}/../bfd/config.bfd
 205     fi
 206
 207     if test x${want64} = xtrue; then
 208       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 209       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 210     fi
 211
 212     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 213         case " $all_emuls " in
 214         *" e${i}.o "*) ;;
 215         *)
 216           all_emuls="$all_emuls e${i}.o"
 217           eval result=\$tdir_$i
 218           test -z "$result" && result=$targ_alias
 219           echo tdir_$i=$result >> tdirs
 220           ;;
 221         esac
 222     done
 223
 224     for i in $targ_emul $targ_extra_libpath; do
 225         case " $all_libpath " in
 226         *" ${i} "*) ;;
 227         *)
 228           if test -z "$all_libpath"; then
 229             all_libpath=${i}
 230           else
 231             all_libpath="$all_libpath ${i}"
 232           fi
 233           ;;
 234         esac
 235     done
 236
 237     for i in $targ_extra_ofiles; do
 238         case " $all_emul_extras " in
 239         *" ${i} "*) ;;
 240         *)
 241           all_emul_extras="$all_emul_extras ${i}"
 242           ;;
 243         esac
 244     done
 245   fi
 246 done
 247
 248 AC_SUBST(EMUL)
 249
 250 TDIRS=tdirs
 251 AC_SUBST_FILE(TDIRS)
 252
 253 if test x${all_targets} = xtrue; then
 254   if test x${want64} = xfalse; then
 255     AC_CHECK_SIZEOF(long)
 256     if test "x${ac_cv_sizeof_long}" = "x8"; then
 257       want64=true
 258     fi
 259   fi
 260   if test x${want64} = xtrue; then
 261     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 262   else
 263     EMULATION_OFILES='$(ALL_EMULATIONS)'
 264   fi
 265   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 266 else
 267   EMULATION_OFILES=$all_emuls
 268   EMUL_EXTRA_OFILES=$all_emul_extras
 269 fi
 270 AC_SUBST(EMULATION_OFILES)
 271 AC_SUBST(EMUL_EXTRA_OFILES)
 272 AC_SUBST(LIB_PATH)
 273
 274 EMULATION_LIBPATH=$all_libpath
 275 AC_SUBST(EMULATION_LIBPATH)
 276
 277 if test x${enable_static} = xno; then
 278   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 279 else
 280   TESTBFDLIB="../bfd/.libs/libbfd.a"
 281 fi
 282 AC_SUBST(TESTBFDLIB)
 283
 284 target_vendor=${target_vendor=$host_vendor}
 285 case "$target_vendor" in
 286   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 287   *)  EXTRA_SHLIB_EXTENSION= ;;
 288 esac
 289
 290 case "$target_os" in
 291   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 292 esac
 293
 294 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 295   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 296    [Additional extension a shared object might have.])
 297 fi
 298
 299 dnl Required by html and install-html
 300 AC_SUBST(datarootdir)
 301 AC_SUBST(docdir)
 302 AC_SUBST(htmldir)
 303
 304 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)