ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright 2012 Free Software Foundation
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 AC_INIT
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 changequote(,)dnl
  29 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  30 changequote([,])dnl
  31 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  32 AM_MAINTAINER_MODE
  33
  34 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43 AC_ARG_ENABLE(64-bit-bfd,
  44 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  45 [case "${enableval}" in
  46   yes)  want64=true  ;;
  47   no)   want64=false ;;
  48   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  49 esac],[want64=false])dnl
  50
  51 AC_ARG_WITH(sysroot,
  52 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  53 [
  54  case ${with_sysroot} in
  55  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  56  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  57  esac
  58
  59  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  60  use_sysroot=yes
  61
  62  if test "x$prefix" = xNONE; then
  63   test_prefix=/usr/local
  64  else
  65   test_prefix=$prefix
  66  fi
  67  if test "x$exec_prefix" = xNONE; then
  68   test_exec_prefix=$test_prefix
  69  else
  70   test_exec_prefix=$exec_prefix
  71  fi
  72  case ${TARGET_SYSTEM_ROOT} in
  73  "${test_prefix}"|"${test_prefix}/"*|\
  74  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  75  '${prefix}'|'${prefix}/'*|\
  76  '${exec_prefix}'|'${exec_prefix}/'*)
  77    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  78    TARGET_SYSTEM_ROOT_DEFINE="$t"
  79    ;;
  80  esac
  81 ], [
  82  use_sysroot=no
  83  TARGET_SYSTEM_ROOT=
  84  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  85 ])
  86 AC_SUBST(use_sysroot)
  87 AC_SUBST(TARGET_SYSTEM_ROOT)
  88 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  89
  90 dnl Use --enable-gold to decide if this linker should be the default.
  91 dnl "install_as_default" is set to false if gold is the default linker.
  92 dnl "installed_linker" is the installed BFD linker name.
  93 AC_ARG_ENABLE(gold,
  94 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  95 [case "${enableval}" in
  96  default)
  97    install_as_default=no
  98    installed_linker=ld.bfd
  99    ;;
 100  yes|no)
 101    install_as_default=yes
 102    installed_linker=ld.bfd
 103    ;;
 104  *)
 105    AC_MSG_ERROR([invalid --enable-gold argument])
 106    ;;
 107  esac],
 108 [install_as_default=yes
 109  installed_linker=ld.bfd])
 110 AC_SUBST(install_as_default)
 111 AC_SUBST(installed_linker)
 112
 113 AC_ARG_ENABLE([got],
 114 AS_HELP_STRING([--enable-got=<type>],
 115                [GOT handling scheme (target, single, negative, multigot)]),
 116 [case "${enableval}" in
 117   target | single | negative | multigot)  got_handling=$enableval ;;
 118   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 119 esac],
 120 [got_handling=target])
 121
 122 case "${got_handling}" in
 123   target)
 124     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 125               [Define to choose default GOT handling scheme]) ;;
 126   single)
 127     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 128               [Define to choose default GOT handling scheme]) ;;
 129   negative)
 130     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 131               [Define to choose default GOT handling scheme]) ;;
 132   multigot)
 133     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 134               [Define to choose default GOT handling scheme]) ;;
 135   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 136 esac
 137
 138 AM_BINUTILS_WARNINGS
 139
 140 AM_LC_MESSAGES
 141
 142 AC_CONFIG_HEADERS([config.h:config.in])
 143
 144 # PR 14072
 145 AH_VERBATIM([00_CONFIG_H_CHECK],
 146 [/* Check that config.h is #included before system headers
 147    (this works only for glibc, but that should be enough).  */
 148 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 149 #  error config.h must be #included before system headers
 150 #endif
 151 #define __CONFIG_H__ 1])
 152
 153 if test -z "$target" ; then
 154     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 155 fi
 156 if test -z "$host" ; then
 157     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 158 fi
 159
 160 # host-specific stuff:
 161
 162 AC_PROG_CC
 163 AC_PROG_CXX
 164 AC_GNU_SOURCE
 165 AC_USE_SYSTEM_EXTENSIONS
 166 ACX_LARGEFILE
 167 AC_PROG_INSTALL
 168
 169 LT_INIT
 170
 171 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 172 ZW_GNU_GETTEXT_SISTER_DIR
 173 AM_PO_SUBDIRS
 174
 175 AC_EXEEXT
 176
 177 AC_PROG_YACC
 178 AM_PROG_LEX
 179
 180 AM_MAINTAINER_MODE
 181 AM_CONDITIONAL(GENINSRC_NEVER, false)
 182 ACX_PROG_CMP_IGNORE_INITIAL
 183
 184 . ${srcdir}/configure.host
 185
 186 AC_SUBST(HDEFINES)
 187 AC_SUBST(HOSTING_CRT0)
 188 AC_SUBST(HOSTING_SCRT0)
 189 AC_SUBST(HOSTING_LIBS)
 190 AC_SUBST(NATIVE_LIB_DIRS)
 191
 192 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 193 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 194 ACX_HEADER_STRING
 195 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 196 AC_CHECK_FUNCS(open lseek close)
 197 AC_HEADER_DIRENT
 198
 199 # Check for dlopen support and enable plugins if possible.
 200 enable_plugins=yes
 201 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 202 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 203 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 204 # We also support plugins on Windows (MinGW).
 205 if test x$enable_plugins = xno ; then
 206   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 207 fi
 208 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 209
 210 AC_ARG_ENABLE(initfini-array,
 211         [  --enable-initfini-array      use .init_array/.fini_array sections],
 212         [], [
 213 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 214                  gcc_cv_initfini_array, [dnl
 215   if test "x${build}" = "x${target}" ; then
 216     AC_RUN_IFELSE([AC_LANG_SOURCE([
 217 static int x = -1;
 218 int main (void) { return x; }
 219 int foo (void) { x = 0; }
 220 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 221              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 222              [gcc_cv_initfini_array=no])
 223    else
 224      gcc_cv_initfini_array=no
 225    fi])
 226   enable_initfini_array=$gcc_cv_initfini_array
 227 ])
 228 AC_SUBST(enable_initfini_array)
 229 if test $enable_initfini_array = yes; then
 230   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 231     [Define .init_array/.fini_array sections are available and working.])
 232 fi
 233
 234 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 235 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 236 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 237 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 238 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 239 if test $ld_cv_decl_getopt_unistd_h = yes; then
 240   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 241             [Is the prototype for getopt in <unistd.h> in the expected format?])
 242 fi
 243
 244 BFD_BINARY_FOPEN
 245
 246 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 247
 248 # Link in zlib if we can.  This is needed only for the bootstrap tests
 249 # right now, since those tests use libbfd, which depends on zlib.
 250 AM_ZLIB
 251
 252 # When converting linker scripts into strings for use in emulation
 253 # files, use astring.sed if the compiler supports ANSI string
 254 # concatenation, or ostring.sed otherwise.  This is to support the
 255 # broken Microsoft MSVC compiler, which limits the length of string
 256 # constants, while still supporting pre-ANSI compilers which do not
 257 # support string concatenation.
 258 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 259 AC_CACHE_VAL(ld_cv_string_concatenation,
 260 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 261   ld_cv_string_concatenation=yes,
 262   ld_cv_string_concatenation=no)])
 263 AC_MSG_RESULT($ld_cv_string_concatenation)
 264 if test "$ld_cv_string_concatenation" = "yes"; then
 265   STRINGIFY=astring.sed
 266 else
 267   STRINGIFY=ostring.sed
 268 fi
 269 AC_SUBST(STRINGIFY)
 270
 271 # target-specific stuff:
 272
 273 all_targets=
 274 EMUL=
 275 all_emuls=
 276 all_emul_extras=
 277 all_libpath=
 278
 279 dnl We need to get an arbitrary number of tdir definitions into
 280 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 281 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 282 dnl file.
 283 rm -f tdirs
 284
 285 # If the host is 64-bit, then we enable 64-bit targets by default.
 286 # This is consistent with what ../bfd/configure.in does.
 287 if test x${want64} = xfalse; then
 288   AC_CHECK_SIZEOF(void *)
 289   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 290     want64=true
 291   fi
 292 fi
 293
 294 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 295 do
 296   if test "$targ_alias" = "all"; then
 297     all_targets=true
 298   else
 299     # Canonicalize the secondary target names.
 300     result=`$ac_config_sub $targ_alias 2>/dev/null`
 301     if test -n "$result"; then
 302         targ=$result
 303     else
 304         targ=$targ_alias
 305     fi
 306
 307     . ${srcdir}/configure.tgt
 308
 309     if test "$targ" = "$target"; then
 310       EMUL=$targ_emul
 311     fi
 312
 313     if test x${want64} = xfalse; then
 314       . ${srcdir}/../bfd/config.bfd
 315     fi
 316
 317     if test x${want64} = xtrue; then
 318       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 319       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 320     fi
 321
 322     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 323         case " $all_emuls " in
 324         *" e${i}.o "*) ;;
 325         *)
 326           all_emuls="$all_emuls e${i}.o"
 327           eval result=\$tdir_$i
 328           test -z "$result" && result=$targ_alias
 329           echo tdir_$i=$result >> tdirs
 330           ;;
 331         esac
 332     done
 333
 334     for i in $targ_emul $targ_extra_libpath; do
 335         case " $all_libpath " in
 336         *" ${i} "*) ;;
 337         *)
 338           if test -z "$all_libpath"; then
 339             all_libpath=${i}
 340           else
 341             all_libpath="$all_libpath ${i}"
 342           fi
 343           ;;
 344         esac
 345     done
 346
 347     for i in $targ_extra_ofiles; do
 348         case " $all_emul_extras " in
 349         *" ${i} "*) ;;
 350         *)
 351           all_emul_extras="$all_emul_extras ${i}"
 352           ;;
 353         esac
 354     done
 355   fi
 356 done
 357
 358 AC_SUBST(EMUL)
 359
 360 TDIRS=tdirs
 361 AC_SUBST_FILE(TDIRS)
 362
 363 if test x${all_targets} = xtrue; then
 364   if test x${want64} = xtrue; then
 365     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 366   else
 367     EMULATION_OFILES='$(ALL_EMULATIONS)'
 368   fi
 369   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 370 else
 371   EMULATION_OFILES=$all_emuls
 372   EMUL_EXTRA_OFILES=$all_emul_extras
 373 fi
 374 AC_SUBST(EMULATION_OFILES)
 375 AC_SUBST(EMUL_EXTRA_OFILES)
 376 AC_SUBST(LIB_PATH)
 377
 378 EMULATION_LIBPATH=$all_libpath
 379 AC_SUBST(EMULATION_LIBPATH)
 380
 381 if test x${enable_static} = xno; then
 382   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 383 else
 384   TESTBFDLIB="../bfd/.libs/libbfd.a"
 385 fi
 386 AC_SUBST(TESTBFDLIB)
 387
 388 target_vendor=${target_vendor=$host_vendor}
 389 case "$target_vendor" in
 390   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 391   *)  EXTRA_SHLIB_EXTENSION= ;;
 392 esac
 393
 394 case "$target_os" in
 395   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 396 esac
 397
 398 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 399   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 400    [Additional extension a shared object might have.])
 401 fi
 402
 403 dnl Required by html, pdf, install-pdf and install-html
 404 AC_SUBST(datarootdir)
 405 AC_SUBST(docdir)
 406 AC_SUBST(htmldir)
 407 AC_SUBST(pdfdir)
 408
 409 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 410 AC_OUTPUT