ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 AM_BINUTILS_WARNINGS
 146
 147 AM_LC_MESSAGES
 148
 149 AC_CONFIG_HEADERS([config.h:config.in])
 150
 151 # PR 14072
 152 AH_VERBATIM([00_CONFIG_H_CHECK],
 153 [/* Check that config.h is #included before system headers
 154    (this works only for glibc, but that should be enough).  */
 155 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 156 #  error config.h must be #included before system headers
 157 #endif
 158 #define __CONFIG_H__ 1])
 159
 160 if test -z "$target" ; then
 161     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 162 fi
 163 if test -z "$host" ; then
 164     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 165 fi
 166
 167 # host-specific stuff:
 168
 169 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 170 ZW_GNU_GETTEXT_SISTER_DIR
 171 AM_PO_SUBDIRS
 172
 173 AC_EXEEXT
 174
 175 AC_PROG_YACC
 176 AM_PROG_LEX
 177
 178 AM_MAINTAINER_MODE
 179 AM_CONDITIONAL(GENINSRC_NEVER, false)
 180 ACX_PROG_CMP_IGNORE_INITIAL
 181
 182 . ${srcdir}/configure.host
 183
 184 AC_SUBST(HDEFINES)
 185 AC_SUBST(HOSTING_CRT0)
 186 AC_SUBST(HOSTING_SCRT0)
 187 AC_SUBST(HOSTING_LIBS)
 188 AC_SUBST(HOSTING_SLIBS)
 189 AC_SUBST(NATIVE_LIB_DIRS)
 190
 191 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 192 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 193 ACX_HEADER_STRING
 194 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 195 AC_CHECK_FUNCS(open lseek close)
 196 AC_HEADER_DIRENT
 197
 198 dnl AC_CHECK_HEADERS(sys/mman.h)
 199 AC_FUNC_MMAP
 200
 201 AC_SEARCH_LIBS([dlopen], [dl])
 202 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 203
 204 AC_ARG_ENABLE(initfini-array,
 205         [  --enable-initfini-array      use .init_array/.fini_array sections],
 206         [], [
 207 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 208                  gcc_cv_initfini_array, [dnl
 209   if test "x${build}" = "x${target}" ; then
 210     AC_RUN_IFELSE([AC_LANG_SOURCE([
 211 static int x = -1;
 212 int main (void) { return x; }
 213 int foo (void) { x = 0; }
 214 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 215              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 216              [gcc_cv_initfini_array=no])
 217    else
 218      gcc_cv_initfini_array=no
 219    fi])
 220   enable_initfini_array=$gcc_cv_initfini_array
 221 ])
 222 AC_SUBST(enable_initfini_array)
 223 if test $enable_initfini_array = yes; then
 224   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 225     [Define .init_array/.fini_array sections are available and working.])
 226 fi
 227
 228 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 229 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 230 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 231 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 232 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 233 if test $ld_cv_decl_getopt_unistd_h = yes; then
 234   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 235             [Is the prototype for getopt in <unistd.h> in the expected format?])
 236 fi
 237
 238 BFD_BINARY_FOPEN
 239
 240 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 241
 242 # Link in zlib if we can.  This is needed only for the bootstrap tests
 243 # right now, since those tests use libbfd, which depends on zlib.
 244 AM_ZLIB
 245
 246 # When converting linker scripts into strings for use in emulation
 247 # files, use astring.sed if the compiler supports ANSI string
 248 # concatenation, or ostring.sed otherwise.  This is to support the
 249 # broken Microsoft MSVC compiler, which limits the length of string
 250 # constants, while still supporting pre-ANSI compilers which do not
 251 # support string concatenation.
 252 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 253 AC_CACHE_VAL(ld_cv_string_concatenation,
 254 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 255   ld_cv_string_concatenation=yes,
 256   ld_cv_string_concatenation=no)])
 257 AC_MSG_RESULT($ld_cv_string_concatenation)
 258 if test "$ld_cv_string_concatenation" = "yes"; then
 259   STRINGIFY=astring.sed
 260 else
 261   STRINGIFY=ostring.sed
 262 fi
 263 AC_SUBST(STRINGIFY)
 264
 265 # target-specific stuff:
 266
 267 all_targets=
 268 EMUL=
 269 all_emuls=
 270 all_emul_extras=
 271 all_libpath=
 272
 273 dnl We need to get an arbitrary number of tdir definitions into
 274 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 275 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 276 dnl file.
 277 rm -f tdirs
 278
 279 # If the host is 64-bit, then we enable 64-bit targets by default.
 280 # This is consistent with what ../bfd/configure.ac does.
 281 if test x${want64} = xfalse; then
 282   AC_CHECK_SIZEOF(void *)
 283   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 284     want64=true
 285   fi
 286 fi
 287
 288 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 289 do
 290   if test "$targ_alias" = "all"; then
 291     all_targets=true
 292   else
 293     # Canonicalize the secondary target names.
 294     result=`$ac_config_sub $targ_alias 2>/dev/null`
 295     if test -n "$result"; then
 296         targ=$result
 297     else
 298         targ=$targ_alias
 299     fi
 300
 301     . ${srcdir}/configure.tgt
 302
 303     if test "$targ" = "$target"; then
 304       EMUL=$targ_emul
 305     fi
 306
 307     if test x${want64} = xfalse; then
 308       . ${srcdir}/../bfd/config.bfd
 309     fi
 310
 311     if test x${want64} = xtrue; then
 312       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 313       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 314     fi
 315
 316     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 317         case " $all_emuls " in
 318         *" e${i}.o "*) ;;
 319         *)
 320           all_emuls="$all_emuls e${i}.o"
 321           eval result=\$tdir_$i
 322           test -z "$result" && result=$targ_alias
 323           echo tdir_$i=$result >> tdirs
 324           ;;
 325         esac
 326     done
 327
 328     for i in $targ_emul $targ_extra_libpath; do
 329         case " $all_libpath " in
 330         *" ${i} "*) ;;
 331         *)
 332           if test -z "$all_libpath"; then
 333             all_libpath=${i}
 334           else
 335             all_libpath="$all_libpath ${i}"
 336           fi
 337           ;;
 338         esac
 339     done
 340
 341     for i in $targ_extra_ofiles; do
 342         case " $all_emul_extras " in
 343         *" ${i} "*) ;;
 344         *)
 345           all_emul_extras="$all_emul_extras ${i}"
 346           ;;
 347         esac
 348     done
 349
 350   fi
 351 done
 352
 353 AC_SUBST(EMUL)
 354
 355 TDIRS=tdirs
 356 AC_SUBST_FILE(TDIRS)
 357
 358 if test x${all_targets} = xtrue; then
 359   if test x${want64} = xtrue; then
 360     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 361     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 362   else
 363     EMULATION_OFILES='$(ALL_EMULATIONS)'
 364     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 365   fi
 366 else
 367   EMULATION_OFILES=$all_emuls
 368   EMUL_EXTRA_OFILES=$all_emul_extras
 369 fi
 370 AC_SUBST(EMULATION_OFILES)
 371 AC_SUBST(EMUL_EXTRA_OFILES)
 372 AC_SUBST(LIB_PATH)
 373
 374 EMULATION_LIBPATH=$all_libpath
 375 AC_SUBST(EMULATION_LIBPATH)
 376
 377 if test x${enable_static} = xno; then
 378   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 379 else
 380   TESTBFDLIB="../bfd/.libs/libbfd.a"
 381 fi
 382 AC_SUBST(TESTBFDLIB)
 383
 384 target_vendor=${target_vendor=$host_vendor}
 385 case "$target_vendor" in
 386   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 387   *)  EXTRA_SHLIB_EXTENSION= ;;
 388 esac
 389
 390 case "$target_os" in
 391   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 392 esac
 393
 394 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 395   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 396    [Additional extension a shared object might have.])
 397 fi
 398
 399 dnl Required by html, pdf, install-pdf and install-html
 400 AC_SUBST(datarootdir)
 401 AC_SUBST(docdir)
 402 AC_SUBST(htmldir)
 403 AC_SUBST(pdfdir)
 404
 405 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 406 AC_OUTPUT