ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 AM_BINUTILS_WARNINGS
 146
 147 AM_LC_MESSAGES
 148
 149 AC_CONFIG_HEADERS([config.h:config.in])
 150
 151 # PR 14072
 152 AH_VERBATIM([00_CONFIG_H_CHECK],
 153 [/* Check that config.h is #included before system headers
 154    (this works only for glibc, but that should be enough).  */
 155 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 156 #  error config.h must be #included before system headers
 157 #endif
 158 #define __CONFIG_H__ 1])
 159
 160 if test -z "$target" ; then
 161     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 162 fi
 163 if test -z "$host" ; then
 164     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 165 fi
 166
 167 # host-specific stuff:
 168
 169 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 170 ZW_GNU_GETTEXT_SISTER_DIR
 171 AM_PO_SUBDIRS
 172
 173 AC_EXEEXT
 174
 175 AC_PROG_YACC
 176 AM_PROG_LEX
 177
 178 AM_MAINTAINER_MODE
 179 AM_CONDITIONAL(GENINSRC_NEVER, false)
 180 ACX_PROG_CMP_IGNORE_INITIAL
 181
 182 . ${srcdir}/configure.host
 183
 184 AC_SUBST(HDEFINES)
 185 AC_SUBST(HOSTING_CRT0)
 186 AC_SUBST(HOSTING_SCRT0)
 187 AC_SUBST(HOSTING_LIBS)
 188 AC_SUBST(HOSTING_SLIBS)
 189 AC_SUBST(NATIVE_LIB_DIRS)
 190
 191 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 192 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 193 ACX_HEADER_STRING
 194 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 195 AC_CHECK_FUNCS(open lseek close)
 196 AC_HEADER_DIRENT
 197
 198 AC_SEARCH_LIBS([dlopen], [dl])
 199 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 200
 201 AC_ARG_ENABLE(initfini-array,
 202         [  --enable-initfini-array      use .init_array/.fini_array sections],
 203         [], [
 204 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 205                  gcc_cv_initfini_array, [dnl
 206   if test "x${build}" = "x${target}" ; then
 207     AC_RUN_IFELSE([AC_LANG_SOURCE([
 208 static int x = -1;
 209 int main (void) { return x; }
 210 int foo (void) { x = 0; }
 211 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 212              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 213              [gcc_cv_initfini_array=no])
 214    else
 215      gcc_cv_initfini_array=no
 216    fi])
 217   enable_initfini_array=$gcc_cv_initfini_array
 218 ])
 219 AC_SUBST(enable_initfini_array)
 220 if test $enable_initfini_array = yes; then
 221   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 222     [Define .init_array/.fini_array sections are available and working.])
 223 fi
 224
 225 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 226 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 227 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 228 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 229 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 230 if test $ld_cv_decl_getopt_unistd_h = yes; then
 231   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 232             [Is the prototype for getopt in <unistd.h> in the expected format?])
 233 fi
 234
 235 BFD_BINARY_FOPEN
 236
 237 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 238
 239 # Link in zlib if we can.  This is needed only for the bootstrap tests
 240 # right now, since those tests use libbfd, which depends on zlib.
 241 AM_ZLIB
 242
 243 # When converting linker scripts into strings for use in emulation
 244 # files, use astring.sed if the compiler supports ANSI string
 245 # concatenation, or ostring.sed otherwise.  This is to support the
 246 # broken Microsoft MSVC compiler, which limits the length of string
 247 # constants, while still supporting pre-ANSI compilers which do not
 248 # support string concatenation.
 249 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 250 AC_CACHE_VAL(ld_cv_string_concatenation,
 251 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 252   ld_cv_string_concatenation=yes,
 253   ld_cv_string_concatenation=no)])
 254 AC_MSG_RESULT($ld_cv_string_concatenation)
 255 if test "$ld_cv_string_concatenation" = "yes"; then
 256   STRINGIFY=astring.sed
 257 else
 258   STRINGIFY=ostring.sed
 259 fi
 260 AC_SUBST(STRINGIFY)
 261
 262 # target-specific stuff:
 263
 264 all_targets=
 265 EMUL=
 266 all_emuls=
 267 all_emul_extras=
 268 all_libpath=
 269
 270 dnl We need to get an arbitrary number of tdir definitions into
 271 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 272 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 273 dnl file.
 274 rm -f tdirs
 275
 276 # If the host is 64-bit, then we enable 64-bit targets by default.
 277 # This is consistent with what ../bfd/configure.ac does.
 278 if test x${want64} = xfalse; then
 279   AC_CHECK_SIZEOF(void *)
 280   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 281     want64=true
 282   fi
 283 fi
 284
 285 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 286 do
 287   if test "$targ_alias" = "all"; then
 288     all_targets=true
 289   else
 290     # Canonicalize the secondary target names.
 291     result=`$ac_config_sub $targ_alias 2>/dev/null`
 292     if test -n "$result"; then
 293         targ=$result
 294     else
 295         targ=$targ_alias
 296     fi
 297
 298     . ${srcdir}/configure.tgt
 299
 300     if test "$targ" = "$target"; then
 301       EMUL=$targ_emul
 302     fi
 303
 304     if test x${want64} = xfalse; then
 305       . ${srcdir}/../bfd/config.bfd
 306     fi
 307
 308     if test x${want64} = xtrue; then
 309       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 310       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 311     fi
 312
 313     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 314         case " $all_emuls " in
 315         *" e${i}.o "*) ;;
 316         *)
 317           all_emuls="$all_emuls e${i}.o"
 318           eval result=\$tdir_$i
 319           test -z "$result" && result=$targ_alias
 320           echo tdir_$i=$result >> tdirs
 321           ;;
 322         esac
 323     done
 324
 325     for i in $targ_emul $targ_extra_libpath; do
 326         case " $all_libpath " in
 327         *" ${i} "*) ;;
 328         *)
 329           if test -z "$all_libpath"; then
 330             all_libpath=${i}
 331           else
 332             all_libpath="$all_libpath ${i}"
 333           fi
 334           ;;
 335         esac
 336     done
 337
 338     for i in $targ_extra_ofiles; do
 339         case " $all_emul_extras " in
 340         *" ${i} "*) ;;
 341         *)
 342           all_emul_extras="$all_emul_extras ${i}"
 343           ;;
 344         esac
 345     done
 346
 347   fi
 348 done
 349
 350 AC_SUBST(EMUL)
 351
 352 TDIRS=tdirs
 353 AC_SUBST_FILE(TDIRS)
 354
 355 if test x${all_targets} = xtrue; then
 356   if test x${want64} = xtrue; then
 357     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 358     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 359   else
 360     EMULATION_OFILES='$(ALL_EMULATIONS)'
 361     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 362   fi
 363 else
 364   EMULATION_OFILES=$all_emuls
 365   EMUL_EXTRA_OFILES=$all_emul_extras
 366 fi
 367 AC_SUBST(EMULATION_OFILES)
 368 AC_SUBST(EMUL_EXTRA_OFILES)
 369 AC_SUBST(LIB_PATH)
 370
 371 EMULATION_LIBPATH=$all_libpath
 372 AC_SUBST(EMULATION_LIBPATH)
 373
 374 if test x${enable_static} = xno; then
 375   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 376 else
 377   TESTBFDLIB="../bfd/.libs/libbfd.a"
 378 fi
 379 AC_SUBST(TESTBFDLIB)
 380
 381 target_vendor=${target_vendor=$host_vendor}
 382 case "$target_vendor" in
 383   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 384   *)  EXTRA_SHLIB_EXTENSION= ;;
 385 esac
 386
 387 case "$target_os" in
 388   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 389 esac
 390
 391 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 392   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 393    [Additional extension a shared object might have.])
 394 fi
 395
 396 dnl Required by html, pdf, install-pdf and install-html
 397 AC_SUBST(datarootdir)
 398 AC_SUBST(docdir)
 399 AC_SUBST(htmldir)
 400 AC_SUBST(pdfdir)
 401
 402 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 403 AC_OUTPUT