init-tools.cmd

   1 @if not defined _echo @echo off
   2 setlocal
   3
   4 set INIT_TOOLS_LOG=%~dp0init-tools.log
   5 if [%PACKAGES_DIR%]==[] set PACKAGES_DIR=%~dp0packages\
   6 if [%TOOLRUNTIME_DIR%]==[] set TOOLRUNTIME_DIR=%~dp0Tools
   7 set DOTNET_PATH=%TOOLRUNTIME_DIR%\dotnetcli\
   8 if [%DOTNET_CMD%]==[] set DOTNET_CMD=%DOTNET_PATH%dotnet.exe
   9 if [%BUILDTOOLS_SOURCE%]==[] set BUILDTOOLS_SOURCE=https://dotnet.myget.org/F/dotnet-buildtools/api/v3/index.json
  10 set /P BUILDTOOLS_VERSION=< "%~dp0BuildToolsVersion.txt"
  11 set BUILD_TOOLS_PATH=%PACKAGES_DIR%Microsoft.DotNet.BuildTools\%BUILDTOOLS_VERSION%\lib\
  12 set INIT_TOOLS_RESTORE_PROJECT=%~dp0init-tools.msbuild
  13 set BUILD_TOOLS_SEMAPHORE_DIR=%TOOLRUNTIME_DIR%\%BUILDTOOLS_VERSION%
  14 set BUILD_TOOLS_SEMAPHORE=%BUILD_TOOLS_SEMAPHORE_DIR%\init-tools.completed
  15
  16 :: if force option is specified then clean the tool runtime and build tools package directory to force it to get recreated
  17 if [%1]==[force] (
  18   if exist "%TOOLRUNTIME_DIR%" rmdir /S /Q "%TOOLRUNTIME_DIR%"
  19   if exist "%PACKAGES_DIR%Microsoft.DotNet.BuildTools" rmdir /S /Q "%PACKAGES_DIR%Microsoft.DotNet.BuildTools"
  20 )
  21
  22 :: If semaphore exists do nothing
  23 if exist "%BUILD_TOOLS_SEMAPHORE%" (
  24   echo Tools are already initialized.
  25   goto :EOF
  26 )
  27
  28 if exist "%TOOLRUNTIME_DIR%" rmdir /S /Q "%TOOLRUNTIME_DIR%"
  29
  30 :: Download Nuget.exe
  31 if NOT exist "%PACKAGES_DIR%NuGet.exe" (
  32   if NOT exist "%PACKAGES_DIR%" mkdir "%PACKAGES_DIR%"
  33   powershell -NoProfile -ExecutionPolicy unrestricted -Command "(New-Object Net.WebClient).DownloadFile('https://www.nuget.org/nuget.exe', '%PACKAGES_DIR%NuGet.exe')
  34 )
  35
  36 echo Running %0 > "%INIT_TOOLS_LOG%"
  37
  38 set /p DOTNET_VERSION=< "%~dp0DotnetCLIVersion.txt"
  39 if exist "%DOTNET_CMD%" goto :afterdotnetrestore
  40
  41 echo Installing dotnet cli...
  42 if NOT exist "%DOTNET_PATH%" mkdir "%DOTNET_PATH%"
  43 set DOTNET_ZIP_NAME=dotnet-dev-win-x64.%DOTNET_VERSION%.zip
  44 set DOTNET_REMOTE_PATH=https://dotnetcli.blob.core.windows.net/dotnet/Sdk/%DOTNET_VERSION%/%DOTNET_ZIP_NAME%
  45 set DOTNET_LOCAL_PATH=%DOTNET_PATH%%DOTNET_ZIP_NAME%
  46 echo Installing '%DOTNET_REMOTE_PATH%' to '%DOTNET_LOCAL_PATH%' >> "%INIT_TOOLS_LOG%"
  47 powershell -NoProfile -ExecutionPolicy unrestricted -Command "$retryCount = 0; $success = $false; do { try { (New-Object Net.WebClient).DownloadFile('%DOTNET_REMOTE_PATH%', '%DOTNET_LOCAL_PATH%'); $success = $true; } catch { if ($retryCount -ge 6) { throw; } else { $retryCount++; Start-Sleep -Seconds (5 * $retryCount); } } } while ($success -eq $false); Add-Type -Assembly 'System.IO.Compression.FileSystem' -ErrorVariable AddTypeErrors; if ($AddTypeErrors.Count -eq 0) { [System.IO.Compression.ZipFile]::ExtractToDirectory('%DOTNET_LOCAL_PATH%', '%DOTNET_PATH%') } else { (New-Object -com shell.application).namespace('%DOTNET_PATH%').CopyHere((new-object -com shell.application).namespace('%DOTNET_LOCAL_PATH%').Items(),16) }" >> "%INIT_TOOLS_LOG%"
  48 if NOT exist "%DOTNET_LOCAL_PATH%" (
  49   echo ERROR: Could not install dotnet cli correctly. 1>&2
  50   goto :error
  51 )
  52
  53 :afterdotnetrestore
  54
  55 if exist "%BUILD_TOOLS_PATH%" goto :afterbuildtoolsrestore
  56 echo Restoring BuildTools version %BUILDTOOLS_VERSION%...
  57 echo Running: "%DOTNET_CMD%" restore "%INIT_TOOLS_RESTORE_PROJECT%" --no-cache --packages %PACKAGES_DIR% --source "%BUILDTOOLS_SOURCE%" /p:BuildToolsPackageVersion=%BUILDTOOLS_VERSION% >> "%INIT_TOOLS_LOG%"
  58 call "%DOTNET_CMD%" restore "%INIT_TOOLS_RESTORE_PROJECT%" --no-cache --packages %PACKAGES_DIR% --source "%BUILDTOOLS_SOURCE%" /p:BuildToolsPackageVersion=%BUILDTOOLS_VERSION% >> "%INIT_TOOLS_LOG%"
  59 if NOT exist "%BUILD_TOOLS_PATH%init-tools.cmd" (
  60   echo ERROR: Could not restore build tools correctly. 1>&2
  61   goto :error
  62 )
  63
  64 :afterbuildtoolsrestore
  65
  66 echo Initializing BuildTools...
  67 echo Running: "%BUILD_TOOLS_PATH%init-tools.cmd" "%~dp0" "%DOTNET_CMD%" "%TOOLRUNTIME_DIR%" >> "%INIT_TOOLS_LOG%"
  68 call "%BUILD_TOOLS_PATH%init-tools.cmd" "%~dp0" "%DOTNET_CMD%" "%TOOLRUNTIME_DIR%" >> "%INIT_TOOLS_LOG%"
  69 set INIT_TOOLS_ERRORLEVEL=%ERRORLEVEL%
  70 if not [%INIT_TOOLS_ERRORLEVEL%]==[0] (
  71   echo ERROR: An error occured when trying to initialize the tools. 1>&2
  72   goto :error
  73 )
  74
  75 :: Create semaphore file
  76 echo Done initializing tools.
  77 if NOT exist "%BUILD_TOOLS_SEMAPHORE_DIR%" (
  78         mkdir "%BUILD_TOOLS_SEMAPHORE_DIR%"
  79 )
  80 echo Init-Tools.cmd completed for BuildTools Version: %BUILDTOOLS_VERSION% > "%BUILD_TOOLS_SEMAPHORE%"
  81 exit /b 0
  82
  83 :error
  84 echo Please check the detailed log that follows. 1>&2
  85 type "%INIT_TOOLS_LOG%" 1>&2
  86 exit /b 1