init-tools.cmd

   1 @if not defined _echo @echo off
   2 setlocal
   3
   4 set INIT_TOOLS_LOG=%~dp0init-tools.log
   5 if [%PACKAGES_DIR%]==[] set PACKAGES_DIR=%~dp0packages\
   6 if [%TOOLRUNTIME_DIR%]==[] set TOOLRUNTIME_DIR=%~dp0Tools
   7 set DOTNET_PATH=%TOOLRUNTIME_DIR%\dotnetcli\
   8 if [%DOTNET_CMD%]==[] set DOTNET_CMD=%DOTNET_PATH%dotnet.exe
   9 if [%BUILDTOOLS_SOURCE%]==[] set BUILDTOOLS_SOURCE=https://dotnet.myget.org/F/dotnet-buildtools/api/v3/index.json
  10 set /P BUILDTOOLS_VERSION=< "%~dp0BuildToolsVersion.txt"
  11 set BUILD_TOOLS_PATH=%PACKAGES_DIR%Microsoft.DotNet.BuildTools\%BUILDTOOLS_VERSION%\lib\
  12 set INIT_TOOLS_RESTORE_PROJECT=%~dp0init-tools.msbuild
  13 set BUILD_TOOLS_SEMAPHORE_DIR=%TOOLRUNTIME_DIR%\%BUILDTOOLS_VERSION%
  14 set BUILD_TOOLS_SEMAPHORE=%BUILD_TOOLS_SEMAPHORE_DIR%\init-tools.completed
  15
  16 :: if force option is specified then clean the tool runtime and build tools package directory to force it to get recreated
  17 if [%1]==[force] (
  18   if exist "%TOOLRUNTIME_DIR%" rmdir /S /Q "%TOOLRUNTIME_DIR%"
  19   if exist "%PACKAGES_DIR%Microsoft.DotNet.BuildTools" rmdir /S /Q "%PACKAGES_DIR%Microsoft.DotNet.BuildTools"
  20 )
  21
  22 :: If semaphore exists do nothing
  23 if exist "%BUILD_TOOLS_SEMAPHORE%" (
  24   echo Tools are already initialized.
  25   goto :EOF
  26 )
  27
  28 if exist "%TOOLRUNTIME_DIR%" rmdir /S /Q "%TOOLRUNTIME_DIR%"
  29
  30 if exist "%DotNetBuildToolsDir%" (
  31   echo Using tools from '%DotNetBuildToolsDir%'.
  32   mklink /j "%TOOLRUNTIME_DIR%" "%DotNetBuildToolsDir%"
  33
  34   if not exist "%DOTNET_CMD%" (
  35     echo ERROR: Ensure that '%DotNetBuildToolsDir%' contains the .NET Core SDK at '%DOTNET_PATH%'
  36     exit /b 1
  37   )
  38
  39   echo Done initializing tools.
  40   if NOT exist "%BUILD_TOOLS_SEMAPHORE_DIR%" mkdir "%BUILD_TOOLS_SEMAPHORE_DIR%"
  41   echo Using tools from '%DotNetBuildToolsDir%'. > "%BUILD_TOOLS_SEMAPHORE%"
  42   exit /b 0
  43 )
  44
  45 echo Running %0 > "%INIT_TOOLS_LOG%"
  46
  47 set /p DOTNET_VERSION=< "%~dp0DotnetCLIVersion.txt"
  48 if exist "%DOTNET_CMD%" goto :afterdotnetrestore
  49
  50 echo Installing dotnet cli...
  51 if NOT exist "%DOTNET_PATH%" mkdir "%DOTNET_PATH%"
  52 set DOTNET_ZIP_NAME=dotnet-sdk-%DOTNET_VERSION%-win-x64.zip
  53 set DOTNET_REMOTE_PATH=https://dotnetcli.azureedge.net/dotnet/Sdk/%DOTNET_VERSION%/%DOTNET_ZIP_NAME%
  54 set DOTNET_LOCAL_PATH=%DOTNET_PATH%%DOTNET_ZIP_NAME%
  55 echo Installing '%DOTNET_REMOTE_PATH%' to '%DOTNET_LOCAL_PATH%' >> "%INIT_TOOLS_LOG%"
  56 powershell -NoProfile -ExecutionPolicy unrestricted -Command "$retryCount = 0; $success = $false; $proxyCredentialsRequired = $false; do { try { $wc = New-Object Net.WebClient; if ($proxyCredentialsRequired) { [Net.WebRequest]::DefaultWebProxy.Credentials = [Net.CredentialCache]::DefaultNetworkCredentials; } $wc.DownloadFile('%DOTNET_REMOTE_PATH%', '%DOTNET_LOCAL_PATH%'); $success = $true; } catch { if ($retryCount -ge 6) { throw; } else { $we = $_.Exception.InnerException -as [Net.WebException]; $proxyCredentialsRequired = ($we -ne $null -and ([Net.HttpWebResponse]$we.Response).StatusCode -eq [Net.HttpStatusCode]::ProxyAuthenticationRequired); Start-Sleep -Seconds (5 * $retryCount); $retryCount++; } } } while ($success -eq $false); Add-Type -Assembly 'System.IO.Compression.FileSystem' -ErrorVariable AddTypeErrors; if ($AddTypeErrors.Count -eq 0) { [System.IO.Compression.ZipFile]::ExtractToDirectory('%DOTNET_LOCAL_PATH%', '%DOTNET_PATH%') } else { (New-Object -com shell.application).namespace('%DOTNET_PATH%').CopyHere((new-object -com shell.application).namespace('%DOTNET_LOCAL_PATH%').Items(),16) }" >> "%INIT_TOOLS_LOG%"
  57 if NOT exist "%DOTNET_LOCAL_PATH%" (
  58   echo ERROR: Could not install dotnet cli correctly. 1>&2
  59   goto :error
  60 )
  61
  62 :afterdotnetrestore
  63
  64 if exist "%BUILD_TOOLS_PATH%" goto :afterbuildtoolsrestore
  65 echo Restoring BuildTools version %BUILDTOOLS_VERSION%...
  66 echo Running: "%DOTNET_CMD%" restore "%INIT_TOOLS_RESTORE_PROJECT%" --no-cache --packages %PACKAGES_DIR% --source "%BUILDTOOLS_SOURCE%" /p:BuildToolsPackageVersion=%BUILDTOOLS_VERSION% /p:ToolsDir=%TOOLRUNTIME_DIR% >> "%INIT_TOOLS_LOG%"
  67 call "%DOTNET_CMD%" restore "%INIT_TOOLS_RESTORE_PROJECT%" --no-cache --packages %PACKAGES_DIR% --source "%BUILDTOOLS_SOURCE%" /p:BuildToolsPackageVersion=%BUILDTOOLS_VERSION% /p:ToolsDir=%TOOLRUNTIME_DIR% >> "%INIT_TOOLS_LOG%"
  68 if NOT exist "%BUILD_TOOLS_PATH%init-tools.cmd" (
  69   echo ERROR: Could not restore build tools correctly. 1>&2
  70   goto :error
  71 )
  72
  73 :afterbuildtoolsrestore
  74
  75 :: Ask init-tools to also restore ILAsm
  76 set /p ILASMCOMPILER_VERSION=< "%~dp0ILAsmVersion.txt"
  77
  78 echo Initializing BuildTools...
  79 echo Running: "%BUILD_TOOLS_PATH%init-tools.cmd" "%~dp0" "%DOTNET_CMD%" "%TOOLRUNTIME_DIR%" >> "%INIT_TOOLS_LOG%"
  80 call "%BUILD_TOOLS_PATH%init-tools.cmd" "%~dp0" "%DOTNET_CMD%" "%TOOLRUNTIME_DIR%" >> "%INIT_TOOLS_LOG%"
  81 set INIT_TOOLS_ERRORLEVEL=%ERRORLEVEL%
  82 if not [%INIT_TOOLS_ERRORLEVEL%]==[0] (
  83   echo ERROR: An error occured when trying to initialize the tools. 1>&2
  84   goto :error
  85 )
  86
  87 :: Create semaphore file
  88 echo Done initializing tools.
  89 if NOT exist "%BUILD_TOOLS_SEMAPHORE_DIR%" mkdir "%BUILD_TOOLS_SEMAPHORE_DIR%"
  90 echo Init-Tools.cmd completed for BuildTools Version: %BUILDTOOLS_VERSION% > "%BUILD_TOOLS_SEMAPHORE%"
  91 exit /b 0
  92
  93 :error
  94 echo Please check the detailed log that follows. 1>&2
  95 type "%INIT_TOOLS_LOG%" 1>&2
  96 exit /b 1