infra/cmake/packages/FlatBuffersConfig.cmake

   1 function(_FlatBuffers_import)
   2   find_package(Flatbuffers QUIET)
   3   set(FlatBuffers_FOUND ${Flatbuffers_FOUND} PARENT_SCOPE)
   4 endfunction(_FlatBuffers_import)
   5
   6 function(_FlatBuffers_build)
   7   if(NOT BUILD_FLATBUFFERS)
   8     message(STATUS "FlatBuffersConfig skip: BUILD_FLATBUFFERS OFF")
   9     return()
  10   endif(NOT BUILD_FLATBUFFERS)
  11
  12   nnas_find_package(FlatBuffersSource EXACT 1.10 QUIET)
  13
  14   if(NOT FlatBuffersSource_FOUND)
  15     # Source is not available
  16     message(STATUS "FlatBuffersConfig skip: FlatBuffersSource not found")
  17     return()
  18   endif(NOT FlatBuffersSource_FOUND)
  19
  20   set(ADDITIONAL_CXX_FLAGS "")
  21   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 8.0)
  22     set(ADDITIONAL_CXX_FLAGS "-Wno-error=class-memaccess")
  23   endif()
  24
  25   nnas_include(ExternalBuildTools)
  26   ExternalBuild_CMake(CMAKE_DIR   ${FlatBuffersSource_DIR}
  27                       BUILD_DIR   ${CMAKE_BINARY_DIR}/externals/FLATBUFFERS-1.10/build
  28                       INSTALL_DIR ${EXT_OVERLAY_DIR}/FLATBUFFERS-1.10
  29                       BUILD_FLAGS ${ADDITIONAL_CXX_FLAGS}
  30                       IDENTIFIER  "1.10-fix4"
  31                       EXTRA_OPTS "-DFLATBUFFERS_BUILD_TESTS:BOOL=OFF -DPOSITION_INDEPENDENT_CODE:BOOL=ON"
  32                       PKG_NAME    "FLATBUFFERS-1.10")
  33
  34 endfunction(_FlatBuffers_build)
  35
  36 _FlatBuffers_build()
  37 _FlatBuffers_import()
  38
  39 if(FlatBuffers_FOUND)
  40   if(NOT TARGET flatbuffers-1.10)
  41     add_library(flatbuffers-1.10 INTERFACE)
  42     target_link_libraries(flatbuffers-1.10 INTERFACE flatbuffers::flatbuffers)
  43     message(STATUS "Found FlatBuffers-1.10: TRUE")
  44   endif(NOT TARGET flatbuffers-1.10)
  45
  46   function(FlatBuffers_Generate PREFIX OUTPUT_DIR SCHEMA_DIR)
  47     get_filename_component(abs_output_dir ${OUTPUT_DIR} ABSOLUTE)
  48     get_filename_component(abs_schema_dir ${SCHEMA_DIR} ABSOLUTE)
  49
  50     foreach(schema ${ARGN})
  51       get_filename_component(schema_fn "${schema}" NAME)
  52       get_filename_component(dir "${schema}" DIRECTORY)
  53
  54       get_filename_component(schema_fn_we "${schema_fn}" NAME_WE)
  55
  56       list(APPEND SCHEMA_FILES "${abs_schema_dir}/${schema}")
  57       list(APPEND OUTPUT_FILES "${abs_output_dir}/${schema_fn_we}_generated.h")
  58     endforeach()
  59
  60     add_custom_command(OUTPUT ${OUTPUT_FILES}
  61                        COMMAND ${CMAKE_COMMAND} -E make_directory "${abs_output_dir}"
  62                        COMMAND "$<TARGET_FILE:flatbuffers::flatc>" -c --no-includes
  63                        --no-union-value-namespacing
  64                        --gen-object-api -o "${abs_output_dir}"
  65                        ${SCHEMA_FILES}
  66                        DEPENDS flatbuffers::flatc)
  67
  68     set(${PREFIX}_SOURCES ${OUTPUT_FILES} PARENT_SCOPE)
  69     set(${PREFIX}_INCLUDE_DIRS ${abs_output_dir} PARENT_SCOPE)
  70   endfunction(FlatBuffers_Generate)
  71
  72   function(FlatBuffers_Target TGT)
  73     set(oneValueArgs OUTPUT_DIR SCHEMA_DIR INCLUDE_DIR)
  74     set(multiValueArgs SCHEMA_FILES)
  75     cmake_parse_arguments(ARG "" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
  76
  77     # Use OUTPUT_DIR as INCLUDE_DIR if INCLUDE_DIR is not specified
  78     if(NOT ARG_INCLUDE_DIR)
  79       set(ARG_INCLUDE_DIR ${ARG_OUTPUT_DIR})
  80     endif(NOT ARG_INCLUDE_DIR)
  81
  82     get_filename_component(abs_output_dir ${ARG_OUTPUT_DIR} ABSOLUTE)
  83     get_filename_component(abs_include_dir ${ARG_INCLUDE_DIR} ABSOLUTE)
  84     get_filename_component(abs_schema_dir ${ARG_SCHEMA_DIR} ABSOLUTE)
  85
  86     # Let's reset list variables before using them
  87     # NOTE THIS DOES NOT AFFECT parent scope
  88     unset(SCHEMA_FILES)
  89     unset(OUTPUT_FILES)
  90
  91     foreach(schema ${ARG_SCHEMA_FILES})
  92       get_filename_component(schema_fn "${schema}" NAME)
  93       get_filename_component(dir "${schema}" DIRECTORY)
  94
  95       get_filename_component(schema_fn_we "${schema_fn}" NAME_WE)
  96
  97       list(APPEND SCHEMA_FILES "${abs_schema_dir}/${schema}")
  98       list(APPEND OUTPUT_FILES "${abs_output_dir}/${schema_fn_we}_generated.h")
  99     endforeach()
 100
 101     # Generate headers
 102     add_custom_command(OUTPUT ${OUTPUT_FILES}
 103                        COMMAND ${CMAKE_COMMAND} -E make_directory "${abs_output_dir}"
 104                        COMMAND "$<TARGET_FILE:flatbuffers::flatc>" -c --no-includes
 105                                --no-union-value-namespacing
 106                                --gen-object-api -o "${abs_output_dir}"
 107                                ${SCHEMA_FILES}
 108                        DEPENDS ${SCHEMA_FILES}
 109                        COMMENT "Generate '${TGT}' headers")
 110
 111     # NOTE This header-only library is deliberately declared as STATIC library
 112     #      to avoid possible scope issues related with generated files
 113     add_library(${TGT} STATIC ${OUTPUT_FILES})
 114     set_target_properties(${TGT} PROPERTIES LINKER_LANGUAGE CXX)
 115     target_include_directories(${TGT} PUBLIC "${ARG_INCLUDE_DIR}")
 116     target_link_libraries(${TGT} PUBLIC flatbuffers-1.10)
 117   endfunction(FlatBuffers_Target)
 118 endif(FlatBuffers_FOUND)