infra/cmake/modules/ExternalSourceTools.cmake

   1 #
   2 # ExternalSource_Download(VAR ...)
   3 #
   4 function(ExternalSource_Download PREFIX)
   5   include(CMakeParseArguments)
   6   nnas_include(StampTools)
   7
   8   cmake_parse_arguments(ARG "" "DIRNAME;URL;CHECKSUM" "" ${ARGN})
   9
  10   # Configure URL
  11   if(ARG_URL)
  12     set(URL ${ARG_URL})
  13   else()
  14     # Use the first unparsed argument as URL (for backward compatibility)
  15     list(GET ARG_UNPARSED_ARGUMENTS 0 URL)
  16   endif(ARG_URL)
  17
  18   # Configure DIRNAME
  19   if(NOT ARG_DIRNAME)
  20     # Use PREFIX as DIRNAME (for backward compatibility)
  21     set(DIRNAME ${PREFIX})
  22   else()
  23     set(DIRNAME ${ARG_DIRNAME})
  24   endif(NOT ARG_DIRNAME)
  25
  26   get_filename_component(FILENAME ${URL} NAME)
  27
  28   set(CACHE_DIR "${NNAS_EXTERNALS_DIR}")
  29   set(OUT_DIR "${CACHE_DIR}/${DIRNAME}")
  30   set(TMP_DIR "${CACHE_DIR}/${DIRNAME}-tmp")
  31
  32   set(DOWNLOAD_PATH "${CACHE_DIR}/${DIRNAME}-${FILENAME}")
  33   set(STAMP_PATH "${CACHE_DIR}/${DIRNAME}.stamp")
  34
  35   if(NOT EXISTS "${CACHE_DIR}")
  36     file(MAKE_DIRECTORY "${CACHE_DIR}")
  37   endif(NOT EXISTS "${CACHE_DIR}")
  38
  39   # Compare URL in STAMP file and the given URL
  40   Stamp_Check(URL_CHECK "${STAMP_PATH}" "${URL}")
  41
  42   if(NOT EXISTS "${OUT_DIR}" OR NOT URL_CHECK)
  43     file(REMOVE "${STAMP_PATH}")
  44     file(REMOVE_RECURSE "${OUT_DIR}")
  45     file(REMOVE_RECURSE "${TMP_DIR}")
  46
  47     file(MAKE_DIRECTORY "${TMP_DIR}")
  48
  49     message(STATUS "Download ${PREFIX} from ${URL}")
  50
  51     foreach(retry_count RANGE 5)
  52       message(STATUS "(Trial Count : ${retry_count})")
  53
  54       file(DOWNLOAD ${URL} "${DOWNLOAD_PATH}"
  55                     STATUS status
  56                     LOG log)
  57
  58       list(GET status 0 status_code)
  59       list(GET status 1 status_string)
  60
  61       # Download success
  62       if(status_code EQUAL 0)
  63         break()
  64       endif()
  65
  66       message(WARNING "error: downloading '${URL}' failed
  67               status_code: ${status_code}
  68               status_string: ${status_string}
  69               log: ${log}")
  70
  71       # Retry limit exceed
  72       if(retry_count EQUAL 5)
  73         message(FATAL_ERROR "Download ${PREFIX} from ${URL} - failed")
  74       endif()
  75
  76       # Retry after 10 seconds when download fails
  77       execute_process(COMMAND sleep 10)
  78     endforeach()
  79
  80     message(STATUS "Download ${PREFIX} from ${URL} - done")
  81
  82     # Verify checksum
  83     if(ARG_CHECKSUM)
  84       message(STATUS "Verify ${PREFIX} archive")
  85       string(REPLACE "=" ";" CHECKSUM_SPEC "${ARG_CHECKSUM}")
  86
  87       list(GET CHECKSUM_SPEC 0 CHECKSUM_ALG)
  88       list(GET CHECKSUM_SPEC 1 CHECKSUM_VAL)
  89       string(STRIP "${CHECKSUM_VAL}" CHECKSUM_VAL)
  90
  91       set(EXPECTED_CHECKSUM ${CHECKSUM_VAL})
  92       file(${CHECKSUM_ALG} "${DOWNLOAD_PATH}" OBTAINED_CHECKSUM)
  93
  94       if(NOT (EXPECTED_CHECKSUM STREQUAL OBTAINED_CHECKSUM))
  95         message(STATUS "CHECKSUM MISMATCH")
  96         message(STATUS "  expected: ${EXPECTED_CHECKSUM}")
  97         message(STATUS "  obtained: ${OBTAINED_CHECKSUM}")
  98         message(FATAL_ERROR "Verify ${PREFIX} archive - fail")
  99       endif(NOT (EXPECTED_CHECKSUM STREQUAL OBTAINED_CHECKSUM))
 100
 101       message(STATUS "Verify ${PREFIX} archive - done")
 102     endif(ARG_CHECKSUM)
 103
 104     message(STATUS "Extract ${PREFIX}")
 105     execute_process(COMMAND ${CMAKE_COMMAND} -E tar xfz "${DOWNLOAD_PATH}"
 106                     WORKING_DIRECTORY "${TMP_DIR}"
 107                     ERROR_VARIABLE EXTRACTION_ERROR)
 108
 109     if(EXTRACTION_ERROR)
 110       message(FATAL_ERROR "Extract ${PREFIX} - failed")
 111     endif(EXTRACTION_ERROR)
 112
 113     file(REMOVE "${DOWNLOAD_PATH}")
 114     message(STATUS "Extract ${PREFIX} - done")
 115
 116     message(STATUS "Cleanup ${PREFIX}")
 117     file(GLOB contents "${TMP_DIR}/*")
 118     list(LENGTH contents n)
 119     if(NOT n EQUAL 1 OR NOT IS_DIRECTORY "${contents}")
 120       set(contents "${TMP_DIR}")
 121     endif()
 122
 123     get_filename_component(contents ${contents} ABSOLUTE)
 124
 125     file(RENAME ${contents} "${OUT_DIR}")
 126     file(REMOVE_RECURSE "${TMP_DIR}")
 127     file(WRITE "${STAMP_PATH}" "${URL}")
 128     message(STATUS "Cleanup ${PREFIX} - done")
 129   endif()
 130
 131   set(${PREFIX}_SOURCE_DIR "${OUT_DIR}" PARENT_SCOPE)
 132 endfunction(ExternalSource_Download)