inference-engine/thirdparty/CMakeLists.txt

   1 # Copyright (C) 2018-2020 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
   6   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=unknown-warning-option -Wno-error=inconsistent-missing-override -Wno-error=pass-failed")
   7   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=unknown-warning-option -Wno-error=inconsistent-missing-override -Wno-error=pass-failed")
   8 elseif(CMAKE_COMPILER_IS_GNUCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 9.1)
   9     # On g++ 9.3.0 (Ubuntu 20.04) the ADE library raises "redundant-move" warnings
  10     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=redundant-move")
  11     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=redundant-move")
  12 endif()
  13
  14 function(build_with_lto)
  15     if(ENABLE_LTO)
  16         ie_enable_lto()
  17     endif()
  18
  19     if (ENABLE_CLDNN)
  20         set(CLDNN__OUTPUT_BIN_DIR ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})
  21         set(CLDNN__OUTPUT_LIB_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY})
  22         if (ENABLE_TESTS AND ENABLE_CLDNN_TESTS)
  23             set(CLDNN__INCLUDE_TESTS ON CACHE BOOL "" FORCE)
  24             set(CLDNN__INCLUDE_CORE_INTERNAL_TESTS ON CACHE BOOL "" FORCE)
  25         else()
  26             set(CLDNN__INCLUDE_TESTS OFF CACHE BOOL "" FORCE)
  27             set(CLDNN__INCLUDE_CORE_INTERNAL_TESTS OFF CACHE BOOL "" FORCE)
  28         endif()
  29         set(CLDNN__INCLUDE_EXAMPLES OFF CACHE BOOL "" FORCE)
  30         set(CLDNN__INCLUDE_TUTORIAL OFF CACHE BOOL "" FORCE)
  31         if (WIN32)
  32             set(CLDNN__ARCHITECTURE_TARGET "Windows64" CACHE STRING "" FORCE)
  33         elseif (ANDROID)
  34             set(CLDNN__ARCHITECTURE_TARGET "Android64" CACHE STRING "" FORCE)
  35         else()
  36             set(CLDNN__ARCHITECTURE_TARGET "Linux64" CACHE STRING "" FORCE)
  37         endif()
  38
  39         add_subdirectory(clDNN)
  40     endif()
  41
  42     function(ie_build_pugixml)
  43         set(BUILD_TESTS_current ${BUILD_TESTS})
  44         set(BUILD_TESTS OFF CACHE BOOL "Build tests" FORCE)
  45         add_subdirectory(pugixml)
  46         set(BUILD_TESTS ${BUILD_TESTS_current} CACHE BOOL "Build tests" FORCE)
  47     endfunction()
  48
  49     ie_build_pugixml()
  50     add_subdirectory(stb_lib)
  51     add_subdirectory(ade)
  52     add_subdirectory(fluid/modules/gapi)
  53
  54     target_include_directories(pugixml INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/pugixml/src>")
  55
  56     set_target_properties(pugixml ade fluid stb_image
  57                           PROPERTIES FOLDER thirdparty)
  58
  59     # developer package
  60
  61     ie_developer_export_targets(ade fluid pugixml)
  62     if(TARGET pugixml_mt)
  63         ie_developer_export_targets(pugixml_mt)
  64         set_target_properties(pugixml_mt PROPERTIES FOLDER thirdparty)
  65     endif()
  66
  67     if(ENABLE_MKL_DNN)
  68         set(SDL_cmake_included ON)
  69         include(mkldnn.cmake)
  70     endif()
  71 endfunction()
  72
  73 build_with_lto()