inference-engine/cmake/FindITT.cmake

   1 # Copyright (C) 2018-2019 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 unset(ITT_INCLUDE_DIR CACHE)
   6 unset(ITT_LIB CACHE)
   7
   8 if(NOT DEFINED INTEL_VTUNE_DIR AND DEFINED ENV{INTEL_VTUNE_DIR})
   9     set(INTEL_VTUNE_DIR "$ENV{INTEL_VTUNE_DIR}")
  10 endif()
  11 if(NOT DEFINED INTEL_VTUNE_DIR)
  12     if(EXISTS "/opt/intel/vtune_amplifier_xe/include")
  13         set(INTEL_VTUNE_DIR "/opt/intel/vtune_amplifier_xe")
  14     elseif(EXISTS "/opt/intel/vtune_amplifier/include")
  15         set(INTEL_VTUNE_DIR "/opt/intel/vtune_amplifier")
  16     elseif (EXISTS "C:/Program Files (x86)/IntelSWTools/VTune Amplifier XE")
  17         set(INTEL_VTUNE_DIR "C:/Program Files (x86)/IntelSWTools/VTune Amplifier XE")
  18     elseif (EXISTS "C:/Program Files (x86)/IntelSWTools/VTune Amplifier")
  19         set(INTEL_VTUNE_DIR "C:/Program Files (x86)/IntelSWTools/VTune Amplifier")
  20     elseif (EXISTS "$ENV{HOME}/intel/vtune_amplifier_2019")
  21         set(INTEL_VTUNE_DIR "$ENV{HOME}/intel/vtune_amplifier_2019")
  22     endif()
  23 endif()
  24
  25 if(DEFINED INTEL_VTUNE_DIR)
  26     message(STATUS "INTEL_VTUNE_DIR = ${INTEL_VTUNE_DIR}")
  27
  28     find_path(ITT_INCLUDE_DIR
  29     FILES
  30         ittnotify.h
  31     PATHS "${INTEL_VTUNE_DIR}/include/")
  32
  33     find_library(ITT_LIB
  34     "libittnotify${CMAKE_STATIC_LIBRARY_SUFFIX}"
  35     PATHS ${INTEL_VTUNE_DIR}/lib64)
  36
  37     set(Located_ITT_LIBS ${ITT_LIB})
  38     set(Located_ITT_INCLUDE_DIRS ${ITT_INCLUDE_DIR})
  39 else()
  40     message(STATUS "INTEL_VTUNE_DIR is not defined")
  41 endif()
  42
  43 # Handle find_package() arguments, and set INTEL_ITT_FOUND
  44 include(FindPackageHandleStandardArgs)
  45 find_package_handle_standard_args(INTEL_ITT
  46     REQUIRED_VARS
  47         Located_ITT_INCLUDE_DIRS
  48         Located_ITT_LIBS)
  49
  50 if(INTEL_ITT_FOUND)
  51     add_library(ittnotify STATIC IMPORTED GLOBAL)
  52     set_target_properties(ittnotify PROPERTIES IMPORTED_LOCATION "${Located_ITT_LIBS}"
  53                                                INTERFACE_INCLUDE_DIRECTORIES ${Located_ITT_INCLUDE_DIRS}
  54                                                INTERFACE_COMPILE_DEFINITIONS ENABLE_PROFILING_ITT)
  55
  56     set(INTEL_ITT_LIBS ittnotify ${CMAKE_DL_LIBS})
  57 endif()