i965_drv_video/shaders/vme/intra_frame.asm

   1 /*
   2  * Copyright © <2010>, Intel Corporation.
   3  *
   4  * This program is licensed under the terms and conditions of the
   5  * Eclipse Public License (EPL), version 1.0.  The full text of the EPL is at
   6  * http://www.opensource.org/licenses/eclipse-1.0.php.
   7  *
   8  */
   9 // Modual name: IntraFrame.asm
  10 //
  11 // Make intra predition estimation for Intra frame
  12 //
  13
  14 //
  15 //  Now, begin source code....
  16 //
  17
  18 /*
  19  * __START
  20  */
  21 __INTRA_START:
  22 mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  23 mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  24
  25 /*
  26  * Media Read Message -- fetch neighbor edge pixels
  27  */
  28 /* ROW */
  29 mul  (2) tmp_reg0.0<1>:D        orig_xy_ub<2,2,1>:UB 16:UW {align1};    /* (x, y) * 16 */
  30 add  (1) tmp_reg0.0<1>:D        tmp_reg0.0<0,1,0>:D -8:W {align1};     /* X offset */
  31 add  (1) tmp_reg0.4<1>:D        tmp_reg0.4<0,1,0>:D -1:W {align1};     /* Y offset */
  32 mov  (1) tmp_reg0.8<1>:UD       BLOCK_32X1 {align1};
  33 mov  (1) tmp_reg0.20<1>:UB      thread_id_ub {align1};                  /* dispatch id */
  34 mov  (8) msg_reg0.0<1>:UD       tmp_reg0.0<8,8,1>:UD {align1};
  35 send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  36
  37 /* COL */
  38 mul  (2) tmp_reg0.0<1>:D        orig_xy_ub<2,2,1>:UB 16:UW {align1};    /* (x, y) * 16 */
  39 add  (1) tmp_reg0.0<1>:D        tmp_reg0.0<0,1,0>:D -4:W {align1};     /* X offset */
  40 mov  (1) tmp_reg0.8<1>:UD       BLOCK_4X16 {align1};
  41 mov  (1) tmp_reg0.20<1>:UB      thread_id_ub {align1};                  /* dispatch id */
  42 mov  (8) msg_reg0.0<1>:UD       tmp_reg0.0<8,8,1>:UD {align1};
  43 send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  44
  45 /*
  46  * VME message
  47  */
  48 /* m0 */
  49 mul  (2) tmp_reg0.8<1>:UW       orig_xy_ub<2,2,1>:UB 16:UW {align1};    /* (x, y) * 16 */
  50 mov  (1) tmp_reg0.20<1>:UB      thread_id_ub {align1};                  /* dispatch id */
  51 mov  (8) vme_msg_0.0<1>:UD      tmp_reg0.0<8,8,1>:UD {align1};
  52
  53 /* m1 */
  54 mov  (1) intra_part_mask_ub<1>:UB LUMA_INTRA_8x8_DISABLE + LUMA_INTRA_4x4_DISABLE {align1};
  55
  56 cmp.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB 0:UW {align1};                                                   /* X != 0 */
  57 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_AE {align1};         /* A */
  58
  59 cmp.nz.f0.0 (1) null<1>:UW orig_y_ub<0,1,0>:UB 0:UW {align1};                                                   /* Y != 0 */
  60 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_B {align1};          /* B */
  61
  62 mul.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB orig_y_ub<0,1,0>:UB {align1};                                    /* X * Y != 0 */
  63 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_D {align1};          /* D */
  64
  65 add  (1) tmp_x_w<1>:W orig_x_ub<0,1,0>:UB 1:UW {align1};                                                        /* X + 1 */
  66 add  (1) tmp_x_w<1>:W w_in_mb_uw<0,1,0>:UW -tmp_x_w<0,1,0>:W {align1};                                          /* width - (X + 1) */
  67 mul.nz.f0.0 (1) null<1>:UD tmp_x_w<0,1,0>:W orig_y_ub<0,1,0>:UB {align1};                                       /* (width - (X + 1)) * Y != 0 */
  68 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_C {align1};          /* C */
  69
  70 mov  (8) vme_msg_1<1>:UD        tmp_reg1.0<8,8,1>:UD {align1};
  71
  72 /* m2 */
  73 mov (8) vme_msg_2<1>:UD         0x0:UD {align1};
  74
  75 /* m3 */
  76 mov  (8) vme_msg_3<1>:UD         INEP_ROW.0<8,8,1>:UD {align1};
  77
  78 /* m4 */
  79 mov  (8) vme_msg_4<1>:UD         0x0 {align1};
  80 mov (16) vme_msg_4.0<1>:UB       INEP_COL0.3<32,8,4>:UB {align1};
  81 mov  (1) vme_msg_4.16<1>:UD      INTRA_PREDICTORE_MODE {align1};
  82
  83 send (8)
  84         vme_msg_ind
  85         vme_wb
  86         null
  87         vme(
  88                 BIND_IDX_VME,
  89                 0,
  90                 0,
  91                 VME_MESSAGE_TYPE_INTRA
  92         )
  93         mlen vme_msg_length
  94         rlen 1
  95         {align1};
  96
  97 /*
  98  * Oword Block Write message
  99  */
 100 mul  (1) tmp_reg3.8<1>:UD       w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
 101 add  (1) tmp_reg3.8<1>:UD       tmp_reg3.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
 102 mov  (1) tmp_reg3.20<1>:UB      thread_id_ub {align1};                  /* dispatch id */
 103 mov  (8) msg_reg0.0<1>:UD       tmp_reg3<8,8,1>:UD {align1};
 104
 105 mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
 106 mov  (1) msg_reg1.4<1>:UD       vme_wb.16<0,1,0>:UD     {align1};
 107 mov  (1) msg_reg1.8<1>:UD       vme_wb.20<0,1,0>:UD     {align1};
 108 mov  (1) msg_reg1.12<1>:UD      vme_wb.24<0,1,0>:UD     {align1};
 109 /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
 110 send (16)
 111         msg_ind
 112         obw_wb
 113         null
 114         data_port(
 115                 OBW_CACHE_TYPE,
 116                 OBW_MESSAGE_TYPE,
 117                 OBW_CONTROL_0,
 118                 OBW_BIND_IDX,
 119                 OBW_WRITE_COMMIT_CATEGORY,
 120                 OBW_HEADER_PRESENT
 121         )
 122         mlen 2
 123         rlen obw_wb_length
 124         {align1};
 125
 126 /*
 127  * kill thread
 128  */
 129 mov  (8) msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
 130 send (16) msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};