gthread/meson.build

   1 # Just a skeleton lib for backwards compatibility since all the functionaliy
   2 # has been moved into glib now
   3
   4 gthread_sources = ['gthread-impl.c']
   5 if host_system == 'windows'
   6   gthread_win_rc = configure_file(
   7     input: 'gthread.rc.in',
   8     output: 'gthread.rc',
   9     configuration: glibconfig_conf,
  10   )
  11   gthread_win_res = windows.compile_resources(gthread_win_rc)
  12   gthread_sources += [gthread_win_res]
  13 endif
  14
  15 libgthread = library('gthread-2.0',
  16   sources : gthread_sources,
  17   version : library_version,
  18   soversion : soversion,
  19   darwin_versions : darwin_versions,
  20   install : true,
  21   dependencies : [libglib_dep],
  22   c_args : ['-DG_LOG_DOMAIN="GThread"' ] + glib_hidden_visibility_args,
  23   link_args : glib_link_flags,
  24 )
  25
  26 pkg.generate(libgthread,
  27   libraries : [thread_dep],
  28   requires : ['glib-2.0'],
  29   version : glib_version,
  30   install_dir : glib_pkgconfigreldir,
  31   filebase : 'gthread-2.0',
  32   name : 'GThread',
  33   description : 'Thread support for GLib',
  34 )
  35
  36 libgthread_dep = declare_dependency(link_with : libgthread)
  37
  38 if meson.version().version_compare('>=0.54.0')
  39   meson.override_dependency('gthread-2.0', libgthread_dep)
  40 endif