gtests/CMakeLists.txt

   1 if(BUILD_TESTING)
   2     if(TARGET gmock)
   3         message(STATUS "Google Mock found - building tests")
   4
   5         set(TEST_SOURCES
   6             # Framework related source files
   7             ${CMAKE_CURRENT_SOURCE_DIR}/Initializer.h
   8             ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
   9             ${CMAKE_CURRENT_SOURCE_DIR}/Settings.cpp
  10             ${CMAKE_CURRENT_SOURCE_DIR}/Settings.h
  11             ${CMAKE_CURRENT_SOURCE_DIR}/TestFixture.cpp
  12             ${CMAKE_CURRENT_SOURCE_DIR}/TestFixture.h
  13
  14             # Test related source files
  15             ${CMAKE_CURRENT_SOURCE_DIR}/AST.FromFile.cpp
  16             ${CMAKE_CURRENT_SOURCE_DIR}/BuiltInResource.FromFile.cpp
  17             ${CMAKE_CURRENT_SOURCE_DIR}/Config.FromFile.cpp
  18             ${CMAKE_CURRENT_SOURCE_DIR}/HexFloat.cpp
  19             ${CMAKE_CURRENT_SOURCE_DIR}/Hlsl.FromFile.cpp
  20             ${CMAKE_CURRENT_SOURCE_DIR}/Link.FromFile.cpp
  21             ${CMAKE_CURRENT_SOURCE_DIR}/Link.FromFile.Vk.cpp
  22             ${CMAKE_CURRENT_SOURCE_DIR}/Pp.FromFile.cpp
  23             ${CMAKE_CURRENT_SOURCE_DIR}/Spv.FromFile.cpp
  24
  25             # -- Remapper tests
  26             ${CMAKE_CURRENT_SOURCE_DIR}/Remap.FromFile.cpp)
  27
  28         add_executable(glslangtests ${TEST_SOURCES})
  29         set_property(TARGET glslangtests PROPERTY FOLDER tests)
  30         glslang_set_link_args(glslangtests)
  31         if(ENABLE_GLSLANG_INSTALL)
  32             install(TARGETS glslangtests
  33                     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  34         endif(ENABLE_GLSLANG_INSTALL)
  35
  36         set(GLSLANG_TEST_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/../Test")
  37         # Supply a default test root directory, so that manual testing
  38         # doesn't have to specify the --test-root option in the normal
  39         # case that you want to use the tests from the same source tree.
  40         target_compile_definitions(glslangtests
  41                                    PRIVATE GLSLANG_TEST_DIRECTORY="${GLSLANG_TEST_DIRECTORY}")
  42         target_include_directories(glslangtests PRIVATE
  43                                    ${CMAKE_CURRENT_SOURCE_DIR}
  44                                    ${PROJECT_SOURCE_DIR}
  45                                    ${gmock_SOURCE_DIR}/include
  46                                    ${gtest_SOURCE_DIR}/include)
  47
  48         set(LIBRARIES
  49             SPVRemapper glslang OSDependent OGLCompiler glslang
  50             SPIRV glslang-default-resource-limits)
  51         if(ENABLE_HLSL)
  52             set(LIBRARIES ${LIBRARIES} HLSL)
  53         endif(ENABLE_HLSL)
  54         target_link_libraries(glslangtests PRIVATE ${LIBRARIES} gmock)
  55
  56         add_test(NAME glslang-gtests
  57                  COMMAND glslangtests --test-root "${GLSLANG_TEST_DIRECTORY}")
  58     endif()
  59 endif()