gtests/CMakeLists.txt

   1 if(BUILD_TESTING)
   2     if(TARGET gmock)
   3         message(STATUS "Google Mock found - building tests")
   4
   5         set(TEST_SOURCES
   6             # Framework related source files
   7             ${CMAKE_CURRENT_SOURCE_DIR}/Initializer.h
   8             ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
   9             ${CMAKE_CURRENT_SOURCE_DIR}/Settings.cpp
  10             ${CMAKE_CURRENT_SOURCE_DIR}/Settings.h
  11             ${CMAKE_CURRENT_SOURCE_DIR}/TestFixture.cpp
  12             ${CMAKE_CURRENT_SOURCE_DIR}/TestFixture.h
  13
  14             # Test related source files
  15             ${CMAKE_CURRENT_SOURCE_DIR}/AST.FromFile.cpp
  16             ${CMAKE_CURRENT_SOURCE_DIR}/BuiltInResource.FromFile.cpp
  17             ${CMAKE_CURRENT_SOURCE_DIR}/Config.FromFile.cpp
  18             ${CMAKE_CURRENT_SOURCE_DIR}/HexFloat.cpp
  19             ${CMAKE_CURRENT_SOURCE_DIR}/Hlsl.FromFile.cpp
  20             ${CMAKE_CURRENT_SOURCE_DIR}/Link.FromFile.cpp
  21             ${CMAKE_CURRENT_SOURCE_DIR}/Link.FromFile.Vk.cpp
  22             ${CMAKE_CURRENT_SOURCE_DIR}/Pp.FromFile.cpp
  23             ${CMAKE_CURRENT_SOURCE_DIR}/Spv.FromFile.cpp
  24
  25             # -- Remapper tests
  26             ${CMAKE_CURRENT_SOURCE_DIR}/Remap.FromFile.cpp)
  27
  28         glslang_pch(TEST_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/pch.cpp)
  29
  30         add_executable(glslangtests ${TEST_SOURCES})
  31         set_property(TARGET glslangtests PROPERTY FOLDER tests)
  32         glslang_set_link_args(glslangtests)
  33         if(ENABLE_GLSLANG_INSTALL)
  34             install(TARGETS glslangtests EXPORT glslangtestsTargets
  35                     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  36                         install(EXPORT glslangtestsTargets DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake)
  37         endif(ENABLE_GLSLANG_INSTALL)
  38
  39         set(GLSLANG_TEST_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/../Test")
  40         # Supply a default test root directory, so that manual testing
  41         # doesn't have to specify the --test-root option in the normal
  42         # case that you want to use the tests from the same source tree.
  43         target_compile_definitions(glslangtests
  44                                    PRIVATE GLSLANG_TEST_DIRECTORY="${GLSLANG_TEST_DIRECTORY}")
  45         target_include_directories(glslangtests PRIVATE
  46                                    ${CMAKE_CURRENT_SOURCE_DIR}
  47                                    ${PROJECT_SOURCE_DIR}
  48                                    ${gmock_SOURCE_DIR}/include
  49                                    ${gtest_SOURCE_DIR}/include)
  50
  51         set(LIBRARIES
  52             SPVRemapper glslang OSDependent OGLCompiler glslang
  53             SPIRV glslang-default-resource-limits)
  54         if(ENABLE_HLSL)
  55             set(LIBRARIES ${LIBRARIES} HLSL)
  56         endif(ENABLE_HLSL)
  57         target_link_libraries(glslangtests PRIVATE ${LIBRARIES} gmock)
  58
  59         add_test(NAME glslang-gtests
  60                  COMMAND glslangtests --test-root "${GLSLANG_TEST_DIRECTORY}")
  61     endif()
  62 endif()