gst-libs/gst/sdp/meson.build

   1 gst_sdp_headers = [
   2   'sdp.h',
   3   'sdp-prelude.h',
   4   'gstsdp.h',
   5   'gstmikey.h',
   6   'gstsdpmessage.h',
   7 ]
   8 install_headers(gst_sdp_headers, subdir : 'gstreamer-1.0/gst/sdp/')
   9
  10 rtsp_deps = [rtp_dep, gst_dep, gio_dep]
  11 gst_sdp_sources = ['gstsdpmessage.c', 'gstmikey.c']
  12 gstsdp = library('gstsdp-@0@'.format(api_version),
  13   gst_sdp_sources,
  14   c_args : gst_plugins_base_args,
  15   include_directories: [configinc, libsinc],
  16   version : libversion,
  17   soversion : soversion,
  18   darwin_versions : osxversion,
  19   install : true,
  20   dependencies : rtsp_deps,
  21 )
  22
  23 sdp_gen_sources  = []
  24 if build_gir
  25   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/sdp/sdp.h' ]
  26   sdp_gen_sources += [gnome.generate_gir(gstsdp,
  27     sources : gst_sdp_sources + gst_sdp_headers,
  28     namespace : 'GstSdp',
  29     nsversion : api_version,
  30     identifier_prefix : 'Gst',
  31     symbol_prefix : 'gst',
  32     export_packages : 'gstreamer-sdp-1.0',
  33     includes : ['Gst-1.0'],
  34     install : true,
  35     extra_args : gst_gir_extra_args,
  36     dependencies : rtsp_deps
  37   )]
  38 endif
  39
  40 sdp_dep = declare_dependency(link_with: gstsdp,
  41   include_directories : [libsinc],
  42   dependencies : rtsp_deps,
  43   sources: sdp_gen_sources)