gst-libs/gst/rtsp/meson.build

   1 rtsp_sources = [
   2   'gstrtsptransport.c',
   3   'gstrtspurl.c',
   4   'gstrtspmessage.c',
   5   'gstrtspconnection.c',
   6   'gstrtspdefs.c',
   7   'gstrtspextension.c',
   8   'gstrtsprange.c'
   9   ]
  10
  11 rtsp_headers = [
  12   'gstrtspconnection.h',
  13   'gstrtspdefs.h',
  14   'gstrtspextension.h',
  15   'gstrtsp.h',
  16   'gstrtspmessage.h',
  17   'gstrtsprange.h',
  18   'gstrtsptransport.h',
  19   'gstrtspurl.h',
  20   'rtsp-prelude.h',
  21   'rtsp.h',
  22 ]
  23 install_headers(rtsp_headers, subdir : 'gstreamer-1.0/gst/rtsp/')
  24
  25 rtsp_enums = gnome.mkenums_simple('gstrtsp-enumtypes',
  26   sources : rtsp_headers,
  27   header_prefix : '#include <gst/rtsp/rtsp-prelude.h>',
  28   decorator : 'GST_RTSP_API',
  29   install_header: true,
  30   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/rtsp'))
  31 gstrtsp_c = rtsp_enums[0]
  32 gstrtsp_h = rtsp_enums[1]
  33
  34 if host_system == 'windows'
  35   winsock2 = cc.find_library('ws2_32')
  36 else
  37   winsock2 = []
  38 endif
  39 gstrtsp_deps = [gst_base_dep, gst_dep, gio_dep, libm, winsock2]
  40
  41 gst_rtsp = library('gstrtsp-@0@'.format(api_version),
  42   rtsp_sources,
  43   gstrtsp_h, gstrtsp_c,
  44   c_args : gst_plugins_base_args,
  45   include_directories: [configinc, libsinc],
  46   version : libversion,
  47   soversion : soversion,
  48   darwin_versions : osxversion,
  49   install : true,
  50   dependencies : gstrtsp_deps,
  51 )
  52
  53 rtsp_gen_sources = [gstrtsp_h]
  54 if build_gir
  55   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/rtsp/rtsp.h' ]
  56   rtsp_gen_sources += [gnome.generate_gir(gst_rtsp,
  57     sources : rtsp_sources + rtsp_headers + [gstrtsp_c] + [gstrtsp_h],
  58     namespace : 'GstRtsp',
  59     nsversion : api_version,
  60     identifier_prefix : 'Gst',
  61     symbol_prefix : 'gst',
  62     export_packages : 'gstreamer-rtsp-1.0',
  63     includes : ['Gst-1.0', 'GstBase-1.0', 'GstSdp-1.0', 'Gio-2.0'],
  64     install : true,
  65     extra_args : gst_gir_extra_args,
  66     dependencies : gstrtsp_deps + [sdp_dep]
  67   )]
  68 endif
  69
  70 rtsp_dep = declare_dependency(link_with : gst_rtsp,
  71   include_directories : [libsinc],
  72   dependencies : gstrtsp_deps,
  73   sources : rtsp_gen_sources)