gst-libs/gst/rtp/meson.build

   1 rtp_sources = [
   2   'gstrtpbuffer.c',
   3   'gstrtcpbuffer.c',
   4   'gstrtppayloads.c',
   5   'gstrtphdrext.c',
   6   'gstrtpmeta.c',
   7   'gstrtpbaseaudiopayload.c',
   8   'gstrtpbasepayload.c',
   9   'gstrtpbasedepayload.c'
  10   ]
  11
  12 rtp_headers = [
  13   'gstrtcpbuffer.h',
  14   'gstrtpbaseaudiopayload.h',
  15   'gstrtpbasedepayload.h',
  16   'gstrtpbasepayload.h',
  17   'gstrtpbuffer.h',
  18   'gstrtpdefs.h',
  19   'gstrtphdrext.h',
  20   'gstrtpmeta.h',
  21   'gstrtppayloads.h',
  22   'rtp-prelude.h',
  23   'rtp.h',
  24 ]
  25 install_headers(rtp_headers, subdir : 'gstreamer-1.0/gst/rtp/')
  26
  27 rtp_enums = gnome.mkenums_simple('gstrtp-enumtypes',
  28   sources : rtp_headers,
  29   body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
  30   header_prefix : '#include <gst/rtp/rtp-prelude.h>',
  31   decorator : 'GST_RTP_API',
  32   install_header: true,
  33   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/rtp'))
  34 gstrtp_enum_c = rtp_enums[0]
  35 gstrtp_enum_h = rtp_enums[1]
  36
  37 gstrtp_deps = [audio_dep, gst_base_dep]
  38 gst_rtp = library('gstrtp-@0@'.format(api_version),
  39   rtp_sources, gstrtp_enum_c, gstrtp_enum_h,
  40   c_args : gst_plugins_base_args + ['-DBUILDING_GST_RTP'],
  41   include_directories: [configinc, libsinc],
  42   version : libversion,
  43   soversion : soversion,
  44   darwin_versions : osxversion,
  45   install : true,
  46   dependencies : gstrtp_deps,
  47 )
  48
  49 rtp_gen_sources = [gstrtp_enum_h]
  50 if build_gir
  51   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/rtp/rtp.h' ]
  52   rtp_gir = gnome.generate_gir(gst_rtp,
  53     sources : rtp_sources + rtp_headers + [gstrtp_enum_c] + [gstrtp_enum_h],
  54     namespace : 'GstRtp',
  55     nsversion : api_version,
  56     identifier_prefix : 'Gst',
  57     symbol_prefix : 'gst',
  58     export_packages : 'gstreamer-rtp-1.0',
  59     includes : ['Gst-1.0', 'GstBase-1.0'],
  60     install : true,
  61     extra_args : gst_gir_extra_args,
  62     dependencies : gstrtp_deps
  63   )
  64
  65   rtp_gen_sources += [rtp_gir]
  66 endif
  67
  68
  69 rtp_dep = declare_dependency(link_with : gst_rtp,
  70   include_directories : [libsinc],
  71   dependencies : gstrtp_deps,
  72   sources : rtp_gen_sources)