gst-libs/gst/audio/meson.build

   1 audio_src= [
   2   'audio.c',
   3   'audio-channel-mixer.c',
   4   'audio-channels.c',
   5   'audio-converter.c',
   6   'audio-format.c',
   7   'audio-info.c',
   8   'audio-quantize.c',
   9   'audio-resampler.c',
  10   'gstaudiobasesink.c',
  11   'gstaudiobasesrc.c',
  12   'gstaudiocdsrc.c',
  13   'gstaudioclock.c',
  14   'gstaudiodecoder.c',
  15   'gstaudioencoder.c',
  16   'gstaudiofilter.c',
  17   'gstaudioiec61937.c',
  18   'gstaudiometa.c',
  19   'gstaudioringbuffer.c',
  20   'gstaudiosink.c',
  21   'gstaudiosrc.c',
  22   'gstaudioutilsprivate.c',
  23   'streamvolume.c',
  24 ]
  25
  26 audio_mkenum_headers = [
  27   'audio.h',
  28   'audio-format.h',
  29   'audio-channels.h',
  30   'audio-channel-mixer.h',
  31   'audio-converter.h',
  32   'audio-info.h',
  33   'audio-quantize.h',
  34   'audio-resampler.h',
  35   'gstaudioringbuffer.h',
  36 ]
  37
  38 # FIXME: check headers
  39 audio_headers = audio_mkenum_headers + [
  40   'gstaudiobasesink.h',
  41   'gstaudiobasesrc.h',
  42   'gstaudiocdsrc.h',
  43   'gstaudioclock.h',
  44   'gstaudiodecoder.h',
  45   'gstaudioencoder.h',
  46   'gstaudiofilter.h',
  47   'gstaudioiec61937.h',
  48   'gstaudiometa.h',
  49   'gstaudiosink.h',
  50   'gstaudiosrc.h',
  51   'streamvolume.h',
  52 ]
  53 install_headers(audio_headers, subdir : 'gstreamer-1.0/gst/audio/')
  54
  55 mkenums = find_program('audio_mkenum.py')
  56 gstaudio_h = custom_target('gstaudioenum_h',
  57   output : 'audio-enumtypes.h',
  58   input : audio_mkenum_headers,
  59   install : true,
  60   install_dir : 'include/gstreamer-1.0/gst/audio/',
  61   command : [mkenums, glib_mkenums, '@OUTPUT@', '@INPUT@'])
  62
  63 gstaudio_c = custom_target('gstaudioenum_c',
  64   output : 'audio-enumtypes.c',
  65   input : audio_mkenum_headers,
  66   depends : [gstaudio_h],
  67   command : [mkenums, glib_mkenums, '@OUTPUT@', '@INPUT@'])
  68
  69 orcsrc = 'gstaudiopack'
  70 if have_orcc
  71   orc_h = custom_target(orcsrc + '.h',
  72     input : orcsrc + '.orc',
  73     output : orcsrc + '.h',
  74     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
  75   orc_c = custom_target(orcsrc + '.c',
  76     input : orcsrc + '.orc',
  77     output : orcsrc + '.c',
  78     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  79 else
  80   orc_h = configure_file(input : orcsrc + '-dist.h',
  81     output : orcsrc + '.h',
  82     configuration : configuration_data())
  83   orc_c = configure_file(input : orcsrc + '-dist.c',
  84     output : orcsrc + '.c',
  85     configuration : configuration_data())
  86 endif
  87
  88 gstaudio = library('gstaudio-@0@'.format(api_version),
  89   audio_src, gstaudio_h, gstaudio_c, orc_c, orc_h,
  90   c_args: gst_plugins_base_args,
  91   include_directories: [configinc, libsinc],
  92   version : libversion,
  93   soversion : soversion,
  94   install : true,
  95   dependencies : [tag_dep, gst_base_dep, libm],
  96   vs_module_defs: vs_module_defs_dir + 'libgstaudio.def',
  97 )
  98 # TODO: generate gir
  99
 100 audio_dep = declare_dependency(link_with : gstaudio,
 101   include_directories : [libsinc],
 102   dependencies : [gst_base_dep, tag_dep],
 103   sources : [gstaudio_h])