gst-libs/gst/audio/meson.build

   1 audio_src= [
   2   'audio.c',
   3   'audio-buffer.c',
   4   'audio-channel-mixer.c',
   5   'audio-channels.c',
   6   'audio-converter.c',
   7   'audio-format.c',
   8   'audio-info.c',
   9   'audio-quantize.c',
  10   'audio-resampler.c',
  11   'gstaudioaggregator.c',
  12   'gstaudiobasesink.c',
  13   'gstaudiobasesrc.c',
  14   'gstaudiocdsrc.c',
  15   'gstaudioclock.c',
  16   'gstaudiodecoder.c',
  17   'gstaudioencoder.c',
  18   'gstaudiofilter.c',
  19   'gstaudioiec61937.c',
  20   'gstaudiometa.c',
  21   'gstaudioringbuffer.c',
  22   'gstaudiosink.c',
  23   'gstaudiosrc.c',
  24   'gstaudioutilsprivate.c',
  25   'streamvolume.c',
  26   'gstaudiostreamalign.c',
  27 ]
  28
  29 audio_mkenum_headers = [
  30   'audio.h',
  31   'audio-format.h',
  32   'audio-channels.h',
  33   'audio-channel-mixer.h',
  34   'audio-converter.h',
  35   'audio-info.h',
  36   'audio-quantize.h',
  37   'audio-resampler.h',
  38   'gstaudioaggregator.h',
  39   'gstaudioringbuffer.h',
  40   'gstaudiobasesrc.h',
  41   'gstaudiocdsrc.h',
  42   'gstaudiobasesink.h',
  43   'gstaudiostreamalign.h',
  44 ]
  45
  46 # FIXME: check headers
  47 audio_headers = audio_mkenum_headers + [
  48   'audio-prelude.h',
  49   'audio-buffer.h',
  50   'gstaudiobasesink.h',
  51   'gstaudiobasesrc.h',
  52   'gstaudiocdsrc.h',
  53   'gstaudioclock.h',
  54   'gstaudiodecoder.h',
  55   'gstaudioencoder.h',
  56   'gstaudiofilter.h',
  57   'gstaudioiec61937.h',
  58   'gstaudiometa.h',
  59   'gstaudiosink.h',
  60   'gstaudiosrc.h',
  61   'streamvolume.h',
  62 ]
  63 install_headers(audio_headers, subdir : 'gstreamer-1.0/gst/audio/')
  64
  65 audio_enums = gnome.mkenums_simple('audio-enumtypes',
  66   sources : audio_mkenum_headers,
  67   header_prefix : '#include <gst/audio/audio-prelude.h>',
  68   decorator : 'GST_AUDIO_API',
  69   install_header: true,
  70   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/audio'))
  71 gstaudio_c = audio_enums[0]
  72 gstaudio_h = audio_enums[1]
  73
  74 audio_gen_sources = [gstaudio_h]
  75
  76 gstaudio_deps = [tag_dep, gst_base_dep, libm]
  77 orcsrc = 'gstaudiopack'
  78 if have_orcc
  79   gstaudio_deps += [orc_dep]
  80   orc_h = custom_target(orcsrc + '.h',
  81     input : orcsrc + '.orc',
  82     output : orcsrc + '.h',
  83     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
  84   orc_c = custom_target(orcsrc + '.c',
  85     input : orcsrc + '.orc',
  86     output : orcsrc + '.c',
  87     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  88 else
  89   orc_h = configure_file(input : orcsrc + '-dist.h',
  90     output : orcsrc + '.h',
  91     configuration : configuration_data())
  92   orc_c = configure_file(input : orcsrc + '-dist.c',
  93     output : orcsrc + '.c',
  94     configuration : configuration_data())
  95 endif
  96
  97 simd_cargs = []
  98 simd_dependencies = []
  99
 100 if have_sse
 101   audio_resampler_sse = static_library('audio_resampler_sse',
 102     ['audio-resampler-x86-sse.c', gstaudio_h],
 103     c_args : gst_plugins_base_args + [sse_args],
 104     include_directories : [configinc, libsinc],
 105     dependencies : [gst_base_dep],
 106     pic : true,
 107     install : false
 108   )
 109   simd_cargs += ['-DHAVE_SSE']
 110   simd_dependencies += audio_resampler_sse
 111 endif
 112
 113 if have_sse2
 114   audio_resampler_sse2 = static_library('audio_resampler_sse2',
 115     ['audio-resampler-x86-sse2.c', gstaudio_h],
 116     c_args : gst_plugins_base_args + [sse2_args],
 117     include_directories : [configinc, libsinc],
 118     dependencies : [gst_base_dep],
 119     pic : true,
 120     install : false
 121   )
 122
 123   simd_cargs += ['-DHAVE_SSE2']
 124   simd_dependencies += audio_resampler_sse2
 125 endif
 126
 127 if have_sse41
 128   audio_resampler_sse41 = static_library('audio_resampler_sse41',
 129     ['audio-resampler-x86-sse41.c', gstaudio_h],
 130     c_args : gst_plugins_base_args + [sse41_args],
 131     include_directories : [configinc, libsinc],
 132     dependencies : [gst_base_dep],
 133     pic : true,
 134     install : false
 135   )
 136
 137   simd_cargs += ['-DHAVE_SSE41']
 138   simd_dependencies += audio_resampler_sse41
 139 endif
 140
 141 gstaudio = library('gstaudio-@0@'.format(api_version),
 142   audio_src, gstaudio_h, gstaudio_c, orc_c, orc_h,
 143   c_args : gst_plugins_base_args + simd_cargs,
 144   include_directories: [configinc, libsinc],
 145   link_with : simd_dependencies,
 146   version : libversion,
 147   soversion : soversion,
 148   darwin_versions : osxversion,
 149   install : true,
 150   dependencies : gstaudio_deps,
 151 )
 152
 153 if build_gir
 154   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/audio/audio.h' ]
 155   audio_gen_sources += [gnome.generate_gir(gstaudio,
 156     sources : audio_src + audio_headers + [gstaudio_c] + [gstaudio_h],
 157     namespace : 'GstAudio',
 158     nsversion : api_version,
 159     identifier_prefix : 'Gst',
 160     symbol_prefix : 'gst',
 161     export_packages : 'gstreamer-audio-1.0',
 162     includes : ['Gst-1.0', 'GstBase-1.0', 'GLib-2.0', 'GObject-2.0', 'GModule-2.0' ],
 163     install : true,
 164     extra_args : gst_gir_extra_args,
 165     dependencies : gstaudio_deps
 166   )]
 167 endif
 168
 169 audio_dep = declare_dependency(link_with : gstaudio,
 170   include_directories : [libsinc],
 171   dependencies : gstaudio_deps,
 172   sources : audio_gen_sources)