gst/volume/meson.build

   1 orcsrc = 'gstvolumeorc'
   2 if have_orcc
   3   orc_h = custom_target(orcsrc + '.h',
   4     input : orcsrc + '.orc',
   5     output : orcsrc + '.h',
   6     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
   7   orc_c = custom_target(orcsrc + '.c',
   8     input : orcsrc + '.orc',
   9     output : orcsrc + '.c',
  10     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  11 else
  12   orc_h = configure_file(input : orcsrc + '-dist.h',
  13     output : orcsrc + '.h',
  14     configuration : configuration_data())
  15   orc_c = configure_file(input : orcsrc + '-dist.c',
  16     output : orcsrc + '.c',
  17     configuration : configuration_data())
  18 endif
  19
  20 gstvolume = library('gstvolume', 'gstvolume.c', orc_c, orc_h,
  21   c_args : gst_plugins_base_args,
  22   include_directories: [configinc, libsinc],
  23   dependencies : glib_deps + [audio_dep, gst_dep, gst_base_dep],
  24   install : true,
  25   install_dir : plugins_install_dir,
  26 )