gst/deinterlace/meson.build

   1 interlace_sources = [
   2   'gstdeinterlace.c',
   3   'gstdeinterlacemethod.c',
   4   'tvtime/tomsmocomp.c',
   5   'tvtime/greedy.c',
   6   'tvtime/greedyh.c',
   7   'tvtime/vfir.c',
   8   'tvtime/weavetff.c',
   9   'tvtime/weavebff.c',
  10   'tvtime/weave.c',
  11   'tvtime/linear.c',
  12   'tvtime/linearblend.c',
  13   'tvtime/scalerbob.c'
  14 ]
  15
  16 orcsrc = 'tvtime'
  17 if have_orcc
  18   orc_h = custom_target(orcsrc + '.h',
  19     input : orcsrc + '.orc',
  20     output : orcsrc + '.h',
  21     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
  22   orc_c = custom_target(orcsrc + '.c',
  23     input : orcsrc + '.orc',
  24     output : orcsrc + '.c',
  25     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  26 else
  27   orc_h = configure_file(input : orcsrc + '-dist.h',
  28     output : orcsrc + '.h',
  29     configuration : configuration_data())
  30   orc_c = configure_file(input : orcsrc + '-dist.c',
  31     output : orcsrc + '.c',
  32     configuration : configuration_data())
  33 endif
  34
  35 gstdeinterlace = library('gstdeinterlace',
  36   interlace_sources, orc_c, orc_h,
  37   c_args : gst_plugins_good_args,
  38   include_directories : [configinc],
  39   dependencies : [orc_dep, gstbase_dep, gstvideo_dep],
  40   install : true,
  41   install_dir : plugins_install_dir,
  42 )
  43 pkgconfig.generate(gstdeinterlace, install_dir : plugins_pkgconfig_install_dir)
  44