gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.13)
   3 AC_INIT(gprof.c)
   4
   5 AC_CANONICAL_SYSTEM
   6 AC_ISC_POSIX
   7
   8 changequote(,)dnl
   9 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  10 changequote([,])dnl
  11 AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
  12
  13 AM_PROG_LIBTOOL
  14
  15 dnl For simplicity, we use the BFD configuration file for most
  16 dnl things.  However, we also need our own configuration file for
  17 dnl the automake PACKAGE and VERSION macros.  We don't name it
  18 dnl config.h, to avoid any possible confusion with the bfd config.h.
  19 AM_CONFIG_HEADER(gconfig.h:gconfig.in)
  20
  21 AC_PROG_CC
  22 AC_PROG_INSTALL
  23
  24 AC_CHECK_FUNCS(setmode)
  25
  26 ALL_LINGUAS="fr tr sv es id da"
  27 CY_GNU_GETTEXT
  28
  29 AM_MAINTAINER_MODE
  30 AC_EXEEXT
  31
  32 AC_CHECK_HEADERS(sys/gmon_out.h)
  33
  34 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  35 AC_ARG_ENABLE(build-warnings,
  36 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  37 [case "${enableval}" in
  38   yes)  ;;
  39   no)   build_warnings="-w";;
  40   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  41         build_warnings="${build_warnings} ${t}";;
  42   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  43         build_warnings="${t} ${build_warnings}";;
  44   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  45 esac
  46 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  47   echo "Setting warning flags = $build_warnings" 6>&1
  48 fi])dnl
  49 WARN_CFLAGS=""
  50 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  51     WARN_CFLAGS="${build_warnings}"
  52 fi
  53 AC_SUBST(WARN_CFLAGS)
  54
  55 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
  56 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])