gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19 AC_PREREQ(2.59)
  20 AC_INIT
  21 AC_CONFIG_SRCDIR([gprof.c])
  22
  23 AC_CANONICAL_TARGET([])
  24 AC_ISC_POSIX
  25
  26 changequote(,)dnl
  27 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  28 changequote([,])dnl
  29 AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
  30
  31 dnl For simplicity, we use the BFD configuration file for most
  32 dnl things.  However, we also need our own configuration file for
  33 dnl the automake PACKAGE and VERSION macros.  We don't name it
  34 dnl config.h, to avoid any possible confusion with the bfd config.h.
  35 AC_CONFIG_HEADERS([gconfig.h:gconfig.in])
  36
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_USE_SYSTEM_EXTENSIONS
  40 ACX_LARGEFILE
  41 AC_PROG_INSTALL
  42
  43 LT_INIT
  44
  45 AC_CHECK_FUNCS(setmode)
  46
  47 ALL_LINGUAS="fr tr sv es id da pt_BR de vi rw ga ms fi nl bg eo ja sr"
  48 ZW_GNU_GETTEXT_SISTER_DIR
  49 AM_PO_SUBDIRS
  50
  51 AM_MAINTAINER_MODE
  52 AM_CONDITIONAL(GENINSRC_NEVER, false)
  53 AC_EXEEXT
  54
  55 AC_CHECK_HEADERS(sys/gmon_out.h)
  56
  57 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
  58 AC_CACHE_VAL(gprof_cv_decl_getopt_unistd_h,
  59 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
  60 gprof_cv_decl_getopt_unistd_h=yes, gprof_cv_decl_getopt_unistd_h=no)])
  61 AC_MSG_RESULT($gprof_cv_decl_getopt_unistd_h)
  62 if test $gprof_cv_decl_getopt_unistd_h = yes; then
  63   AC_DEFINE([HAVE_DECL_GETOPT], 1,
  64             [Is the prototype for getopt in <unistd.h> in the expected format?])
  65 fi
  66
  67 # Some systems have fabs only in -lm, not in -lc.
  68 AC_SEARCH_LIBS(fabs, m)
  69
  70 AM_BINUTILS_WARNINGS
  71
  72 dnl Required by html, pdf, install-pdf and install-html
  73 AC_SUBST(datarootdir)
  74 AC_SUBST(docdir)
  75 AC_SUBST(htmldir)
  76 AC_SUBST(pdfdir)
  77
  78 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
  79 AC_OUTPUT