googlemock/CMakeLists.txt

   1 ########################################################################
   2 # Note: CMake support is community-based. The maintainers do not use CMake
   3 # internally.
   4 #
   5 # CMake build script for Google Mock.
   6 #
   7 # To run the tests for Google Mock itself on Linux, use 'make test' or
   8 # ctest.  You can select which tests to run using 'ctest -R regex'.
   9 # For more options, run 'ctest --help'.
  10
  11 option(gmock_build_tests "Build all of Google Mock's own tests." OFF)
  12
  13 # A directory to find Google Test sources.
  14 if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gtest/CMakeLists.txt")
  15   set(gtest_dir gtest)
  16 else()
  17   set(gtest_dir ../googletest)
  18 endif()
  19
  20 # Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build().
  21 include("${gtest_dir}/cmake/hermetic_build.cmake" OPTIONAL)
  22
  23 if (COMMAND pre_project_set_up_hermetic_build)
  24   # Google Test also calls hermetic setup functions from add_subdirectory,
  25   # although its changes will not affect things at the current scope.
  26   pre_project_set_up_hermetic_build()
  27 endif()
  28
  29 ########################################################################
  30 #
  31 # Project-wide settings
  32
  33 # Name of the project.
  34 #
  35 # CMake files in this project can refer to the root source directory
  36 # as ${gmock_SOURCE_DIR} and to the root binary directory as
  37 # ${gmock_BINARY_DIR}.
  38 # Language "C" is required for find_package(Threads).
  39 cmake_minimum_required(VERSION 3.13)
  40 project(gmock VERSION ${GOOGLETEST_VERSION} LANGUAGES CXX C)
  41
  42 if (COMMAND set_up_hermetic_build)
  43   set_up_hermetic_build()
  44 endif()
  45
  46 # Instructs CMake to process Google Test's CMakeLists.txt and add its
  47 # targets to the current scope.  We are placing Google Test's binary
  48 # directory in a subdirectory of our own as VC compilation may break
  49 # if they are the same (the default).
  50 add_subdirectory("${gtest_dir}" "${gmock_BINARY_DIR}/${gtest_dir}")
  51
  52
  53 # These commands only run if this is the main project
  54 if(CMAKE_PROJECT_NAME STREQUAL "gmock" OR CMAKE_PROJECT_NAME STREQUAL "googletest-distribution")
  55   # BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to
  56   # make it prominent in the GUI.
  57   option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF)
  58 else()
  59   mark_as_advanced(gmock_build_tests)
  60 endif()
  61
  62 # Although Google Test's CMakeLists.txt calls this function, the
  63 # changes there don't affect the current scope.  Therefore we have to
  64 # call it again here.
  65 config_compiler_and_linker()  # from ${gtest_dir}/cmake/internal_utils.cmake
  66
  67 # Adds Google Mock's and Google Test's header directories to the search path.
  68 set(gmock_build_include_dirs
  69   "${gmock_SOURCE_DIR}/include"
  70   "${gmock_SOURCE_DIR}"
  71   "${gtest_SOURCE_DIR}/include"
  72   # This directory is needed to build directly from Google Test sources.
  73   "${gtest_SOURCE_DIR}")
  74 include_directories(${gmock_build_include_dirs})
  75
  76 ########################################################################
  77 #
  78 # Defines the gmock & gmock_main libraries.  User tests should link
  79 # with one of them.
  80
  81 # Google Mock libraries.  We build them using more strict warnings than what
  82 # are used for other targets, to ensure that Google Mock can be compiled by
  83 # a user aggressive about warnings.
  84 if (MSVC)
  85   cxx_library(gmock
  86               "${cxx_strict}"
  87               "${gtest_dir}/src/gtest-all.cc"
  88               src/gmock-all.cc)
  89
  90   cxx_library(gmock_main
  91               "${cxx_strict}"
  92               "${gtest_dir}/src/gtest-all.cc"
  93               src/gmock-all.cc
  94               src/gmock_main.cc)
  95 else()
  96   cxx_library(gmock "${cxx_strict}" src/gmock-all.cc)
  97   target_link_libraries(gmock PUBLIC gtest)
  98   set_target_properties(gmock PROPERTIES VERSION ${GOOGLETEST_VERSION})
  99   cxx_library(gmock_main "${cxx_strict}" src/gmock_main.cc)
 100   target_link_libraries(gmock_main PUBLIC gmock)
 101   set_target_properties(gmock_main PROPERTIES VERSION ${GOOGLETEST_VERSION})
 102 endif()
 103
 104 string(REPLACE ";" "$<SEMICOLON>" dirs "${gmock_build_include_dirs}")
 105 target_include_directories(gmock SYSTEM INTERFACE
 106   "$<BUILD_INTERFACE:${dirs}>"
 107   "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 108 target_include_directories(gmock_main SYSTEM INTERFACE
 109   "$<BUILD_INTERFACE:${dirs}>"
 110   "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 111
 112 ########################################################################
 113 #
 114 # Install rules
 115 install_project(gmock gmock_main)
 116
 117 ########################################################################
 118 #
 119 # Google Mock's own tests.
 120 #
 121 # You can skip this section if you aren't interested in testing
 122 # Google Mock itself.
 123 #
 124 # The tests are not built by default.  To build them, set the
 125 # gmock_build_tests option to ON.  You can do it by running ccmake
 126 # or specifying the -Dgmock_build_tests=ON flag when running cmake.
 127
 128 if (gmock_build_tests)
 129   # This must be set in the root directory for the tests to be run by
 130   # 'make test' or ctest.
 131   enable_testing()
 132
 133   if (MINGW OR CYGWIN)
 134     add_compile_options("-Wa,-mbig-obj")
 135   endif()
 136
 137   ############################################################
 138   # C++ tests built with standard compiler flags.
 139
 140   cxx_test(gmock-actions_test gmock_main)
 141   cxx_test(gmock-cardinalities_test gmock_main)
 142   cxx_test(gmock_ex_test gmock_main)
 143   cxx_test(gmock-function-mocker_test gmock_main)
 144   cxx_test(gmock-internal-utils_test gmock_main)
 145   cxx_test(gmock-matchers-arithmetic_test gmock_main)
 146   cxx_test(gmock-matchers-comparisons_test gmock_main)
 147   cxx_test(gmock-matchers-containers_test gmock_main)
 148   cxx_test(gmock-matchers-misc_test gmock_main)
 149   cxx_test(gmock-more-actions_test gmock_main)
 150   cxx_test(gmock-nice-strict_test gmock_main)
 151   cxx_test(gmock-port_test gmock_main)
 152   cxx_test(gmock-spec-builders_test gmock_main)
 153   cxx_test(gmock_link_test gmock_main test/gmock_link2_test.cc)
 154   cxx_test(gmock_test gmock_main)
 155
 156   if (DEFINED GTEST_HAS_PTHREAD)
 157     cxx_test(gmock_stress_test gmock)
 158   endif()
 159
 160   # gmock_all_test is commented to save time building and running tests.
 161   # Uncomment if necessary.
 162   # cxx_test(gmock_all_test gmock_main)
 163
 164   ############################################################
 165   # C++ tests built with non-standard compiler flags.
 166
 167   if (MSVC)
 168     cxx_library(gmock_main_no_exception "${cxx_no_exception}"
 169       "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 170
 171     cxx_library(gmock_main_no_rtti "${cxx_no_rtti}"
 172       "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 173
 174   else()
 175     cxx_library(gmock_main_no_exception "${cxx_no_exception}" src/gmock_main.cc)
 176     target_link_libraries(gmock_main_no_exception PUBLIC gmock)
 177
 178     cxx_library(gmock_main_no_rtti "${cxx_no_rtti}" src/gmock_main.cc)
 179     target_link_libraries(gmock_main_no_rtti PUBLIC gmock)
 180   endif()
 181   cxx_test_with_flags(gmock-more-actions_no_exception_test "${cxx_no_exception}"
 182     gmock_main_no_exception test/gmock-more-actions_test.cc)
 183
 184   cxx_test_with_flags(gmock_no_rtti_test "${cxx_no_rtti}"
 185     gmock_main_no_rtti test/gmock-spec-builders_test.cc)
 186
 187   cxx_shared_library(shared_gmock_main "${cxx_default}"
 188     "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 189
 190   # Tests that a binary can be built with Google Mock as a shared library.  On
 191   # some system configurations, it may not possible to run the binary without
 192   # knowing more details about the system configurations. We do not try to run
 193   # this binary. To get a more robust shared library coverage, configure with
 194   # -DBUILD_SHARED_LIBS=ON.
 195   cxx_executable_with_flags(shared_gmock_test_ "${cxx_default}"
 196     shared_gmock_main test/gmock-spec-builders_test.cc)
 197   set_target_properties(shared_gmock_test_
 198     PROPERTIES
 199     COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
 200
 201   ############################################################
 202   # Python tests.
 203
 204   cxx_executable(gmock_leak_test_ test gmock_main)
 205   py_test(gmock_leak_test)
 206
 207   cxx_executable(gmock_output_test_ test gmock)
 208   py_test(gmock_output_test)
 209 endif()