googleMock/CMakeLists.txt

   1 ########################################################################
   2 # CMake build script for Google Mock.
   3 #
   4 # To run the tests for Google Mock itself on Linux, use 'make test' or
   5 # ctest.  You can select which tests to run using 'ctest -R regex'.
   6 # For more options, run 'ctest --help'.
   7
   8 # BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to
   9 # make it prominent in the GUI.
  10
  11 set (CMAKE_CXX_FLAGS "-std=gnu++0x -D_GNU_SOURCE -Wno-variadic-macros")
  12
  13 option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF)
  14
  15 # Forces BUILD_SHARED_LIBS to OFF as Google Mock currently does not support
  16 # working in a DLL.
  17 # TODO(vladl@google.com): Implement building gMock as a DLL.
  18 set(BUILD_SHARED_LIBS OFF)
  19
  20 option(gmock_build_tests "Build all of Google Mock's own tests." OFF)
  21
  22 # A directory to find Google Test sources.
  23 if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gtest/CMakeLists.txt")
  24   set(gtest_dir gtest)
  25 else()
  26   set(gtest_dir ../gtest)
  27 endif()
  28
  29 # Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build().
  30 include("${gtest_dir}/cmake/hermetic_build.cmake" OPTIONAL)
  31
  32 if (COMMAND pre_project_set_up_hermetic_build)
  33   # Google Test also calls hermetic setup functions from add_subdirectory,
  34   # although its changes will not affect things at the current scope.
  35   pre_project_set_up_hermetic_build()
  36 endif()
  37
  38 ########################################################################
  39 #
  40 # Project-wide settings
  41
  42 # Name of the project.
  43 #
  44 # CMake files in this project can refer to the root source directory
  45 # as ${gmock_SOURCE_DIR} and to the root binary directory as
  46 # ${gmock_BINARY_DIR}.
  47 # Language "C" is required for find_package(Threads).
  48 project(gmock CXX C)
  49 cmake_minimum_required(VERSION 2.6.2)
  50
  51 if (COMMAND set_up_hermetic_build)
  52   set_up_hermetic_build()
  53 endif()
  54
  55 # Instructs CMake to process Google Test's CMakeLists.txt and add its
  56 # targets to the current scope.  We are placing Google Test's binary
  57 # directory in a subdirectory of our own as VC compilation may break
  58 # if they are the same (the default).
  59 add_subdirectory("${gtest_dir}" "${gmock_BINARY_DIR}/gtest")
  60
  61 # Although Google Test's CMakeLists.txt calls this function, the
  62 # changes there don't affect the current scope.  Therefore we have to
  63 # call it again here.
  64 config_compiler_and_linker()  # from ${gtest_dir}/cmake/internal_utils.cmake
  65
  66 # Adds Google Mock's and Google Test's header directories to the search path.
  67 include_directories("${gmock_SOURCE_DIR}/include"
  68                     "${gmock_SOURCE_DIR}"
  69                     "${gtest_SOURCE_DIR}/include"
  70                     # This directory is needed to build directly from Google
  71                     # Test sources.
  72                     "${gtest_SOURCE_DIR}")
  73
  74 ########################################################################
  75 #
  76 # Defines the gmock & gmock_main libraries.  User tests should link
  77 # with one of them.
  78
  79 # Google Mock libraries.  We build them using more strict warnings than what
  80 # are used for other targets, to ensure that Google Mock can be compiled by
  81 # a user aggressive about warnings.
  82 cxx_library(gmock "${cxx_strict}" src/gmock-all.cc)
  83 target_link_libraries(gmock gtest)
  84
  85 cxx_library(gmock_main "${cxx_strict}" src/gmock_main.cc)
  86 target_link_libraries(gmock_main gmock)
  87
  88 ########################################################################
  89 #
  90 # Google Mock's own tests.
  91 #
  92 # You can skip this section if you aren't interested in testing
  93 # Google Mock itself.
  94 #
  95 # The tests are not built by default.  To build them, set the
  96 # gmock_build_tests option to ON.  You can do it by running ccmake
  97 # or specifying the -Dgmock_build_tests=ON flag when running cmake.
  98
  99 if (gmock_build_tests)
 100   # This must be set in the root directory for the tests to be run by
 101   # 'make test' or ctest.
 102   enable_testing()
 103
 104   ############################################################
 105   # C++ tests built with standard compiler flags.
 106
 107   cxx_test(gmock-actions_test gmock_main)
 108   cxx_test(gmock-cardinalities_test gmock_main)
 109   cxx_test(gmock-generated-actions_test gmock_main)
 110   cxx_test(gmock-generated-function-mockers_test gmock_main)
 111   cxx_test(gmock-generated-internal-utils_test gmock_main)
 112   cxx_test(gmock-generated-matchers_test gmock_main)
 113   cxx_test(gmock-internal-utils_test gmock_main)
 114   cxx_test(gmock-matchers_test gmock_main)
 115   cxx_test(gmock-more-actions_test gmock_main)
 116   cxx_test(gmock-nice-strict_test gmock_main)
 117   cxx_test(gmock-port_test gmock_main)
 118   cxx_test(gmock-spec-builders_test gmock_main)
 119   cxx_test(gmock_link_test gmock_main test/gmock_link2_test.cc)
 120   # cxx_test(gmock_stress_test gmock)
 121   cxx_test(gmock_test gmock_main)
 122
 123   # gmock_all_test is commented to save time building and running tests.
 124   # Uncomment if necessary.
 125   # cxx_test(gmock_all_test gmock_main)
 126
 127   ############################################################
 128   # C++ tests built with non-standard compiler flags.
 129
 130   cxx_library(gmock_main_no_exception "${cxx_no_exception}"
 131     "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 132   cxx_library(gmock_main_no_rtti "${cxx_no_rtti}"
 133     "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 134   cxx_library(gmock_main_use_own_tuple "${cxx_use_own_tuple}"
 135     "${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc)
 136
 137   cxx_test_with_flags(gmock-more-actions_no_exception_test "${cxx_no_exception}"
 138     gmock_main_no_exception test/gmock-more-actions_test.cc)
 139
 140   cxx_test_with_flags(gmock_no_rtti_test "${cxx_no_rtti}"
 141     gmock_main_no_rtti test/gmock-spec-builders_test.cc)
 142
 143   cxx_test_with_flags(gmock_use_own_tuple_test "${cxx_use_own_tuple}"
 144     gmock_main_use_own_tuple test/gmock-spec-builders_test.cc)
 145
 146   ############################################################
 147   # Python tests.
 148
 149   cxx_executable(gmock_leak_test_ test gmock_main)
 150   py_test(gmock_leak_test)
 151
 152   cxx_executable(gmock_output_test_ test gmock)
 153   py_test(gmock_output_test)
 154 endif()